Datasets examples

* fichier :  dyna9.dgibi
OPTIO ECHO 0;                                                                   
GRAPH='N';                                                                      
SAUT PAGE ;                                                                     
*                                                                               
*************************************************************************       
*                            DYNA9                                              
*                                                                               
*           CALCUL DES FREQUENCES PROPRES D'UNE PLAQUE-CONSOLE                  
*                                                                               
* Dans cet exemple on calcule les fr{quences propres d'une plaque               
* encastr{e sur un cot{ et libre sur les trois autres cot{s.                    
*                                                                               
* Les solutions calcul{es sont compar{es @ celles publi{es par                  
* M.V. BARTON dans l'article :                                                  
*                                                                               
*           VIBRATIONS OF RECTANGULAR AND SHEAR PLATES                          
*           JOU. OF APPL. MECH. , VOL.18 , 1951                                 
*                                                                               
*************************************************************************      
*
TITRE 'FREQUENCES PROPRES D UNE PLAQUE CONSOLE' ;

OPTION DIME 3 ELEM QUA4 ;

TEMPS ;
*
*------------------------- GEOMETRIE ------------------------------------
*
P0 = 0 0 0 ;
P1 = 0 1 0 ;
P2 = 2 1 0 ;
P3 = 2 0 0 ;
L1 = D 8 P0 P1 ;
L2 = D 16 P1 P2 ;
L3 = D 8 P2 P3 ;
L4 = D 16 P3 P0 ;
S = L1 L2 L3 L4 DALL PLAN ;
*
OEIL1 = 10 10 10 ;
*
SI (NEG GRAPH 'N');
TRAC OEIL1 S ;
FINSI;
*
*------------------------- MATERIAU -------------------------------------
*
MM = MODL S MECANIQUE COQ4 ;

MA = MATR MM YOUN 30E6 NU 0.3 RHO 7.32E-4 ;
CA = CARB MM EPAI 0.01 ;
MA =MA ET CA;
*
*-------------- CONDITIONS AUX LIMITES - CALCUL DES MATRICES ------------
*
INC = BLOQ DEPL ROTA L1 ;
K = RIGI MM MA ;
KT = K ET INC ;
M = MASS MM MA;
*
*------------------------ CALCUL ----------------------------------------
*
PROG1 = PROG 85. 360. 530. 1200. ;
AUTO = VIBR PROCHE PROG1 KT M ;
*
*
*-------------------------- TRACE ET SORTIES ----------------------------
*
F1  = (TIRE AUTO FREQ NUME 1) ;
F2  = (TIRE AUTO FREQ NUME 2) ;
F3  = (TIRE AUTO FREQ NUME 3) ;
F4  = (TIRE AUTO FREQ NUME 4) ;
*
SAUT PAGE ; SAUT 2 LIGNE ;
*
MESS ' MODE 1     FREQUENCE THEORIQUE 84.6       CALCULEE ' F1 ;
MESS ' MODE 2     FREQUENCE THEORIQUE 363.8      CALCULEE ' F2 ;
MESS ' MODE 3     FREQUENCE THEORIQUE 526.6      CALCULEE ' F3 ;
MESS ' MODE 4     FREQUENCE THEORIQUE 1187       CALCULEE ' F4 ;

*---------------- CODE DE FONCTIONNEMENT --------------------------------

ERR1=100*((ABS(84.6 -F1)/84.6));
ERR2=100*((ABS(363.8 -F2)/363.8 ));
ERR3=100*((ABS(526.6 -F3)/526.6 ));
ERR4=100*((ABS(1187 -F4)/1187));
ERRMAX=MAXI (PROG ERR1 ERR2 ERR3 ERR4);
SI (ERRMAX < 5);
ERRE 0;
SINON;
ERRE 5;
FINSI;

SAUT 2 LIGN ;
TEMPS ;
FIN;