Procedures | Cast3M

   1 : * RAMBERG   PROCEDUR  VALETA    95/02/14    21:15:07     1480           
   2 : 'DEBP' RAMBERG  TAB1*'TABLE';
   3 : ****************************************************
   4 : ***** Determination des coef de Ramberg-Osgood *****
   5 : ****************************************************
   6 : 
   7 : **************** Procedure RAMBERG ************************************
   8 : ***** PARAMETRES D'ENTREE
   9 : ***** -------------------
  10 : ***** TAB1.'COURBE_TRACTION' : evolution de la courbe de traction SIGMA
  11 : *****                          en fct de EPSI
  12 : ***** TAB1.'EPS0'   : flottant -> valeur de la deformation d'un point 
  13 : *****                 de la courbe de traction.
  14 : ***** TAB1.'SIG0'   : flottant -> valeur de la contrainte d'un point de la
  15 : *****                 courbe de traction.
  16 : *****
  17 : ***** PARAMETRES DE SORTIE
  18 : ***** ---------------------
  19 : ***** TAB1.'COURBE_RAMBERG' : evolution de la courbe de traction 
  20 : *****                         sous la forme Ramberg - Osgood
  21 : ***** TAB1.'ALPHA' : coefficient alpha de la loi de Ramberg - Osgood
  22 : ***** TAB1.'N' : valeur de la puissance de la loi de Ramberg - Osgood
  23 : ***********************************************************************
  24 : COURBE = TAB1.'COURBE_TRACTION';
  25 : EPS0 = TAB1.'EPS0';
  26 : SIG0 = TAB1.'SIG0';
  27 : 
  28 : sigm = 'EXTR' COURBE 'ORDO';
  29 : epsi = 'EXTR' COURBE 'ABSC';
  30 : Nb = 'DIME' sigm;
  31 : 
  32 : ***** Calcul des valeurs Ai,Bi et Nb
  33 : LA = 'LOG' ((epsi / eps0) - (sigm / sig0));
  34 : LB = 'LOG' ( sigm / sig0 );
  35 :  
  36 : ***** Calcul des sommes
  37 : i    = 0;
  38 : SAi  = 0.;
  39 : SBi  = 0.;
  40 : SBi2 = 0.;
  41 : SABi = 0.;
  42 : SAi2 = 0.;
  43 : REPETER Boucle Nb;
  44 :    i    = i+1;
  45 :    Ai   = 'EXTR' LA i;
  46 :    Bi   = 'EXTR' LB i;
  47 :    SAi  = SAi + Ai;
  48 :    SBi  = SBi + Bi;
  49 :    SBi2 = SBi2 + (Bi ** 2);
  50 :    SAi2 = SAi2 + (Ai ** 2);
  51 :    SABi = SABi + (Ai * Bi);
  52 : 'FIN' Boucle;
  53 : S2Bi = SBi ** 2;
  54 : S2Ai = SAi ** 2;
  55 : 
  56 : ***** Calcul des coef Beta , n et Alpha
  57 : n = (SABi - ((SAi * SBi) / Nb)) / (SBi2 - (S2Bi / Nb));
  58 : Beta = (SAi - (n * SBi)) / Nb;
  59 : Alph = 'EXP' Beta ;
  60 : 
  61 : ***** Courbe Ramberg - Osgood
  62 : epss = EPS0 * ((sigm / SIG0) + (Alph * (( sigm / SIG0)**n)));
  63 : COURBS = evol manu 'EPS' epss 'SIG' sigm;
  64 : 
  65 : ***** Calcul du coefficient d'ajustement
  66 : aju = (SABi - ((SAi * SBi) / Nb)) / (SAi2 - (S2Ai / Nb));
  67 : aju = aju * n;
  68 : 
  69 : ***** Sortie resultats
  70 : MESS 'ALPHA = ' Alph;
  71 : MESS 'n     = ' n;
  72 : MESS 'coefficient d ajustement = ' aju;
  73 : SI (AJU < 0.95);
  74 :    MESS 'ATTENTION COEFFICIENT D AJUSTEMENT < 0.95';
  75 : FINSI;
  76 : 
  77 : ***** Stockage des resultats
  78 : TAB1.'ALPHA' = Alph;
  79 : TAB1.'N' =  n;
  80 : TAB1.'COURBE_RAMBERG' = COURBS;
  81 : TAB1.'AJUSTEMENT' = aju;
  82 : 
  83 : 'FINP' TAB1;