C TCOND2    SOURCE    FANDEUR   11/07/19    21:17:30     7042           

C=======================================================================
C=                            T C O N D 2                              =
C=                            -----------                              =
C=                                                                     =
C=  Fonction :                                                         =
C=  ----------                                                         =
C=  Ce sous-programme remplit le segment DESCRipteur de la matrice de  =
C=  CONDUCTIVITE/CAPACITE (RIGIDITE) dans le cas d'un modele THERMIQUE =
C=                                                                     =
C=  Parametres :  (E)=Entree   (S)=Sortie                              =
C=  ------------                                                       =
C=   NBNN    (E)  Nombre de NOEUDS dans le type d'element considere    =
C=   ICOQ    (E)  = 0 si element MASSIF, sinon element COQUE           =
C=   IDESCR  (S)  Pointeur sur le segment DESCR                        =
C=                                                                     =
C=  Remarques :                                                        =
C=  -----------                                                        =
C=  - L'inconnue PRIMALE est la temperature 'T   ' pour les elements   =
C=    MASSIFs et 'TINF', 'TSUP' et 'T   ' dans le cas d'element COQUE. =
C=  - L'inconnue DUALE est la chaleur 'Q   ' pour les elements MASSIFs =
C=    et 'QINF', 'QSUP' et 'Q   ' dans le cas d'elements COQUEs.       =
C=  - Ces noms de composantes pourraient figurer dans BDATA.           =
C=                                                                     =
C=  Denis ROBERT, le 6 janvier 1988.                                   =
C=  Mise a jour pour les coques, P. DOWLATYARI, juin 1990.             =
C=======================================================================

      SUBROUTINE TCOND2 (ICOQ,NBNN,IDESCR)

      IMPLICIT INTEGER(I-N)
      IMPLICIT REAL*8 (A-H,O-Z)

-INC SMRIGID

      CHARACTER*4 MOTHER,MOCHAL,MOTHR1,MOTHR2,MOCHL1,MOCHL2

      PARAMETER ( MOTHER='T   ' )
      PARAMETER ( MOCHAL='Q   ' )
      PARAMETER ( MOTHR1='TINF',MOTHR2='TSUP' )
      PARAMETER ( MOCHL1='QINF',MOCHL2='QSUP' )

C  1 - Cas des elements COQUES
C =============================
      IF (ICOQ.NE.0) THEN
        NLIGRP = 3*NBNN
        NLIGRD = 3*NBNN
        SEGINI,DESCR
        NBNN2 = 2*NBNN
        DO i = 1, NLIGRP
          IF (i.LE.NBNN) THEN
            LISINC(i) = MOTHR1
            LISDUA(i) = MOCHL1
            NOELEP(i) = i
            NOELED(i) = i
          ELSE IF (i.LE.NBNN2) THEN
            LISINC(i) = MOTHER
            LISDUA(i) = MOCHAL
            j = i-NBNN
            NOELEP(i) = j
            NOELED(i) = j
          ELSE
            LISINC(i) = MOTHR2
            LISDUA(i) = MOCHL2
            j = i-NBNN2
            NOELEP(i) = j
            NOELED(i) = j
          ENDIF
        ENDDO

C  2 - Cas des elements MASSIFS
C ==============================
      ELSE
        NLIGRP = NBNN
        NLIGRD = NBNN
        SEGINI,DESCR
        DO i = 1, NLIGRP
          LISINC(i) = MOTHER
          LISDUA(i) = MOCHAL
          NOELEP(i) = i
          NOELED(i) = i
        ENDDO
      ENDIF

      SEGDES,DESCR
      IDESCR = DESCR

      RETURN
      END