!   D02PWF Example Program Text
!   Mark 24 Release. NAG Copyright 2012.

    Module d02pwfe_mod

!     D02PWF Example Program Module:
!            Parameters and User-defined Routines

!     .. Use Statements ..
      Use nag_library, Only: nag_wp
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Real (Kind=nag_wp), Parameter        :: tol1 = 1.0E-4_nag_wp
      Real (Kind=nag_wp), Parameter        :: tol2 = 1.0E-5_nag_wp
      Integer, Parameter                   :: neq = 4, nin = 5, nout = 6,      &
                                              npts = 6
      Integer, Parameter                   :: lenwrk = 32*neq
    Contains
      Subroutine f(t,y,yp)

!       .. Scalar Arguments ..
        Real (Kind=nag_wp), Intent (In)      :: t
!       .. Array Arguments ..
        Real (Kind=nag_wp), Intent (In)      :: y(*)
        Real (Kind=nag_wp), Intent (Out)     :: yp(*)
!       .. Local Scalars ..
        Real (Kind=nag_wp)                   :: r
!       .. Intrinsic Procedures ..
        Intrinsic                            :: sqrt
!       .. Executable Statements ..
        r = sqrt(y(1)**2+y(2)**2)
        yp(1) = y(3)
        yp(2) = y(4)
        yp(3) = -y(1)/r**3
        yp(4) = -y(2)/r**3
        Return
      End Subroutine f
    End Module d02pwfe_mod

    Program d02pwfe

!     D02PWF Example Main Program

!     .. Use Statements ..
      Use nag_library, Only: d02pdf, d02pvf, d02pwf, d02pyf, nag_wp
      Use d02pwfe_mod, Only: f, lenwrk, neq, nin, nout, npts, tol1, tol2
!     .. Implicit None Statement ..
      Implicit None
!     .. Local Scalars ..
      Real (Kind=nag_wp)                   :: hnext, hstart, tendnu, tfinal,   &
                                              tinc, tnow, tol, tstart, waste
      Integer                              :: i, ifail, method, stpcst,        &
                                              stpsok, totf
      Logical                              :: errass
!     .. Local Arrays ..
      Real (Kind=nag_wp), Allocatable      :: thres(:), work(:), ynow(:),      &
                                              ypnow(:), ystart(:)
!     .. Intrinsic Procedures ..
      Intrinsic                            :: real
!     .. Executable Statements ..
      Write (nout,*) 'D02PWF Example Program Results'
!     Skip heading in data file
      Read (nin,*)
!     neq: number of differential equations
      Read (nin,*) method
      Allocate (thres(neq),work(lenwrk),ynow(neq),ypnow(neq),ystart(neq))

!     Set initial conditions and input for D02PVF

      Read (nin,*) tstart, tfinal
      Read (nin,*) ystart(1:neq)
      Read (nin,*) hstart
      Read (nin,*) thres(1:neq)
      Read (nin,*) errass

!     Set output control

      tinc = (tfinal-tstart)/real(npts,kind=nag_wp)

      Do i = 1, 2
        If (i==1) tol = tol1
        If (i==2) tol = tol2
        tendnu = tstart + tinc

!       ifail: behaviour on error exit   
!              =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
        ifail = 0
        Call d02pvf(neq,tstart,ystart,tendnu,tol,thres,method,'Complex Task', &
          errass,hstart,work,lenwrk,ifail)

        Write (nout,99999) tol
        Write (nout,99998)
        Write (nout,99997) tstart, ystart(1:neq)

loop:   Do
          ifail = 0
          Call d02pdf(f,tnow,ynow,ypnow,work,ifail)

          If (tnow>=tendnu) Then
            Write (nout,99997) tnow, ynow(1:neq)

            If (tnow>=tfinal) Exit loop
            tendnu = tendnu + tinc
            Call d02pwf(tendnu,ifail)
          End If

        End Do loop

        ifail = 0
        Call d02pyf(totf,stpcst,waste,stpsok,hnext,ifail)
        Write (nout,99996) totf
      End Do

99999 Format (/' Calculation with TOL = ',E8.1)
99998 Format (/'    t         y1         y2         y3         y4'/)
99997 Format (1X,F6.3,4(3X,F8.4))
99996 Format (/' Cost of the integration in evaluations of F is',I6)

    End Program d02pwfe