* fichier : tran2.dgibi
* CAS TEST DU 91/06/24 PROVENANCE : DELA
GRAPH = 'N';
SAUT PAGE ;
*
*--------------------------------------------------------------------*
* *
* TEST TRAN2 *
* *
*--- Probl}me : *
* *
* Probl}me de Valentin : thermique transitoire lin{aire
* *
* *
*--- Description de la g{om{trie : *
* *
* A ----- B *
* | | *
* | | AB = 1. *
* | | BC = 10. *
* | | EC = 4. *
* | | *
* | | *
* F |-----| E *
* | | *
* D | | C *
* X------ -----> R *
* R=0. *
* *
* Conductivit{ isotrope : K = 1. *
* Capacit{ du mat{riau : C = 1. , RHO = 1. *
* Sur AB , temp{rature impos{e : T = 1. *
* Sur BC , convection forc{e : TE = 1. , H = 10. *
* Dans CDFE , source volumique : Q = 1. *
* Ailleurs, flux impos{ : F = 0. *
* *
*--- Calcul : *
* Calcul axisym{trique *
* Recherche de la temp{rature maximale dans le cylindre {pais *
* par une m{thode pas @ pas *
* L'{volution de la temp{rature est compar{e avec la solution *
* analytique *
* *
*--- R{sultats : *
* *
* Comparer avec le cas-test THERMX 'PLI45' *
* La temp{rature maximale doit tendre vers 1.3 *
* *
*--------------------------------------------------------------------*
*
TITRE 'PROBLEME DE VALENTIN - THERMIQUE TRANSITOIRE LINEAIRE' ;
OPTION ECHO 0 ;
OPTION DIME 2 ELEM TRI6 MODE AXIS ;
TEMPS ;
*
*--------------------- Cr{ation de la g{om{trie -------------------------
*
PD = 0. 0. ;
PC = 1. 0. ;
PB = 1. 10. ;
PA = 0. 10. ;
PE = 1. 4. ;
PF = 0. 4. ;
D1 = DROITE 4 PD PC ;
D2 = DROITE 5 PC PE ;
D3 = DROITE 4 PE PF ;
D4 = DROITE 5 PF PD ;
LIG1 = D1 ET D2 ET D3 ET D4 ;
D5 = DROITE 8 PF PA ;
D6 = DROITE 4 PA PB ;
D7 = DROITE 8 PB PE ;
LIG2 = D3 ET D5 ET D6 ET D7 ;
SURF1 = SURF LIG1 PLANE ;
SURF2 = SURF LIG2 PLANE ;
SURF3 = SURF1 ET SURF2 ;
*
SI(NEG GRAPH 'N');
TRAC SURF3 ;
FINSI;
*
*--------------- DONNEES DU PROBLEME DE THERMIQUE -----------------------
*
*------ 1 - Mod{lisation du maillage SURF3 : formulation + mat{riau
*
MOD1 = MODL SURF3 THERMIQUE ISOTROPE ;
*
*------ 2 - Cr{ation d'un CHAMELEM de sous-type CARACTERISTIQUES
*
MAT1 = MATR MOD1 K 1. 'C' 1. RHO 1. ;
*
*------ 3 - Condition de source volumique : calcul du CHPOINT
* des flux nodaux {quivalents
*
S1 = SOURCE MOD1 1. SURF1 ;
*
*------ 4 - Mod{lisation pour la formulation convection et type d'{l{ment
*
MOD2 = MODL D7 THERMIQUE CONVECTION ;
MOD3 = MODL D2 THERMIQUE CONVECTION ;
MOD4 = MOD1 ET MOD2 ET MOD3;
*
*------ 5 - Cr{ation de CHAMELEM de caract{ristiques pour la convection
*
MAT2 = MATR MOD2 H 10. ;
MAT3 = MATR MOD3 H 10. ;
MAT4 = MAT1 ET MAT2 ET MAT3;
*
*------ 6 - Blocage des temp{ratures
*
B1 = BLOQUE T D6 ;
*
*------ 7 - Valeur des temp{ratures impos{es
*
E1 = DEPI B1 1. ;
*
*------ 8 - Condition de flux nul : calcul du CHPOINT de flux
* {quivalent
*
FF1 = FLUX MOD1 0. D1 ;
*
*------ 9 - Assemblage des CHPOINTs de flux {quivalents
*
QQQ1 = S1 ET FF1 ;
*
*------ 10 - chargement
*
D69 = D7 'ET' D2;
CH_TE = 'MANU' 'CHPO' 1 D69 'TE' 1.;
PP1 = PROG 0. PAS 0.05 NPAS 50 ;
PP2 = PROG 51. * 1. ;
MEVOL1 = EVOL MANU 'TEMPS' PP1 'COEFF' PP2 ;
MEVOL2 = EVOL MANU 'TEMPS' (PROG 0. 2.) 'COEFF' (PROG 1. 1.);
CHA1 = CHAR 'Q ' QQQ1 MEVOL1 ;
CHA2 = CHAR 'TIMP' E1 MEVOL2;
CHA3 = CHAR 'TECO' CH_TE MEVOL2;
CHA4 = CHA1 ET CHA2 ET CHA3;
*
* ----- 11 - remplissage de la table de pasapas
*
ETAB = TABLE;
CHTER0 = MANU CHPO SURF3 1 T 1. ;
ETAB.'TEMPERATURES' = TABLE;
ETAB.'TEMPERATURES' . 0 = CHTER0 ;
ETAB.'MODELE' = MOD4;
ETAB.'CARACTERISTIQUES' = MAT4;
ETAB.'BLOCAGES_THERMIQUES' = B1 ;
ETAB.'CHARGEMENT' = CHA4;
ETAB.'TEMPS_CALCULES' = PROG 0.1 0.2 0.3 0.4 0.5 0.6 0.7 0.8 0.9
1. 1.1 1.2 1.3;
ETAB.'PROCEDURE_THERMIQUE' = LINEAIRE;
PASAPAS ETAB ;
*
ITER = 0 ;
ITER2= 0 ;
*
LISTT = PROG ;
TEMP1 = PROG ;
REPETER BOUC_SOR 13;
ITER = ITER + 1;
LISTT=INSERER LISTT ITER (ETAB.'TEMPS'.ITER) ;
TEMP1 =INSERER TEMP1 ITER ( MAXIMUM ( ETAB.'TEMPERATURES'.ITER ) ) ;
FIN BOUC_SOR ;
*
*----- 12 - SORTIE DES RESULTATS
*
EV1 = EVOL BLEU MANU 'TEMPS' LISTT 'TEMPERATURE' TEMP1 ;
TIME = PROG 0.1 0.200 0.300 0.400 0.500 0.600 0.700
0.800 0.900 1.000 1.100 1.200 1.300 ;
LTEM = PROG 1.076 1.135 1.179 1.212 1.236 1.253
1.266 1.276 1.282 1.287 1.290 1.293 1.295 ;
EV2 = EVOL ROUGE MANU TIME LTEM ;
TITRE ' EVOLUTION DE LA TEMPERATURE MAXIMALE ' ;
SI(NEG GRAPH 'N');
DESS (EV1 ET EV2) ;
FINSI;
TEMPS ;
* CODE DE FONCTIONNEMENT BAS{ SUR UN ECART MILIEU DE COURBE
* TEST RUDIMENTAIRE POUVANT FORT BIEN ETRE OPTIMIS{
TREF=1.253;ITERA=6;TMAX=MAXIMUM(ETAB.'TEMPERATURES'.ITERA);
RESI=ABS((TMAX-TREF)/TREF);
SI(RESI <EG 5E-2);
ERRE 0;
SINO;
ERRE 5;
FINSI;FIN;
© Cast3M 2003 - All rights reserved.
Disclaimer