*     G03EJF Example Program Text
*     Mark 18 Revised. NAG Copyright 1997.
*     .. Parameters ..
      INTEGER          NIN, NOUT
      PARAMETER        (NIN=5,NOUT=6)
      INTEGER          NMAX, MMAX, LENC
      PARAMETER        (NMAX=10,MMAX=10,LENC=20)
*     .. Local Scalars ..
      DOUBLE PRECISION DLEVEL, DMIN, DSTEP, YDIST
      INTEGER          I, IFAIL, J, K, LDX, M, METHOD, N, NSYM
      CHARACTER        DIST, SCALE, UPDATE
*     .. Local Arrays ..
      DOUBLE PRECISION CD(NMAX-1), D(NMAX*(NMAX-1)/2), DORD(NMAX),
     +                 S(MMAX), X(NMAX,MMAX)
      INTEGER          IC(NMAX), ILC(NMAX-1), IORD(NMAX), ISX(MMAX),
     +                 IUC(NMAX-1), IWK(2*NMAX)
      CHARACTER*3      NAME(NMAX)
      CHARACTER*60     C(LENC)
*     .. External Subroutines ..
      EXTERNAL         G03EAF, G03ECF, G03EHF, G03EJF
*     .. Intrinsic Functions ..
      INTRINSIC        DBLE, MOD
*     .. Executable Statements ..
      WRITE (NOUT,*) 'G03EJF Example Program Results'
*     Skip heading in data file
      READ (NIN,*)
      READ (NIN,*) N, M
      IF (N.LE.NMAX .AND. M.LE.MMAX) THEN
         READ (NIN,*) METHOD
         READ (NIN,*) UPDATE, DIST, SCALE
         DO 20 J = 1, N
            READ (NIN,*) (X(J,I),I=1,M), NAME(J)
   20    CONTINUE
         READ (NIN,*) (ISX(I),I=1,M)
         READ (NIN,*) (S(I),I=1,M)
         READ (NIN,*) K, DLEVEL
*
*        Compute the distance matrix
*
         IFAIL = 1
         LDX = NMAX
*
         CALL G03EAF(UPDATE,DIST,SCALE,N,M,X,LDX,ISX,S,D,IFAIL)
         IF (IFAIL.NE.0) THEN
            WRITE (NOUT,*)
            WRITE (NOUT,99995) ' ** G03EAF returned with IFAIL = ',
     +        IFAIL
            GO TO 100
         END IF
*
*        Perform clustering
*
         IFAIL = 1
*
         CALL G03ECF(METHOD,N,D,ILC,IUC,CD,IORD,DORD,IWK,IFAIL)
*
         IF (IFAIL.NE.0) THEN
            WRITE (NOUT,*)
            WRITE (NOUT,99995) ' ** G03ECF returned with IFAIL = ',
     +        IFAIL
            GO TO 100
         END IF
         WRITE (NOUT,*)
         WRITE (NOUT,*) '  Distance   Clusters Joined'
         WRITE (NOUT,*)
         DO 40 I = 1, N - 1
            WRITE (NOUT,99999) CD(I), NAME(ILC(I)), NAME(IUC(I))
   40    CONTINUE
*
*        Produce dendrogram
*
         IFAIL = 1
         NSYM = LENC
         DMIN = 0.0D0
         DSTEP = (CD(N-1))/DBLE(NSYM)
*
         CALL G03EHF('S',N,DORD,DMIN,DSTEP,NSYM,C,LENC,IFAIL)
*
         IF (IFAIL.NE.0) THEN
            WRITE (NOUT,*)
            WRITE (NOUT,99995) ' ** G03EHF returned with IFAIL = ',
     +        IFAIL
            GO TO 100
         END IF
         WRITE (NOUT,*)
         WRITE (NOUT,*) 'Dendrogram'
         WRITE (NOUT,*)
         YDIST = CD(N-1)
         DO 60 I = 1, NSYM
            IF (MOD(I,3).EQ.1) THEN
               WRITE (NOUT,99999) YDIST, C(I)
            ELSE
               WRITE (NOUT,99998) C(I)
            END IF
            YDIST = YDIST - DSTEP
   60    CONTINUE
         WRITE (NOUT,*)
         WRITE (NOUT,99998) (NAME(IORD(I)),I=1,N)
         IFAIL = 1
*
         CALL G03EJF(N,CD,IORD,DORD,K,DLEVEL,IC,IFAIL)
*
         IF (IFAIL.EQ.0) THEN
            WRITE (NOUT,*)
            WRITE (NOUT,99997) ' Allocation to ', K, ' clusters'
            WRITE (NOUT,*)
            WRITE (NOUT,*) ' Object  Cluster'
            WRITE (NOUT,*)
            DO 80 I = 1, N
               WRITE (NOUT,99996) NAME(I), IC(I)
   80       CONTINUE
         ELSE
            WRITE (NOUT,*)
            WRITE (NOUT,99995) ' ** G03EJF returned with IFAIL = ',
     +        IFAIL
         END IF
      END IF
  100 CONTINUE
*
99999 FORMAT (F10.3,5X,2A)
99998 FORMAT (15X,20A)
99997 FORMAT (A,I2,A)
99996 FORMAT (5X,A,5X,I2)
99995 FORMAT (1X,A,I5)
      END