Datasets examples

* fichier :  plexus1.dgibi
* CAS TEST DU 92/01/16     PROVENANCE : PLA2                                    
OPTI ECHO 1;                                                                    
OPTION REST FORMAT '/u/castem/divers/plexus1.couplage' ;                               
GRAPH='N';                                                                      
SAUT PAGE ;                                                                     
*                                                                               
************************************************************************        
*                          PLEXUS1                                              
*                                                                               
*                 CAS TEST DE L INTERFACE                                       
*                  CASTEM 2000 - PLEXUS                                         
*                                                                               
* Cet exemple permet de tester la relecture de la bande CASTEM 2000 cree        
* par PLEXUS .                                                                  
*                                                                               
*                                                                               
*************************************************************************       
*                                                                               
TITRE 'TEST DE L INTERFACE CASTEM 2000 - PLEXUS';                               
OPTIO ECHO 0 ;                                                                  
*------------- Restitution de la bande cree par PLEXUS --------                 
TEMPS ;                                                                         
RESTITUER FORMAT ;                                                              
*                                                                               
*                   TESTS DES CHPO CREES PAR PLEXUS                             
*                   ===============================                             
ND5 = NOEU 5 ;                                                                  
ND11 = NOEU 11 ;                                                                
*                                                                               
* creation d un chpo de deplacements et de vitesses                             
*              ( 2 et 3 eme sauvegarde)                                         
*                                                                               
DEPl2 = TABPLEX . 2 . DEPL ;                                                    
VITE3 = TABPLEX . 3 . VITE ;                                                    
*                                                                               
* extraction du deplacement suivant r pour le noeud no 5                        
* et de la vitesse suivant z du noeud 11                                        
*                                                                               
FD5R = EXTR DEPL2 ND5 UR ;                                                      
FV11Z = EXTR VITE3 ND11 UZ ;                                                    
*                                                                               
*                   TESTS DES MCHAML CREES PAR PLEXUS                           
*                   =================================                           
*                                                                               
CONT3 = TABPLEX . 3 . CONT ;                                                    
EPST2 = TABPLEX . 2 . EPTS ;                                                    
*                                                                               
* on extrait du champ de contrainte et du champ des defo. totales               
* la composante S_2 (resp. D_1) pour laquelle on change le nom                  
* de la composante.                                                             
*                                                                               
CHN22 = EXCO S_2 CONT3 N22 ;                                                    
CHD11 = EXCO D_1 EPST2 D11 ;                                                    
*                                                                               
* on cree un objet de type MODL , un objet de type MATR                         
*  associes a la 1 ere zone du maillage ZONE_1                                  
*                                                                               
MODL1 = MODL ZONE_1 MECANIQUE ELASTIQUE COQ2 ;                                  
CAR1 = MATR MODL1 'YOUN' 200.E3  'NU' 0. 'EPAI' 2. 'RHO' 7.8E-9 ;               
*                                                                               
* on reduit le nouveau chamelem sur la 1 ere zone du maillage ZONE_1            
*                                                                               
CHN22R=REDU CHN22 ZONE_1;                                                       
*                                                                               
* on extrait la composante N22 du 1 er sous-paquet du 1er element               
* pour le 1 er point de gauss (ds notre cas le 1 er noeud : mchaml              
*  au noeuds en sortie de PLEXUS)                                               
*                                                                               
N22_1 = EXTRAIRE CHN22R N22 1 1 1 ;                                             
TEMPS ;                                                                         
VAL1 = 1.5492E-5 ;                                                              
VAL2 = 335.39 ;                                                                 
VAL3 = 2.2031 ;                                                                 
RESI1 = ABS(( FD5R - VAL1 ) / VAL1 ) ;                                          
RESI2 = ABS(( FV11Z - VAL2 ) / VAL2 ) ;                                         
RESI3 = ABS(( N22_1 - VAL3 ) / VAL3 ) ;                                         
*                                                                               
*           CODE FONCTIONNEMENT                                                 
*           -------------------                                                 
SI((RESI1 <EG 1E-4) ET (RESI2 <EG 1E-4) ET                                      
   (RESI3 <EG 1E-4));                                                           
  ERRE  0;                                                                      
SINO;                                                                           
  ERRE  5;                                                                      
FINSI;                                                                          
FIN;