!   F01FMF Example Program Text

!   Mark 24 Release. NAG Copyright 2012.

    Module f01fmfe_mod

!     F01FMF Example Program Module:
!            Parameters and User-defined Routines

!     .. Use Statements ..
      Use nag_library, Only: nag_wp
!     .. Implicit None Statement ..
      Implicit None
    Contains
      Subroutine fexp3(m,iflag,nz,z,fz,iuser,ruser)

!       .. Use Statements ..
        Use nag_library, Only: nag_wp
!       .. Parameters ..
        Complex (Kind=nag_wp), Parameter     ::                                &
                                            three = (3.0E0_nag_wp,0.0E0_nag_wp)
!       .. Scalar Arguments ..
        Integer, Intent (Inout)              :: iflag
        Integer, Intent (In)                 :: m, nz
!       .. Array Arguments ..
        Complex (Kind=nag_wp), Intent (Out)  :: fz(nz)
        Complex (Kind=nag_wp), Intent (In)   :: z(nz)
        Real (Kind=nag_wp), Intent (Inout)   :: ruser(*)
        Integer, Intent (Inout)              :: iuser(*)
!       .. Intrinsic Procedures ..
        Intrinsic                            :: exp
!       .. Executable Statements ..
        Continue
        fz(1:nz) = (three**m)*exp(three*z(1:nz))
        Return

      End Subroutine fexp3

    End Module f01fmfe_mod

    Program f01fmfe

!     F01FMF Example Main Program

!     .. Use Statements ..
      Use nag_library, Only: f01fmf, nag_wp, x04daf
      Use f01fmfe_mod, Only: fexp3
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter                   :: nin = 5, nout = 6
!     .. Local Scalars ..
      Integer                              :: i, ifail, iflag, lda, n
!     .. Local Arrays ..
      Complex (Kind=nag_wp), Allocatable   :: a(:,:)
      Real (Kind=nag_wp)                   :: ruser(1)
      Integer                              :: iuser(1)
!     .. Executable Statements ..
      Write (nout,*) 'F01FMF Example Program Results'
      Write (nout,*)
!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) n

      lda = n
      Allocate (a(lda,n))

!     Read A from data file
      Read (nin,*)(a(i,1:n),i=1,n)

!     Find f( A )
      ifail = 0
      Call f01fmf(n,a,lda,fexp3,iuser,ruser,iflag,ifail)

!     Print solution
      ifail = 0
      Call x04daf('G','N',n,n,a,lda,'F(A) = EXP(3A)',ifail)

    End Program f01fmfe