*     F04BCF Example Program Text
*     Mark 21 Release. NAG Copyright 2004.
*     .. Parameters ..
      INTEGER          NIN, NOUT
      PARAMETER        (NIN=5,NOUT=6)
      INTEGER          NMAX, NRHSMX
      PARAMETER        (NMAX=8,NRHSMX=2)
      INTEGER          LDB
      PARAMETER        (LDB=NMAX)
*     .. Local Scalars ..
      DOUBLE PRECISION ERRBND, RCOND
      INTEGER          I, IERR, IFAIL, J, N, NRHS
*     .. Local Arrays ..
      DOUBLE PRECISION B(LDB,NRHSMX), D(NMAX), DL(NMAX-1), DU(NMAX-1),
     +                 DU2(NMAX-2)
      INTEGER          IPIV(NMAX)
*     .. External Subroutines ..
      EXTERNAL         F04BCF, X04CAF
*     .. Executable Statements ..
      WRITE (NOUT,*) 'F04BCF Example Program Results'
      WRITE (NOUT,*)
*     Skip heading in data file
      READ (NIN,*)
      READ (NIN,*) N, NRHS
      IF (N.LE.NMAX .AND. NRHS.LE.NRHSMX) THEN
*
*        Read A and B from data file
*
         READ (NIN,*) (DU(I),I=1,N-1)
         READ (NIN,*) (D(I),I=1,N)
         READ (NIN,*) (DL(I),I=1,N-1)
         READ (NIN,*) ((B(I,J),J=1,NRHS),I=1,N)
*
*        Solve the equations AX = B for X
*
         IFAIL = 1
         CALL F04BCF(N,NRHS,DL,D,DU,DU2,IPIV,B,LDB,RCOND,ERRBND,IFAIL)
*
         IF (IFAIL.EQ.0) THEN
*
*           Print solution, estimate of condition number and approximate
*           error bound
*
            IERR = 0
            CALL X04CAF('General',' ',N,NRHS,B,LDB,'Solution',IERR)
*
            WRITE (NOUT,*)
            WRITE (NOUT,*) 'Estimate of condition number'
            WRITE (NOUT,99999) 1.0D0/RCOND
            WRITE (NOUT,*)
            WRITE (NOUT,*)
     +        'Estimate of error bound for computed solutions'
            WRITE (NOUT,99999) ERRBND
         ELSE IF (IFAIL.EQ.N+1) THEN
*
*           Matrix A is numerically singular.  Print estimate of
*           reciprocal of condition number and solution
*
            WRITE (NOUT,*)
            WRITE (NOUT,*) 'Estimate of reciprocal of condition number'
            WRITE (NOUT,99999) RCOND
*
            WRITE (NOUT,*)
            IERR = 0
            CALL X04CAF('General',' ',N,NRHS,B,LDB,'Solution',IERR)
*
         ELSE IF (IFAIL.GT.0 .AND. IFAIL.LE.N) THEN
*
*           The upper triangular matrix U is exactly singular.  Print
*           details of factorization
*
            WRITE (NOUT,*) 'Details of factorization'
            WRITE (NOUT,*)
            WRITE (NOUT,*) ' Second super-diagonal of U'
            WRITE (NOUT,99998) (DU2(I),I=1,N-2)
            WRITE (NOUT,*)
            WRITE (NOUT,*) ' First super-diagonal of U'
            WRITE (NOUT,99998) (DU(I),I=1,N-1)
            WRITE (NOUT,*)
            WRITE (NOUT,*) ' Main diagonal of U'
            WRITE (NOUT,99998) (D(I),I=1,N)
            WRITE (NOUT,*)
            WRITE (NOUT,*) ' Multipliers'
            WRITE (NOUT,99998) (DL(I),I=1,N-1)
            WRITE (NOUT,*)
            WRITE (NOUT,*) ' Vector of interchanges'
            WRITE (NOUT,99997) (IPIV(I),I=1,N)
         ELSE
            WRITE (NOUT,99996) IFAIL
         END IF
      ELSE
         WRITE (NOUT,*) 'NMAX and/or NRHSMX too small'
      END IF
*
99999 FORMAT (6X,1P,E9.1)
99998 FORMAT (1X,8F9.4)
99997 FORMAT (1X,8I9)
99996 FORMAT (1X,' ** F04BCF returned with IFAIL = ',I5)
      END