*     S30BBF Example Program Text
*     Mark 22 Release. NAG Copyright 2007.
*     .. Parameters ..
      INTEGER          NIN, NOUT
      PARAMETER        (NIN=5,NOUT=6)
      INTEGER          LDP, MMAX, NMAX
      PARAMETER        (LDP=10,MMAX=10,NMAX=10)
*     .. Local Scalars ..
      DOUBLE PRECISION Q, R, S, SIGMA
      INTEGER          I, IFAIL, J, M, N
      CHARACTER        PUT
*     .. Local Arrays ..
      DOUBLE PRECISION CHARM(LDP,NMAX), COLOUR(LDP,NMAX),
     +                 CRHO(LDP,NMAX), DELTA(LDP,NMAX), GAMMA(LDP,NMAX),
     +                 P(LDP,NMAX), RHO(LDP,NMAX), SM(MMAX),
     +                 SPEED(LDP,NMAX), T(NMAX), THETA(LDP,NMAX),
     +                 VANNA(LDP,NMAX), VEGA(LDP,NMAX), VOMMA(LDP,NMAX),
     +                 ZOMMA(LDP,NMAX)
*     .. External Subroutines ..
      EXTERNAL         S30BBF
*     .. Executable Statements ..
      WRITE (NOUT,*) 'S30BBF Example Program Results'
      WRITE (NOUT,*)
      WRITE (NOUT,*) 'Floating-Strike Lookback'
*     Skip heading in data file
      READ (NIN,*)
*     Read problem parameters.
      READ (NIN,*) PUT
      READ (NIN,*) S, SIGMA, R, Q
      READ (NIN,*) M, N
*
      IF (M.LE.MMAX .AND. N.LE.NMAX) THEN
*        Read array of MIN/MAX prices, SM
         READ (NIN,*) (SM(I),I=1,M)
*        Read array of times to expiry
         READ (NIN,*) (T(I),I=1,N)
*
         IFAIL = 1
*
         CALL S30BBF(PUT,M,N,SM,S,T,SIGMA,R,Q,P,LDP,DELTA,GAMMA,VEGA,
     +               THETA,RHO,CRHO,VANNA,CHARM,SPEED,COLOUR,ZOMMA,
     +               VOMMA,IFAIL)
*
         IF (IFAIL.EQ.0) THEN
            IF (PUT.EQ.'C') THEN
               WRITE (NOUT,*) 'European Call :'
            ELSE IF (PUT.EQ.'P') THEN
               WRITE (NOUT,*) 'European Put :'
            END IF
*
            WRITE (NOUT,'(A,1X,F8.4)') '  Spot       = ', S
            WRITE (NOUT,'(A,1X,F8.4)') '  Volatility = ', SIGMA
            WRITE (NOUT,'(A,1X,F8.4)') '  Rate       = ', R
            WRITE (NOUT,'(A,1X,F8.4)') '  Dividend   = ', Q
*
            WRITE (NOUT,*)
            DO 60 J = 1, N
               WRITE (NOUT,*)
               WRITE (NOUT,99999) T(J)
               WRITE (NOUT,*) 'S-Max/Min     Price     Delta     Gamma'
     +           //'      Vega      Theta      Rho      CRho'
               DO 20 I = 1, M
                  WRITE (NOUT,99998) SM(I), P(I,J), DELTA(I,J),
     +              GAMMA(I,J), VEGA(I,J), THETA(I,J), RHO(I,J),
     +              CRHO(I,J)
   20          CONTINUE
*
               WRITE (NOUT,*) 'S-Max/Min     Price     Vanna     Charm'
     +           //'     Speed     Colour    Zomma     Vomma'
               DO 40 I = 1, M
                  WRITE (NOUT,99998) SM(I), P(I,J), VANNA(I,J),
     +              CHARM(I,J), SPEED(I,J), COLOUR(I,J), ZOMMA(I,J),
     +              VOMMA(I,J)
   40          CONTINUE
*
   60       CONTINUE
         ELSE
            WRITE (NOUT,*)
            WRITE (NOUT,99997) IFAIL
         END IF
      END IF
*
99999 FORMAT (1X,'Time to Expiry : ',1X,F8.4)
99998 FORMAT (8(1X,F9.4))
99997 FORMAT (1X,' ** S30BBF returned with IFAIL = ',I5)
      END