* fichier : dyna14.dgibi
***************************************
*
* TEST POUR LA SOUS-STRUCTURATION
*
* SANS UTILISATION DE BASE
*
* ASSEMBLAGE DE 2 PLAQUES
*
* D. COMBESCURE 30/09/2005
**************************************
*
*GRAPH = 'O';
GRAPH = 'N';
*
opti dime 2 elem qua4 mode plan cont;
*
nele = 1;
q0 = 0. 0. ; vz = 0. 1;
q1 = 5. 0. ; q2 = 10. 0. ;
q1b = q1 plus (0. 0.);
q3 = q0 plus vz;
q4 = q1 plus vz;
q5 = q2 plus vz;
q4b = q4 plus (0. 0.);
lig1 = d (5*nele) q0 q1 ;
sur1 = tran nele lig1 vz;
ligi0 = d nele q0 q3;
ligi1 = d nele q1 q4;
elim 0.0001 (lig1 et sur1 et ligi1 et ligi0);
lig2 = d (5*nele) q1b q2 ;
sur2 = coul (tran nele lig2 vz) rouge;
ligi1b = d nele q1b q4b;
ligi2 = d nele q2 q5;
elim 0.0001 (lig2 et sur2 et ligi2 et ligi1b);
*
* Plaque 1
*
MO1= MODL SUR1 MECANIQUE ELASTIQUE QUA4 ;
MATE1=MATR MO1 YOUNG 2.E5 NU 0.3 RHO 7.800D-3;
RIGPL1 =RIGI MATE1 MO1 ;
MASPLA1=MASS MATE1 MO1 ;
BLOQ1=(BLOQ DEPL ligi0);
RIGPLA1 = RIGPL1 et BLOQ1 ;
SPLA1=STRU RIGPLA1 MASPLA1;
Meshi1 = ligi1;
BLOQ1L=(BLOQ UX Meshi1) et (BLOQ UY Meshi1);
*
* Plaque 2
*
MO2= MODL SUR2 MECANIQUE ELASTIQUE QUA4 ;
MATE2=MATR MO2 YOUNG 2.E5 NU 0.3 RHO 7.80d-3;
RIGPL2 =RIGI MATE2 MO2 ;
MASPLA2=MASS MATE2 MO2 ;
BLOQ2=BLOQ DEPL ligi2;
Meshi2 = ligi1b;
BLOQ2L=(BLOQ UX Meshi2) et (BLOQ UY Meshi2);
RIGPLA2 = RIGPL2 et BLOQ2 ;
* Liaison
LIUX = RELA ux Meshi1 - ux Meshi2 ;
LIUY= RELA UY Meshi1 - UY Meshi2;
ENCL = (LIUX et LIUY);
*
* mode propre Plaque 1
*
MODPLA1=VIBR PROC (prog 0.) (lect 1)
(RIGPLA1 et BLOQ1L) MASPLA1 tbas;
* RIGPLA1 MASPLA1 tbas;
def1 = MODPLA1. MODES . 1 . DEFORMEE_MODALE;
frq1 = MODPLA1. MODES . 1 . FREQUENCE;
defdyn11 =exco def1 (mots UX UY) (mots UX UY);
si (ega graph 'O');
trac (defo sur1 defdyn11);
finsi;
*
*
* mode propre
MODPLA2=VIBR PROC (prog 0.) (lect 1)
(RIGPLA2 et BLOQ2L) MASPLA2 TBAS;
*
def2 = MODPLA2. MODES . 1 . DEFORMEE_MODALE;
defdyn21 =exco def2 (mots UX UY) (mots UX UY);
si (ega graph 'O');
trac (defo sur2 defdyn21);
finsi;
*
nlab1 = nbno Meshi1;
REPETER LAB1 nlab1;
i = &lab1;
si (i ega 1);
meshlia1 = (Meshi1 poin i) ;
sinon;
meshlia1 = meshlia1 et (Meshi1 poin i);
finsi;
FIN LAB1;
nlab2 = nbno Meshi2;
REPETER LAB2 nlab2;
i = &lab2;
si (i ega 1);
meshlia2 = (Meshi2 poin i) ;
sinon;
meshlia2 = meshlia2 et (Meshi2 poin i);
finsi;
FIN LAB2;
*
tblsta1 = idli BLOQ1L meshlia1;
bliaiq1 = bloque tblsta1 ;
depi tblsta1;
*
tblsta2 = idli BLOQ2L meshlia2;
bliaiq2 = bloque tblsta2 ;
depi tblsta2;
nt2 = (dime tblsta2) - 1;
*
* solutions statiques
resout (RIGPLA1 et bliaiq1) (tblsta1) ;
resout (RIGPLA2 et bliaiq2) (tblsta2) ;
reac bliaiq1 tblsta1;
reac bliaiq2 tblsta2;
*
si (ega graph 'O');
repeter lab2 ((dime tblsta1) - 1);
defsta1 = exco (tblsta1. &lab2 . DEFORMEE)
(mots UX UY) (mots UX UY);
trac (defo (sur1 et sur2) defsta1);
defsta2 = exco (tblsta2. &lab2 . DEFORMEE)
(mots UX UY) (mots UX UY);
trac (defo (sur1 et sur2) defsta2);
fin lab2;
finsi;
*
rigtot1 = rigi tblsta1 modpla1;
mastot1 = mass tblsta1 modpla1 MASPLA1;
*
rigtot2 = rigi tblsta2 modpla2;
mastot2 = mass tblsta2 modpla2 MASPLA2;
*
ENCLP = PJBA ENCL (tblsta1 et tblsta2);
RIGMO = rigtot1 et rigtot2 et ENCLP;
MASMO = mastot1 et mastot2;
*
* Avec sous-structuration - modes propres bloques + modes statiques
*
*
SOLTSS = VIBR PROC (PROG 0.1) (lect 4) RIGMO MASMO TBAS;
*
*
* Base libre-libre sans mode statique
*
*MODPLA1L=VIBR PROC (prog 0.) RIGPLA1 MASPLA1 TBAS;
*MODPLA2L=VIBR PROC (prog 0.) RIGPLA2 MASPLA2 TBAS;
*MODPLAL=VIBR PROC (prog 0.) (lect 2) (RIGPLA1 et RIGPLA2)
* (MASPLA1 et MASPLA2) TBAS;
*ENCLPL = PJBA ENCL (MODPLAL);
*RIGMOL = PJBA (RIGPLA1 et rigpla2) (MODPLAL);
*MASMOL = PJBA (MASPLA1 et MASPLA2) (MODPLAL);
*
* Avec sous-structuration - modes propres libres sans mode statiqu
*
*SOLTSSL = VIBR PROC (PROG 0.1) (lect 4) RIGMOL MASMOL TBAS;
*
*
* Calcul du système complet sans sous-structuration
*
*
SOLTT = VIBR PROC (PROG 0.) (lect 4) (RIGPLA2 et RIGPLA1 et ENCL)
(MASPLA2 et MASPLA1) TBAS;
*
si (ega graph 'O');
repeter lab1 4;
i=&lab1;
dp1_t1 = exco (reco (SOLTSS . modes . i . DEFORMEE_MODALE)
(tblsta1) (modpla1)) (mots UX UY) (mots UX UY) nature discret;
dp1_t2 = exco (reco (SOLTSS . modes . i . DEFORMEE_MODALE)
(tblsta2) (modpla2)) (mots UX UY) (mots UX UY) nature discret;
fr1_ss = SOLTSS. MODES . i . FREQUENCE;
mess 'Avec sous-structuration';
list fr1_ss;
trac (defo (sur1 et sur2) (dp1_t1 et dp1_t2));
*
dp1_tot = SOLTT. MODES . i . DEFORMEE_MODALE;
fr1_tot = SOLTT. MODES . i . FREQUENCE;
mess 'Structure complete';
list fr1_tot;
trac (defo (sur1 et sur2) dp1_tot);
fin lab1;
finsi;
*
fr1_ss = SOLTSS. MODES . 1 . FREQUENCE;
fr1_tt = SOLTT. MODES . 1 . FREQUENCE;
erel = (fr1_ss - fr1_tt)/fr1_tt;
SI (erel < 0.05);
ERRE 0;
SINON;
ERRE 5;
FINSI;
*
FIN;
*
*
© Cast3M 2003 - All rights reserved.
Disclaimer