*     C06FBF Example Program Text
*     Mark 14 Revised. NAG Copyright 1989.
*     .. Parameters ..
      INTEGER          NMAX
      PARAMETER        (NMAX=20)
      INTEGER          NIN, NOUT
      PARAMETER        (NIN=5,NOUT=6)
*     .. Local Scalars ..
      INTEGER          IFAIL, J, N, N2, NJ
*     .. Local Arrays ..
      DOUBLE PRECISION U(0:NMAX-1), V(0:NMAX-1), WORK(NMAX),
     +                 X(0:NMAX-1), XX(0:NMAX-1)
*     .. External Subroutines ..
      EXTERNAL         C06FAF, C06FBF, C06GBF
*     .. Intrinsic Functions ..
      INTRINSIC        MOD
*     .. Executable Statements ..
      WRITE (NOUT,*) 'C06FBF Example Program Results'
*     Skip heading in data file
      READ (NIN,*)
   20 READ (NIN,*,END=140) N
      IF (N.GT.1 .AND. N.LE.NMAX) THEN
         DO 40 J = 0, N - 1
            READ (NIN,*) X(J)
            XX(J) = X(J)
   40    CONTINUE
         U(0) = X(0)
         V(0) = 0.0D0
         N2 = (N-1)/2
         DO 60 J = 1, N2
            NJ = N - J
            U(J) = X(J)
            U(NJ) = X(J)
            V(J) = X(NJ)
            V(NJ) = -X(NJ)
   60    CONTINUE
         IF (MOD(N,2).EQ.0) THEN
            U(N2+1) = X(N2+1)
            V(N2+1) = 0.0D0
         END IF
         IFAIL = 1
*
         CALL C06FBF(X,N,WORK,IFAIL)
*
         IF (IFAIL.EQ.0) THEN
            WRITE (NOUT,*)
            WRITE (NOUT,*)
     +        'Original sequence and corresponding complex sequence'
            WRITE (NOUT,*)
            WRITE (NOUT,*) '         Data           Real      Imag'
            WRITE (NOUT,*)
            DO 80 J = 0, N - 1
               WRITE (NOUT,99999) J, XX(J), '     ', U(J), V(J)
   80       CONTINUE
            WRITE (NOUT,*)
            WRITE (NOUT,*) 'Components of discrete Fourier transform'
            WRITE (NOUT,*)
            DO 100 J = 0, N - 1
               WRITE (NOUT,99999) J, X(J)
  100       CONTINUE
*
            CALL C06FAF(X,N,WORK,IFAIL)
            CALL C06GBF(X,N,IFAIL)
*
            WRITE (NOUT,*)
            WRITE (NOUT,*)
     +        'Original sequence as restored by inverse transform'
            WRITE (NOUT,*)
            WRITE (NOUT,*) '        Original  Restored'
            WRITE (NOUT,*)
            DO 120 J = 0, N - 1
               WRITE (NOUT,99998) J, XX(J), X(J)
  120       CONTINUE
            GO TO 20
         ELSE
            WRITE (NOUT,*)
            WRITE (NOUT,99997) ' ** C06FBF returned with IFAIL = ',
     +        IFAIL
         END IF
      ELSE
         WRITE (NOUT,*) 'Invalid value of N'
      END IF
  140 CONTINUE
*
99999 FORMAT (1X,I5,F10.5,A,2F10.5)
99998 FORMAT (1X,I5,2F10.5)
99997 FORMAT (1X,A,I5)
      END