* fichier : vecoul3D.dgibi
*********************************************************************
'OPTION' 'ECHO' 1 ;
'SAUTER' 'PAGE';
*
'TITRE' 'Vecteurs couleur'   ;
OPTI DIME 3 ELEM CUB8   ;
*OPTI ISOV SURFACE ;
OPTI ISOV SULI ;
*OPTI TRAC PSC ;
*
GRAPH1 = FAUX ;
************************ CAS TEST : vecoul.dgibi ******************
*******************************************************************
*
*--------------------- Création du maillage 3D ---------------------
*
EPSI1 = 0.0001 ;
*--------------------- Points du plan de base --------------
*
X1 = 10.0D0 ;
Y1 = 9.0D0 ;
Z1 = 13.5D0 ;
*
A1 = 2D0 0.0D0 0.0D0 ;
B1 = X1 0.0D0 0.0D0 ;
C1 = X1 Y1 0.0D0 ;
D1 = 0.0D0 Y1 0.0D0 ;
*
*--------------------- Lignes du plan de base --------------
*                          -- Densites --
NIV1 = 1.0 ;
NBX1 = ENTIER (NIV1 * 5) ;
NBY1 = ENTIER (NIV1 * 8) ;
NBZ1 = ENTIER (NIV1 * 6) ;
LG1 = DROIT NBX1 A1 B1 ;
LG2 = DROIT NBY1 B1 C1 ;
LG3 = DROIT NBX1 C1 D1 ;
LG4 = DROIT NBY1 D1 A1 ;
*
*----------------------- Surface plan de base --------------
*
GP1 = DALLER LG1 LG2 LG3 LG4 ;
*
*------------------------------- Volume --------------------
*
VD1 = 0.0D0 0.0D0 Z1 ;
GP2 = GP1 PLUS VD1 ;
MASSIF0 = COUL BLEU (GP1 VOLU NBZ1 GP2) ;
SI GRAPH1 ;
   TRAC CACH MASSIF0 ;
FINSI ;
*
*
*=====================================================================
*                             -- MAILLAGES QUAF --
QFTOT = CHANGE MASSIF0 QUAF ;
*
*=====================================================================
*                                 -- MODELE --
MODHYB = 'MODL' QFTOT 'DARCY' 'ANISOTROPE'     ;
XXC YYC ZZC = 'COOR' (DOMA MODHYB 'CENTRE') ;
*
*=====================================================================
*                   -- Vecteur de base --
CH1 = (NOMC 'VX' (2.0*XXC)) ET (NOMC 'VY' YYC) ET (NOMC 'VZ' ZZC) ;
CH2 = 1.0D+11 * CH1 ;
VECT1 = VECT CH2 VX VY VZ ROUG ;
AFTOT = 'ARETE' QFTOT ;
SI GRAPH1 ;
   TRAC VECT1 QFTOT AFTOT ;
FINSI ;
AMPL2 = 0.61224E-12 ;
*
VCTOT1 = @VECOUL AMPL2 CH2 ;
SI GRAPH1 ;
   TRAC VCTOT1 QFTOT AFTOT ;
FINSI ;
*
VCTOT1 = @VECOUL AMPL2 CH2 0.34 ;
SI GRAPH1 ;
   TRAC VCTOT1 QFTOT AFTOT ;
FINSI ;
*
VCTOT1 = @VECOUL AMPL2 CH2 'ALTR' 0.34 ;
SI GRAPH1 ;
   TRAC VCTOT1 QFTOT AFTOT ;
FINSI ;
*
LMOT = 'MOTS' 'VX' 'VY' 'VZ' ;
*
VCTOT1 = @VECOUL AMPL2 ('*' CH2 0.) LMOT -1. ;
SI GRAPH1 ;
   TRAC VCTOT1 QFTOT AFTOT ;
FINSI ;
*
FIN ;
*