*     F08FQF Example Program Text
*     Mark 20 Revised. NAG Copyright 2001.
*     .. Parameters ..
      INTEGER          NIN, NOUT
      PARAMETER        (NIN=5,NOUT=6)
      INTEGER          NMAX, LDA
      PARAMETER        (NMAX=8,LDA=NMAX)
      INTEGER          LWORK, LIWORK, LRWORK
      PARAMETER        (LWORK=NMAX*(NMAX+2),LIWORK=5*NMAX+3,
     +                 LRWORK=2*NMAX*NMAX+5*NMAX+1)
*     .. Local Scalars ..
      INTEGER          I, IFAIL, INFO, J, N
      CHARACTER        JOB, UPLO
*     .. Local Arrays ..
      COMPLEX *16      A(LDA,NMAX), WORK(LWORK)
      DOUBLE PRECISION RWORK(LRWORK), W(NMAX)
      INTEGER          IWORK(LIWORK)
*     .. External Subroutines ..
      EXTERNAL         X04DAF, ZHEEVD
*     .. Executable Statements ..
      WRITE (NOUT,*) 'F08FQF Example Program Results'
*     Skip heading in data file
      READ (NIN,*)
      READ (NIN,*) N
      IF (N.LE.NMAX) THEN
         READ (NIN,*) UPLO
*
*        Read A from data file
*
         IF (UPLO.EQ.'U') THEN
            READ (NIN,*) ((A(I,J),J=I,N),I=1,N)
         ELSE IF (UPLO.EQ.'L') THEN
            READ (NIN,*) ((A(I,J),J=1,I),I=1,N)
         END IF
*
         READ (NIN,*) JOB
*
*        Calculate all the eigenvalues and eigenvectors of A
*
         CALL ZHEEVD(JOB,UPLO,N,A,LDA,W,WORK,LWORK,RWORK,LRWORK,IWORK,
     +               LIWORK,INFO)
*
         WRITE (NOUT,*)
         IF (INFO.GT.0) THEN
            WRITE (NOUT,*) 'Failure to converge.'
         ELSE
*
*           Print eigenvalues and eigenvectors
*
            WRITE (NOUT,*) 'Eigenvalues'
            DO 20 I = 1, N
               WRITE (NOUT,99999) I, W(I)
   20       CONTINUE
            WRITE (NOUT,*)
            IFAIL = 0
*
            CALL X04DAF('General',' ',N,N,A,LDA,'Eigenvectors',IFAIL)
*
         END IF
      END IF
*
99999 FORMAT (3X,I5,5X,2F8.4)
      END