* fichier : vpla3.dgibi
GRAPH = 'N';
SAUT PAGE ;
complet = faux;
*********************************************$
* pour test complet mettre complet à ; vrai
*********************************************$
*
*------------------------------------------------------------------------
* Sortie du domaine {lastique et phase visco-plastique
* comportement visco-plastique - modele Guionnet - cas axisymetrique
* cylindre creux soumis a pression interne constante et
* deformation axiale imposee cyclique variant de
* 0.35% a -0.35%
* comparaison des boucles sigma axiale fonction de deformation axiale avec
* resultats experimentaux (rapport DMT/93-434)
* comparaison de la deformation circonferentielle progressive en fonction
* du nombre de cycles avec resultats experimentaux
*------------------------------------------------------------------------
OPTION ECHO 0 ;
opti dime 2 elem qua8 mode axisymetrique ;
*
* -----definition de la geometrie
*
ray=8.; ep=2.; long=ep;
p0 = ray 0. ;
p1 = ray long ;
p2 = (ray+ep) long ;
p3 = (ray+ep) 0. ;
*
s01 = p0 droit 1 p1 ;
s12 = p1 droit 1 p2 ;
s23 = p2 droit 1 p3 ;
s30 = p3 droit 1 p0 ;
pout = daller s01 s12 s23 s30 'PLAN' ;
*
* -----definition des conditions aux limites-----
* ----- et des deplacements imposes -----
*
cl1 = bloq uz s12 ;
cl2 = bloq uz s30 ;
*
cl = cl1 et cl2 ;
*
deltal=long*0.35E-2;
fl1 = depi cl1 deltal ;
*
mo = modl pout 'MECANIQUE' 'ELASTIQUE' 'VISCOPLASTIQUE' 'GUIONNET' ;
ma = matr mo 'YOUN' 192500. 'NU ' 0.3 'N ' 24 'K ' 200.
'CK ' 0. 'R0 ' 25. 'CD ' 0. 'M ' 0.8
'A ' 24000. 'A1 ' 3.3E5 'C ' 180. 'C1 ' 40.
'G ' 0. 'R ' 0. 'NN ' 0.005 'C2 ' 40.
'Q ' 1.466 'G1 ' 0. 'R1 ' 0. 'BETA' 1.1
'C0 ' 180. 'P1M0' 0.00333 ;
*
* -----chargement en traction/compression
*
* montee en charge et 1er cycle
*
l1 = prog 0. 1. 3. 5. ;
l2 = prog 0. 1. -1. 1. ;
*
* au total 10 cycles
*
si complet;
repeter stru1 9;
nl1 = dime l1 ;
x = extr l1 nl1 ;
l1 = l1 et (prog (x+2.) (x+4.)) ;
l2 = l2 et (prog -1 1) ;
fin stru1 ;
finsi;
*
ev = evol manu 't' l1 'ft' l2 ;
*
cha1 = char 'DIMP' fl1 ev ;
*
* -----chargement en pression
*
lp1 = prog 0. 1. 100000.0 ;
lp2 = prog 0. 1. 1.0 ;
*
ev = evol manu 't' lp1 'ftp' lp2 ;
*
fl2 = press 'MASS' mo 21.5 s01 ;
*
cha2 = char MECA fl2 ev ;
*
cha = cha1 et cha2 ;
*
*
* -----mise en charge
lis0 = prog .2 .3 .4 pas .05 .6 pas .02 .8 pas .01 1 ;
si complet;
* -----premier cycle
lis1 = prog 1.01 1.02 pas 0.02 1.1 pas 0.05 2.9 pas 0.02 2.98 2.99 3.
3.01 3.02 pas 0.02 3.1 pas 0.05 4.9 pas 0.02 4.98 4.99 5. ;
* -----cycle 2 a 10
nlis=dime lis1;
liscte4=prog nlis*4.;
lis2 = lis1 + liscte4;lis3 = lis2 + liscte4;lis4 = lis3 + liscte4;
lis5 = lis4 + liscte4;lis6 = lis5 + liscte4;lis7 = lis6 + liscte4;
lis8 = lis7 + liscte4;lis9 = lis8 + liscte4;lis10 = lis9 + liscte4;
*
lis = lis0 et lis1 et lis2 et lis3 et lis4 et lis5 et lis6 et lis7
et lis8 et lis9 et lis10;
sinon;
lis = lis0;
finsi;
*
TAB = TABLE ;
TAB.'PRECISION' = 1E-3;
TAB.'BLOCAGES_MECANIQUES' = cl ;
TAB.'CARACTERISTIQUES' = ma ;
TAB.'CHARGEMENT' = cha ;
TAB.'TEMPS_CALCULES' = lis ;
TAB.'MODELE' = mo ;
PASAPAS TAB ;
*
*
*+++++++++++++++++++++++++++++++++++++++++++++++++++++++
* COMPARAISON DES RESULTATS AVEC RESULTATS EXPERIMENTAUX
* RAPPORT DMT/93-434
*+++++++++++++++++++++++++++++++++++++++++++++++++++++++
*
j = 0;
progsig = prog; progeps = prog;
si complet;
lecti = lect 37 85 133 181 229 277 325 469 517 949 997;
sinon;
lecti = lect 37;
finsi;
*
*+++++++++++++++++++++++++++++++++++++++++++++++++++++++
* CONTRAINTE AXIALE EN FIN DE MONTEE EN CHARGE
* EN MILIEU ET FIN DES CYCLES 1 2 ET 3
*+++++++++++++++++++++++++++++++++++++++++++++++++++++++
*
si complet;
nfois = (dime lecti) - 4 ;
sinon;
nfois=1;
finsi;
repeter stru1 nfois;;
j = j + 1;
i = extr lecti j;
sig = tab.contraintes.i;
sig11 = extr sig smzz 1 1 9;
progsig = progsig et (prog sig11);
fin stru1;
*
*
*+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
* DEFORMATION CIRCONFERENTIELLE MOYENNE (en %) POUR CYCLES 5 ET 10
*+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
*
si complet;
repeter stru2 2;
j = j + 1;
i1 = extr lecti j ;
i2 = extr lecti (j+1);
eps_1 = epsi mo (tab.deplacements.i1);
eps_2 = epsi mo (tab.deplacements.i2);
eps22_1 = ( (extr eps_1 eptt 1 1 9) + (extr eps_1 eptt 1 1 6) +
(extr eps_1 eptt 1 1 3) ) / 3.;
eps22_2 = ( (extr eps_2 eptt 1 1 9) + (extr eps_2 eptt 1 1 6) +
(extr eps_2 eptt 1 1 3) ) / 3.;
eps22 = (eps22_1 + eps22_2) / 2. ;
progeps = progeps et (prog eps22);
j = j + 1;
fin stru2;
progeps = 100. * progeps;
finsi;
*
*+++++++++++++++++++++++++++++++++++++++++++++++++++++++
* RESULTATS EXPERIMENTAUX
* RAPPORT DMT/93-434
*+++++++++++++++++++++++++++++++++++++++++++++++++++++++
*
si complet;
progsx = prog 300 -300 330.3 -309.8 345.9 -312.8 351.9 ;
progex = prog 0.22 0.2675 ;
sinon;
progsx = prog 300 ;
finsi;
*
*++++++++++++++
* COMPARAISON
*++++++++++++++
*
err_sig = abs ( (progsig - progsx) / progsx ) ;
err_sig = maxi err_sig ;
mess err_sig;
si complet ; erradm = 0.19; sinon; erradm=0.03; finsi;
si (err_sig <EG erradm);
ERRE 0;
sinon;
ERRE 5;
finsi;
*
si complet;
err_eps = abs ( (progeps - progex) / progex ) ;
err_eps = maxi err_eps ;
si (err_eps <EG 0.16);
ERRE 0;
sinon;
ERRE 5;
finsi;
finsi;
*
fin;
© Cast3M 2003 - All rights reserved.
Disclaimer