*     G11BBF Example Program Text
*     Mark 17 Release. NAG Copyright 1995.
*     .. Parameters ..
      INTEGER          NIN, NOUT
      PARAMETER        (NIN=5,NOUT=6)
      INTEGER          NMAX, MMAX, LTMAX
      PARAMETER        (NMAX=54,MMAX=3,LTMAX=18)
*     .. Local Scalars ..
      DOUBLE PRECISION PERCNT
      INTEGER          I, IFAIL, J, K, LDF, MAXT, N, NCELLS, NCOL, NDIM,
     +                 NFAC, NROW
      CHARACTER        TYP, WEIGHT
*     .. Local Arrays ..
      DOUBLE PRECISION TABLE(LTMAX), WK(2*NMAX), WT(NMAX), Y(NMAX)
      INTEGER          ICOUNT(LTMAX), IDIM(MMAX), IFAC(NMAX,MMAX),
     +                 ISF(MMAX), IWK(2*MMAX+NMAX), LFAC(MMAX)
*     .. External Subroutines ..
      EXTERNAL         G11BBF
*     .. Executable Statements ..
      WRITE (NOUT,*) 'G11BBF Example Program Results'
*     Skip heading in data file
      READ (NIN,*)
      READ (NIN,*) TYP, WEIGHT, N, NFAC, PERCNT
      IF (N.LE.NMAX .AND. NFAC.LE.MMAX) THEN
         IF (WEIGHT.EQ.'W' .OR. WEIGHT.EQ.'w' .OR. WEIGHT.EQ.'V' .OR.
     +       WEIGHT.EQ.'v') THEN
            DO 20 I = 1, N
               READ (NIN,*) (IFAC(I,J),J=1,NFAC), Y(I), WT(I)
   20       CONTINUE
         ELSE
            DO 40 I = 1, N
               READ (NIN,*) (IFAC(I,J),J=1,NFAC), Y(I)
   40       CONTINUE
         END IF
         READ (NIN,*) (LFAC(J),J=1,NFAC)
         READ (NIN,*) (ISF(J),J=1,NFAC)
         LDF = NMAX
         MAXT = LTMAX
         IFAIL = 0
*
         CALL G11BBF(TYP,WEIGHT,N,NFAC,ISF,LFAC,IFAC,LDF,PERCNT,Y,WT,
     +               TABLE,MAXT,NCELLS,NDIM,IDIM,ICOUNT,IWK,WK,IFAIL)
*
         WRITE (NOUT,*)
         WRITE (NOUT,99999) ' TABLE for ', PERCNT, 'th percentile'
         WRITE (NOUT,*)
         NCOL = IDIM(NDIM)
         NROW = NCELLS/NCOL
         K = 1
         DO 60 I = 1, NROW
            WRITE (NOUT,99998) (TABLE(J),'(',ICOUNT(J),')',J=K,K+NCOL-1)
            K = K + NCOL
   60    CONTINUE
      END IF
*
99999 FORMAT (A,F4.0,A)
99998 FORMAT (1X,6(F8.2,A,I2,A))
      END