*     F08HBF Example Program Text
*     Mark 21 Release.  NAG Copyright 2004.
*     .. Parameters ..
      INTEGER          NIN, NOUT
      PARAMETER        (NIN=5,NOUT=6)
      INTEGER          KDMAX, NMAX, MMAX
      PARAMETER        (KDMAX=5,NMAX=20,MMAX=10)
      INTEGER          LDAB, LDQ, LDZ
      PARAMETER        (LDAB=KDMAX+1,LDQ=NMAX,LDZ=NMAX)
      CHARACTER        UPLO
      PARAMETER        (UPLO='U')
      DOUBLE PRECISION ZERO
      PARAMETER        (ZERO=0.0D+0)
*     .. Local Scalars ..
      DOUBLE PRECISION ABSTOL, VL, VU
      INTEGER          I, IFAIL, IL, INFO, IU, J, KD, M, N
*     .. Local Arrays ..
      DOUBLE PRECISION AB(LDAB,NMAX), Q(LDQ,NMAX), W(NMAX),
     +                 WORK(7*NMAX), Z(LDZ,MMAX)
      INTEGER          IWORK(5*NMAX), JFAIL(NMAX)
*     .. External Subroutines ..
      EXTERNAL         DSBEVX, X04CAF
*     .. Intrinsic Functions ..
      INTRINSIC        MAX, MIN
*     .. Executable Statements ..
      WRITE (NOUT,*) 'F08HBF Example Program Results'
      WRITE (NOUT,*)
*     Skip heading in data file
      READ (NIN,*)
      READ (NIN,*) N, KD
      IF (N.LE.NMAX .AND. KD.LE.KDMAX) THEN
*
*        Read the lower and upper bounds of the interval to be searched,
*        and read the upper or lower triangular part of the matrix A
*        from data file
*
         READ (NIN,*) VL, VU
         IF (UPLO.EQ.'U') THEN
            READ (NIN,*) ((AB(KD+1+I-J,J),J=I,MIN(N,I+KD)),I=1,N)
         ELSE IF (UPLO.EQ.'L') THEN
            READ (NIN,*) ((AB(1+I-J,J),J=MAX(1,I-KD),I),I=1,N)
         END IF
*
*        Set the absolute error tolerance for eigenvalues.  With ABSTOL
*        set to zero, the default value is used instead
*
         ABSTOL = ZERO
*
*        Solve the band symmetric eigenvalue problem
*
         CALL DSBEVX('Vectors','Values in range',UPLO,N,KD,AB,LDAB,Q,
     +               LDQ,VL,VU,IL,IU,ABSTOL,M,W,Z,LDZ,WORK,IWORK,JFAIL,
     +               INFO)
*
         IF (INFO.GE.0 .AND. M.LE.MMAX) THEN
*
*           Print solution
*
            WRITE (NOUT,99999) 'Number of eigenvalues found =', M
            WRITE (NOUT,*)
            WRITE (NOUT,*) 'Eigenvalues'
            WRITE (NOUT,99998) (W(J),J=1,M)
*
            IFAIL = 0
            CALL X04CAF('General',' ',N,M,Z,LDZ,'Selected eigenvectors',
     +                  IFAIL)
            IF (INFO.GT.0) THEN
               WRITE (NOUT,99999)
     +           'INFO eigenvectors failed to converge, INFO =', INFO
               WRITE (NOUT,*)
     +           'Indices of eigenvectors that did not converge'
               WRITE (NOUT,99997) (JFAIL(J),J=1,M)
            END IF
         ELSE IF (M.GT.MMAX) THEN
            WRITE (NOUT,99996) 'M greater than MMAX, M =', M,
     +        ', MMAX =', MMAX
         ELSE
            WRITE (NOUT,99999) 'Failure in DSBEVX. INFO =', INFO
         END IF
      ELSE
         WRITE (NOUT,*)
         WRITE (NOUT,*) 'NMAX and/or KDMAX too small'
      END IF
*
99999 FORMAT (1X,A,I5)
99998 FORMAT (3X,(8F8.4))
99997 FORMAT (3X,(8I8))
99996 FORMAT (1X,A,I5,A,I5)
      END