*     C06RAF Example Program Text
*     Mark 19 Release. NAG Copyright 1998.
*     .. Parameters ..
      INTEGER          NIN, NOUT
      PARAMETER        (NIN=5,NOUT=6)
      INTEGER          MMAX, NMAX
      PARAMETER        (MMAX=5,NMAX=20)
*     .. Local Scalars ..
      INTEGER          I, IFAIL, J, M, N
*     .. Local Arrays ..
      DOUBLE PRECISION WORK(MMAX*NMAX+2*NMAX+15), X((NMAX+2)*MMAX)
*     .. External Subroutines ..
      EXTERNAL         C06RAF
*     .. Executable Statements ..
      WRITE (NOUT,*) 'C06RAF Example Program Results'
*     Skip heading in data file
      READ (NIN,*)
   20 CONTINUE
      READ (NIN,*,END=120) M, N
      IF (M.LE.MMAX .AND. N.LE.NMAX) THEN
         DO 40 J = 1, M
            READ (NIN,*) (X((I-1)*M+J),I=1,N-1)
   40    CONTINUE
         WRITE (NOUT,*)
         WRITE (NOUT,*) 'Original data values'
         WRITE (NOUT,*)
         DO 60 J = 1, M
            WRITE (NOUT,99999) (X((I-1)*M+J),I=1,N-1)
   60    CONTINUE
         IFAIL = 1
*
*        -- Compute transform
         CALL C06RAF(M,N,X,WORK,IFAIL)
*
         IF (IFAIL.EQ.0) THEN
            WRITE (NOUT,*)
            WRITE (NOUT,*) 'Discrete Fourier sine transforms'
            WRITE (NOUT,*)
            DO 80 J = 1, M
               WRITE (NOUT,99999) (X((I-1)*M+J),I=1,N-1)
   80       CONTINUE
*
*           -- Compute inverse transform
            CALL C06RAF(M,N,X,WORK,IFAIL)
*
            WRITE (NOUT,*)
            WRITE (NOUT,*)
     +        'Original data as restored by inverse transform'
            WRITE (NOUT,*)
            DO 100 J = 1, M
               WRITE (NOUT,99999) (X((I-1)*M+J),I=1,N-1)
  100       CONTINUE
            GO TO 20
         ELSE
            WRITE (NOUT,*)
            WRITE (NOUT,99998) ' ** C06RAF returned with IFAIL = ',
     +        IFAIL
         END IF
      ELSE
         WRITE (NOUT,*) 'Invalid value of M or N'
      END IF
  120 CONTINUE
*
99999 FORMAT (6X,6F10.4)
99998 FORMAT (1X,A,I5)
      END