* fichier : dy_dev11.dgibi
******************************************************************
*
* Cas-Test de la liaison palier de l'operateur DYNE
*
* Arbre rigide L=1m sur 2 paliers a 3 lobes
* Chargement dynamique des paliers Amp= 3000 N / Freq.= 100 Hz
*
******************************************************************
*
OPTI 'DIME' 3 'ELEM' SEG2 ;
*
NPas1 = 1000 ;
PTps1 = 6.25e-5/30. ;
NSor1 = 30 ;
NbMod1 = 6 ;
*
Ra1= 0.02 ;
E1 = 2.e+15 ;
Rho1 = 7800. ;
Nu1 = 0.3 ;
*
P0 = 0. 0. 0. ;
P1 = 0.5 0. 0. ;
P2 = 1. 0. 0. ;
*
El1 = DROI P0 P1 1 ;
El2 = DROI P1 P2 1 ;
Mail1 = El1 ET El2 ;
*
Modl1 = MODL Mail1 'MECANIQUE' 'TUYA' ;
*
Cara1 = CARA Modl1 'RAYO' Ra1 'EPAI' Ra1 ;
*
Mate1 = MATE Modl1 'YOUNG' E1 'NU' Nu1 'RHO' Rho1 ;
*
Blo1 = BLOQ 'UX' 'RX' 'RY' 'RZ' Mail1 ;
*
MMass1 = MASS Modl1 (Cara1 ET Mate1) ;
MRigi1 = RIGI Modl1 (Cara1 ET Mate1) ;
*
TBasR1 = VIBR 'SIMU' 10. NbMod1 (MRigi1 ET Blo1) MMass1 'TBAS' ;
NNOR TBasR1.MODES 'AVEC' (MOTS 'UY' 'UZ') ;
*
* Creation de la table des CONDITIONS INITIALES
************************************************
TInit1 = TABLE 'INITIAL' ;
*
UY0 = 0. ;
UZ0 = -0.0001e-3 ;
Dep0 = MANU 'CHPO' Mail1 2 'UY' UY0 'UZ' UZ0 NATURE DIFFUS ;
*
REPE bb1 NbMod1 ;
i1 = &bb1 ;
Def1 = TBasR1 . 'MODES' . i1 . 'DEFORMEE_MODALE' ;
M_G1 = TBasR1 . 'MODES' . i1 . 'MASSE_GENERALISEE' ;
P_R1 = TBasR1 . 'MODES' . i1 . 'POINT_REPERE' ;
qi1 = (YTMX Def1 MMass1 Dep0) / M_G1 ;
f_r1 = TBasR1 . 'MODES' . i1 . 'FREQUENCE';
mai4 = manu poi1 p_r1 ;
mo_mod4 = modele mai4 mecanique elastique modal ;
ca_mod4 = mate mo_mod4 freq f_r1 mass m_g1 defo Def1;
SI (EGA i1 1) ;
TInit1.'DEPLACEMENT' = MANU 'CHPO' P_R1 1 'ALFA' qi1 NATURE DIFFUS ;
TInit1.'VITESSE' = MANU 'CHPO' P_R1 1 'ALFA' 0. NATURE DIFFUS ;
mo_1 = mo_mod4 ; ca_1 = ca_mod4 ;
SINON ;
TInit1.'DEPLACEMENT' = TInit1.'DEPLACEMENT' ET
(MANU 'CHPO' P_R1 1 'ALFA' qi1 NATURE DIFFUS) ;
TInit1.'VITESSE' = TInit1.'VITESSE' ET
(MANU 'CHPO' P_R1 1 'ALFA' 0. NATURE DIFFUS) ;
mo_1 = mo_1 et mo_mod4 ; ca_1 = ca_1 et ca_mod4 ;
FINSI ;
FIN bb1 ;
*
* Creation de la table des LIAISONS (paliers)
**********************************************
*
TLiai1 = TABLE 'LIAISON' ;
TLiai1 . LIAISON_B = TABLE 'LIAISON_B' ;
PAL1 = TABLE 'LIAISON_ELEMENTAIRE' ;
PAL1 . TYPE_LIAISON = 'PALIER_FLUIDE' ;
PAL1 . MODELE_PALIER = RODELI ;
PAL1 . POINT_SUPPORT = P0 ;
PAL1 . LONGUEUR_PALIER = 0.01 ;
PAL1 . RAYON_ARBRE = 0.02 ;
PAL1 . VISCOSITE_FLUIDE = 0.02 ;
PAL1 . RHO_FLUIDE = 960. ;
PAL1 . PRESSION_ADMISSION = 0. ;
PAL1 . VITESSE_ROTATION = 2 * pi * 100. ;
PAL1 . EPSI = 0.;
PAL1 . PHII = 0. ;
PAL1 . AFFICHAGE = 0 ;
PAL1 . GEOMETRIE_PALIER = TABLE ;
PAL1 . GEOMETRIE_PALIER . NOMBRE_LOBES = 3 ;
PAL1 . GEOMETRIE_PALIER . CRITERE_ARRET = 1e-4 ;
PAL1 . GEOMETRIE_PALIER . 1 = TABLE ;
PAL1 . GEOMETRIE_PALIER . 1 . ASYMETRIE = 5.5 * pi / 180. ;
PAL1 . GEOMETRIE_PALIER . 1 . JEU_USINAGE = 2.e-5 ;
PAL1 . GEOMETRIE_PALIER . 1 . PRECHARGE = 0.2e-5 ;
PAL1 . GEOMETRIE_PALIER . 1 . ANGLE_DEBUT = -0.5 * pi / 180. ;
PAL1 . GEOMETRIE_PALIER . 1 . AMPL_ANGLE = 110. * pi / 180. ;
PAL1 . GEOMETRIE_PALIER . 1 . COEF_SUR = 1.715 ;
PAL1 . GEOMETRIE_PALIER . 1 . NB_MAILLES = 100 ;
PAL1 . GEOMETRIE_PALIER . 2 = TABLE ;
PAL1 . GEOMETRIE_PALIER . 2 . ASYMETRIE = 125.5 * pi / 180. ;
PAL1 . GEOMETRIE_PALIER . 2 . JEU_USINAGE = 2.e-5 ;
PAL1 . GEOMETRIE_PALIER . 2 . PRECHARGE = 0.2e-5 ;
PAL1 . GEOMETRIE_PALIER . 2 . ANGLE_DEBUT = -0.5 * pi / 180. ;
PAL1 . GEOMETRIE_PALIER . 2 . AMPL_ANGLE = 110. * pi / 180. ;
PAL1 . GEOMETRIE_PALIER . 2 . COEF_SUR = 1.715 ;
PAL1 . GEOMETRIE_PALIER . 2 . NB_MAILLES = 100 ;
PAL1 . GEOMETRIE_PALIER . 3 = TABLE ;
PAL1 . GEOMETRIE_PALIER . 3 . ASYMETRIE = 245.5 * pi / 180. ;
PAL1 . GEOMETRIE_PALIER . 3 . JEU_USINAGE = 2.e-5 ;
PAL1 . GEOMETRIE_PALIER . 3 . PRECHARGE = 0.2e-5 ;
PAL1 . GEOMETRIE_PALIER . 3 . ANGLE_DEBUT = -0.5 * pi / 180. ;
PAL1 . GEOMETRIE_PALIER . 3 . AMPL_ANGLE = 110. * pi / 180. ;
PAL1 . GEOMETRIE_PALIER . 3 . COEF_SUR = 1.715 ;
PAL1 . GEOMETRIE_PALIER . 3 . NB_MAILLES = 100 ;
*
maifl1 = manu poi1 p0 ;
mpafl1 = modele maifl1 liaison 'PALIER_FLUIDE' 'RHODE_LI';
cpafl1 = mate mpafl1 'LONG' 0.01 'RAYO' 0.02 'VISC' 0.02 'RHOF' 960.
'PADM' 0. 'VROT' (2*pi*100) 'EPSI' 0. 'PHII' 0. 'AFFI' 0
'TLOB' PAL1 . GEOMETRIE_PALIER ;
*
PAL2 = TABLE 'LIAISON_ELEMENTAIRE' ;
PAL2 . TYPE_LIAISON = 'PALIER_FLUIDE' ;
PAL2 . MODELE_PALIER = RODELI ;
PAL2 . POINT_SUPPORT = P2 ;
PAL2 . LONGUEUR_PALIER = 0.01 ;
PAL2 . RAYON_ARBRE = 0.02 ;
PAL2 . VISCOSITE_FLUIDE = 0.02 ;
PAL2 . RHO_FLUIDE = 960. ;
PAL2 . PRESSION_ADMISSION = 0. ;
PAL2 . VITESSE_ROTATION = 2 * pi * 100. ;
PAL2 . EPSI = 0.;
PAL2 . PHII = 0. ;
PAL2 . AFFICHAGE = 0 ;
PAL2 . GEOMETRIE_PALIER = TABLE ;
PAL2 . GEOMETRIE_PALIER . NOMBRE_LOBES = 3 ;
PAL2 . GEOMETRIE_PALIER . CRITERE_ARRET = 1e-4 ;
PAL2 . GEOMETRIE_PALIER . 1 = TABLE ;
PAL2 . GEOMETRIE_PALIER . 1 . ASYMETRIE = 5.5 * pi / 180. ;
PAL2 . GEOMETRIE_PALIER . 1 . JEU_USINAGE = 2.e-5 ;
PAL2 . GEOMETRIE_PALIER . 1 . PRECHARGE = 0.2e-5 ;
PAL2 . GEOMETRIE_PALIER . 1 . ANGLE_DEBUT = -0.5 * pi / 180. ;
PAL2 . GEOMETRIE_PALIER . 1 . AMPL_ANGLE = 110. * pi / 180. ;
PAL2 . GEOMETRIE_PALIER . 1 . COEF_SUR = 1.715 ;
PAL2 . GEOMETRIE_PALIER . 1 . NB_MAILLES = 100 ;
PAL2 . GEOMETRIE_PALIER . 2 = TABLE ;
PAL2 . GEOMETRIE_PALIER . 2 . ASYMETRIE = 125.5 * pi / 180. ;
PAL2 . GEOMETRIE_PALIER . 2 . JEU_USINAGE = 2.e-5 ;
PAL2 . GEOMETRIE_PALIER . 2 . PRECHARGE = 0.2e-5 ;
PAL2 . GEOMETRIE_PALIER . 2 . ANGLE_DEBUT = -0.5 * pi / 180. ;
PAL2 . GEOMETRIE_PALIER . 2 . AMPL_ANGLE = 110. * pi / 180. ;
PAL2 . GEOMETRIE_PALIER . 2 . COEF_SUR = 1.715 ;
PAL2 . GEOMETRIE_PALIER . 2 . NB_MAILLES = 100 ;
PAL2 . GEOMETRIE_PALIER . 3 = TABLE ;
PAL2 . GEOMETRIE_PALIER . 3 . ASYMETRIE = 245.5 * pi / 180. ;
PAL2 . GEOMETRIE_PALIER . 3 . JEU_USINAGE = 2.e-5 ;
PAL2 . GEOMETRIE_PALIER . 3 . PRECHARGE = 0.2e-5 ;
PAL2 . GEOMETRIE_PALIER . 3 . ANGLE_DEBUT = -0.5 * pi / 180. ;
PAL2 . GEOMETRIE_PALIER . 3 . AMPL_ANGLE = 110. * pi / 180. ;
PAL2 . GEOMETRIE_PALIER . 3 . COEF_SUR = 1.715 ;
PAL2 . GEOMETRIE_PALIER . 3 . NB_MAILLES = 100 ;
*
maifl2 = manu poi1 p2 ;
mpafl2 = modele maifl2 liaison 'PALIER_FLUIDE' 'RHODE_LI';
cpafl2 = mate mpafl2 'LONG' 0.01 'RAYO' 0.02 'VISC' 0.02 'RHOF' 960.
'PADM' 0. 'VROT' (2*pi*100) 'EPSI' 0. 'PHII' 0. 'AFFI' 0
'TLOB' PAL2 . GEOMETRIE_PALIER ;
*
*
TLiai1 . LIAISON_B . 1 = PAL1 ;
TLiai1 . LIAISON_B . 2 = PAL2 ;
*
* Creation de la table des VARIABLES DE SORTIE
***********************************************
TSort1 = TABLE 'SORTIE' ;
TSort1 . 'VARIABLE' = TABLE 'VARIABLE' ;
TSort1 . 'LIAISON_B' = TABLE 'LIAISON_B' ;
TSort1 . 'LIAISON_B' . PAL1 = VRAI ;
TSort1 . 'LIAISON_B' . PAL2 = VRAI ;
*
* Creation de la table du CHARGEMENT (chargement dynamique)
*************************************
TChar1 = TABLE 'CHARGEMENT' ;
LTps1 = PROG 0.0 'PAS' PTps1 'NPAS' (NPas1+1) ;
Freq1 = 100. ;
AmpY1 = 3000. ;
AmpZ1 = 3000. ;
LFdY1 = PROG 'SINU' Freq1 'AMPL' AmpY1 LTps1 ;
LFdZ1 = PROG 'SINU' Freq1 'PHAS' 90. 'AMPL' AmpZ1 LTps1 ;
Ev_FdY1 = EVOL MANU 'Tps' LTps1 'FdY(t)' LFdY1 ;
Ev_FdZ1 = EVOL MANU 'Tps' LTps1 'FdZ(t)' LFdZ1 ;
Chp_FdY1 = MANU CHPO 3 (P0 ET P2)
'FX' 0. 'FY' 1. 'FZ' 0. ;
Chp_FdZ1 = MANU CHPO 3 (P0 ET P2)
'FX' 0. 'FY' 0. 'FZ' -1. ;
Char_Fd1 = (CHAR Chp_FdY1 Ev_FdY1) ET (CHAR Chp_FdZ1 Ev_FdZ1) ;
*
TChar1 . 'BASE_A' = PJBA TBasR1 Char_Fd1 ;
char_fs2 = pjba char_fd1 mo_1 ca_1 ;
*
tabdyn = table 'PASAPAS' ;
tabdyn . modele = mo_1 et mpafl1 et mpafl2 ;
tabdyn . caracteristiques = ca_1 et cpafl1 et cpafl2 ;
tabdyn . sortie = table ;
tabdyn . sortie . mpafl1 = vrai ;
tabdyn . sortie . mpafl2 = vrai ;
tabdyn . chargement = char_fs2 ;
tabdyn . pas_de_temps = ptps1 ;
tabdyn . nombre_pas = npas1 ;
tabdyn . pas_de_sortie = nsor1 ;
dyne de_vogelaere tabdyn ;
* Cacul temporel : Appel a DYNE
********************************
TResu1 = DYNE 'DE_VOGELAERE' TBasR1 TChar1 TInit1 TSort1
TLiai1 PTps1 NPas1 NSor1 ;
*
Abs1 = TResu1 . PAL1 . 'UY_ARBRE' /
PAL1 . 'GEOMETRIE_PALIER'. 1 . 'JEU_USINAGE' ;
Ord1 = TResu1 . PAL1 .'UZ_ARBRE' /
PAL1 . 'GEOMETRIE_PALIER' . 1 . 'JEU_USINAGE' ;
Abs2 = TResu1 . PAL1 . 'FY_PALIER';
Ord2 = TResu1 . PAL1 . 'FZ_PALIER';
Abs11 = tabdyn . liaisons . mpafl1 . 'UY_ARBRE' /
PAL1 . 'GEOMETRIE_PALIER'. 1 . 'JEU_USINAGE' ;
Ord11 = tabdyn . liaisons . mpafl1 .'UZ_ARBRE' /
PAL1 . 'GEOMETRIE_PALIER' . 1 . 'JEU_USINAGE' ;
Abs21 = tabdyn . liaisons . mpafl1 . 'FY_PALIER';
Ord21 = tabdyn . liaisons . mpafl1 . 'FZ_PALIER';
*
OPTI ECHO 0 ;
MESS 'Resultats attendus : .69 / -.48 / -2906 / 825' ;
MESS 'Resultats calcules :' ;
MESS (EXTR Abs1 34) (EXTR Ord1 34) (EXTR Abs2 34) (EXTR Ord2 34) ;
MESS (EXTR Abs11 34) (EXTR Ord11 34) (EXTR Abs21 34) (EXTR Ord21 34) ;
err1 = (.69 - (EXTR Abs11 34))/ .69 ;
err2 = (-.48 - (EXTR Ord11 34))/ -.48 ;
err3 = (-2906 - (EXTR Abs21 34))/ -2906 ;
err4 = (825 - (EXTR Ord21 34)) / 825 ;
si (((abs err1) > 0.05) ou ((abs err2) > 0.05) ou
((abs err3) > 0.05) ou ((abs err4) > 0.05)) ;
erre 5 ;
sinon ;
erre 0 ;
finsi ;
*
FIN ;
© Cast3M 2003 - All rights reserved.
Disclaimer