Datasets examples

* fichier :  vibr11.dgibi
*************************************************
*  TEST : VIBR11                                *
*                                               *
*   Calcul de la reponse au balourd             *
*   Test de l'option 'BALOU de l'operateur      *
*   VIBC                                        *
*************************************************
OPTI 'DIME' 3 'ELEM' SEG2 ;
*
*donnees
m1 = 50. ;
k1 = 1.e4 ;
c1 = 100. ;
f1 = ((k1 / m1) ** 0.5) / (2. * pi) ;
m2 = 100. ;
k2 = 4.e4 ;
c2 = -200. ;
f2 = ((k2 / m2) ** 0.5) / (2. * pi) ;
MESS 'f1, f2 =' f1 f2 ;
*
P1 = 0. 0. 0. ;
P2 = 1. 0. 0. ;
P3 = 2. 0. 0. ;
L1 = P1 DROI P2 1 ;
L2 = P2 DROI P1 1 ;
*
TR1 = P1 ET P2 ET P3 ;
*
*deformees modales :
Phi1 = MANU 'CHPO' TR1 2 'UY' (PROG 1. 1. 1.) 
                         'UZ' (PROG 0. 0.5 1.) ;
Phi2 = MANU 'CHPO' TR1 2 'UY' (PROG -1. 1. 2.)
                         'UZ' (PROG 0.5 2. 1.) ;
*
*points reperes des modes
PR1 = 0. 0. 0. ;
PR2 = 0. 0. 0. ;
PR3 = 0. 0. 0. ;
PR4 = 0. 0. 0. ;
*
*base des mods reels :
TBasR = TABLE 'BASE_MODALE' ;
TBasR.MODES = TABLE 'BASE_DE_MODES' ;
TBasR.MODES . 'MAILLAGE' = TR1 ;
TBasR.MODES . 1 = TABLE 'MODE' ;
TBasR.MODES . 1 . 'NUMERO_MODE' = 1 ;
TBasR.MODES . 1 . 'POINT_REPERE' = PR1 ;
TBasR.MODES . 1 . 'FREQUENCE' = f1 ;
TBasR.MODES . 1 . 'MASSE_GENERALISEE' = m1 ;
TBasR.MODES . 1 . 'DEPLACEMENTS_GENERALISES' =
  k1 - (2 * pi * f1) ;
TBasR.MODES . 1 . 'DEFORMEE_MODALE' = Phi1 ;
*
TBasR.MODES . 2 = TABLE 'MODE' ;
TBasR.MODES . 2 . 'NUMERO_MODE' = 2 ;
TBasR.MODES . 2 . 'POINT_REPERE' = PR2 ;
TBasR.MODES . 2 . 'FREQUENCE' = f2 ;
TBasR.MODES . 2 . 'MASSE_GENERALISEE' = m1 ;
TBasR.MODES . 2 . 'DEPLACEMENTS_GENERALISES' =
  k2 - (2 * pi * f2) ;
TBasR.MODES . 2 . 'DEFORMEE_MODALE' = Phi2 ;
*
*vitesse (rad/s)
omeg1 = 10. ;
*
El1 = MANU 'SUPER' (PR1 ET PR2) ;
*-matrices de masse et de raideur projetee sur la base réelle :
MMasP = MANU 'RIGI' El1 (MOTS 'ALFA')
             (PROG m1 0. 0. m2) ;
MRigP = MANU 'RIGI' El1 (MOTS 'ALFA')
             (PROG k1 0. 0. k2) ;
MAmoP = MANU 'RIGI' El1 (MOTS 'ALFA')
             (PROG 0. c1 c2 0.) ;
*
*-force d'excitation du balourd projetee sur la base réelle :
  PjFBal1 = MANU 'CHPO' (PR1 ET PR2 ET PR3 ET PR4) 1 'FALF'
             (PROG 1000. 2000. -1000. -2000.) ;
*
*-calcul de la reponse :
  RepRe1 RepIm1 = VIBC 'BALOU' MMasP MRigP MAmoP TBasR
                       PjFBal1 omeg1 ;
*
* Phi1y = 1. 1. 1.
* Phi1z = 0. 0.5 1.
* Phi2y = -1. 1. 2.
* Phi2z = 0.5 2. 1.
*
*  | k1-w^2*m1      0        0       -w*c1   | | q1s |   |  1000. | 
*  |     0     k2-w^2*m2    w*c2       0     | | q2s |   |  2000. | 
*  |     0        w*c1   k1-w^2*m1     0     | | q1c | = | -1000. | 
*  |  -w*c2         0        0     k2-w^2*m2 | | q2s |   | -2000. | 
*
* q1s = 28000/148000  = 0.1892
* q2s =  6000/74000   = 0.0811
* q1c = 32000/-148000 = -.2162
* q2c = -4000/74000   = -.0541
*
* YR = Phi1y*q1c + Phi2y*q2c
* YI = Phi1y*q1s + Phi2y*q2s
* ZR = Phi1z*q1c + Phi2z*q2c
* ZI = Phi1z*q1s + Phi2z*q2s
*
YR1 = EXCO 'UY' RepRe1 ;
ZR1 = EXCO 'UZ' RepRe1 ;
YI1 = EXCO 'UY' RepIm1 ;
ZI1 = EXCO 'UZ' RepIm1 ;
*
* YR1 = q1c - q2c / q1c + q2c / q1c + 2q2c =
* YR1 = 1 -1.62162E-01    2   -2.70270E-01    3   -3.24324E-01 
LIST YR1 ;
*
* YI1 = q1s - q2s / q1s + q2s / q1s + 2q2s =
* YI1 = 1  1.08108E-01    2    2.70270E-01    3    3.51351E-01
LIST YI1 ;
*
* ZR1 = 0.5*q2c / 0.5*q1c + 2q2c / q1c + q2c =
* ZR1 = 1 -2.7027E-02     2   -2.16216E-01    3   -2.70270E-01
LIST ZR1 ;
*
* ZI1 = 0.5*q2s / 0.5*q1s + 2q2s / q1s + q2s =
* ZI1 = 1  4.05405E-2     2    2.56757E-01    3    2.70270E-01
LIST ZI1 ;
*
FIN ;