*     E04MGA Example Program Text
*     Mark 20 Release. NAG Copyright 2001.
*     .. Parameters ..
      INTEGER          NIN, NOUT
      PARAMETER        (NIN=5,NOUT=6)
      INTEGER          NMAX, NCMAX
      PARAMETER        (NMAX=10,NCMAX=10)
      INTEGER          LDA
      PARAMETER        (LDA=NCMAX)
      INTEGER          LIWORK, LWORK
      PARAMETER        (LIWORK=1000,LWORK=10000)
      INTEGER          LCWSAV, LIWSAV, LLWSAV, LRWSAV
      PARAMETER        (LCWSAV=1,LIWSAV=610,LLWSAV=120,LRWSAV=475)
*     .. Local Scalars ..
      DOUBLE PRECISION OBJ
      INTEGER          I, IFAIL, INFORM, ITER, J, N, NCLIN, OUTCHN
*     .. Local Arrays ..
      DOUBLE PRECISION A(LDA,NMAX), AX(NCMAX), BL(NMAX+NCMAX),
     +                 BU(NMAX+NCMAX), CLAMDA(NMAX+NCMAX), CVEC(NMAX),
     +                 RWSAV(LRWSAV), WORK(LWORK), X(NMAX)
      INTEGER          ISTATE(NMAX+NCMAX), IWORK(LIWORK), IWSAV(LIWSAV)
      LOGICAL          LWSAV(LLWSAV)
      CHARACTER*80     CWSAV(LCWSAV)
*     .. External Subroutines ..
      EXTERNAL         E04MFA, E04MGA, E04MHA, E04WBF, X04ABF
*     .. Executable Statements ..
      WRITE (NOUT,*) 'E04MGA Example Program Results'
      OUTCHN = NOUT
*     Skip heading in data file
      READ (NIN,*)
      READ (NIN,*) N, NCLIN
      IF (N.LE.NMAX .AND. NCLIN.LE.NCMAX) THEN
*
*        Read CVEC, A, BL, BU and X from data file
*
         READ (NIN,*) (CVEC(I),I=1,N)
         READ (NIN,*) ((A(I,J),J=1,N),I=1,NCLIN)
         READ (NIN,*) (BL(I),I=1,N+NCLIN)
         READ (NIN,*) (BU(I),I=1,N+NCLIN)
         READ (NIN,*) (X(I),I=1,N)
*
*        Set the unit number for advisory messages to OUTCHN
*
         CALL X04ABF(1,OUTCHN)
*
*        Initialise using E04WBF and check for error exits
*
         IFAIL = 1
         CALL E04WBF('E04MFA',CWSAV,LCWSAV,LWSAV,LLWSAV,IWSAV,LIWSAV,
     +               RWSAV,LRWSAV,IFAIL)
         IF (IFAIL.EQ.0) THEN
*
*           Set two options using E04MHA
*
            CALL E04MHA(' Check Frequency = 10 ',LWSAV,IWSAV,RWSAV,
     +                  INFORM)
            IF (INFORM.EQ.0) THEN
               CALL E04MHA(' Infinite Bound Size = 1.0D+25 ',LWSAV,
     +                     IWSAV,RWSAV,INFORM)
            END IF
            IF (INFORM.NE.0) THEN
               WRITE (NOUT,99999) 'E04MHA terminated with INFORM = ',
     +           INFORM
            ELSE
*
*              Read the options file for the remaining options
*
               CALL E04MGA(NIN,LWSAV,IWSAV,RWSAV,INFORM)
*
               IF (INFORM.NE.0) THEN
                  WRITE (NOUT,99999) 'E04MGA terminated with INFORM = ',
     +              INFORM
               END IF
            END IF
            IF (INFORM.EQ.0) THEN
*
*              Solve the problem
*
               IFAIL = 1
*
               CALL E04MFA(N,NCLIN,A,LDA,BL,BU,CVEC,ISTATE,X,ITER,OBJ,
     +                     AX,CLAMDA,IWORK,LIWORK,WORK,LWORK,LWSAV,
     +                     IWSAV,RWSAV,IFAIL)
*
               WRITE (NOUT,*)
               IF (IFAIL.EQ.6) THEN
                  WRITE (NOUT,99998)
               ELSE IF (IFAIL.GE.0) THEN
                  WRITE (NOUT,99997) IFAIL
                  WRITE (NOUT,*)
                  WRITE (NOUT,99996)
                  WRITE (NOUT,*)
                  DO 20 I = 1, N
                     WRITE (NOUT,99995) I, ISTATE(I), X(I), CLAMDA(I)
   20             CONTINUE
                  IF (NCLIN.GT.0) THEN
                     WRITE (NOUT,*)
                     WRITE (NOUT,*)
                     WRITE (NOUT,99994)
                     WRITE (NOUT,*)
                     DO 40 I = N + 1, N + NCLIN
                        J = I - N
                        WRITE (NOUT,99993) J, ISTATE(I), AX(J),
     +                    CLAMDA(I)
   40                CONTINUE
                  END IF
                  WRITE (NOUT,*)
                  WRITE (NOUT,*)
                  WRITE (NOUT,99992) OBJ
                  WRITE (NOUT,*)
                  WRITE (NOUT,*)
                  WRITE (NOUT,99991) ITER
               ELSE
                  WRITE (NOUT,99999) ' ** E04MFA returned with IFAIL = '
     +              , IFAIL
               END IF
            END IF
         ELSE
            WRITE (NOUT,*)
            WRITE (NOUT,99999) ' ** E04WBF terminated with IFAIL = ',
     +        IFAIL
         END IF
      END IF
*
99999 FORMAT (1X,A,I5)
99998 FORMAT (1X,'An input parameter is invalid')
99997 FORMAT (1X,'E04MFA returned with IFAIL = ',I5)
99996 FORMAT (1X,'Varbl',2X,'Istate',3X,'Value',8X,'Lagr Mult')
99995 FORMAT (1X,'V',2(1X,I3),2X,1P,G14.6,2X,1P,G12.4)
99994 FORMAT (1X,'L Con',2X,'Istate',3X,'Value',8X,'Lagr Mult')
99993 FORMAT (1X,'L',2(1X,I3),2X,1P,G14.6,2X,1P,G12.4)
99992 FORMAT (1X,'Final objective value = ',G15.7)
99991 FORMAT (1X,'Exit from problem after',1X,I6,1X,'iterations.')
      END