Download ouvfiss.procedur

Back to the list

   1 : * OUVFISS   PROCEDUR  AM        12/12/20    21:15:21     7631           
   2 : 
   3 : DEBP OUVFISS TAB1*TABLE IPAS/ENTIER OPT1/MOT;
   4 : *
   5 : * Procédure OUVFISS Christian La Borderie & M. Matallah
   6 : * Cette procédure permet de calculer l'ouverture de fissure à
   7 : * Partir de la table de calcul PASAPAS si le modèle utilisé est
   8 : * Régularisé par la méthode de Hillerborg
   9 : * Les résultats sont dans tab1.ouv
  10 : *
  11 : * Améliorations à apporter : 
  12 : *     utilisation de l'opérateur taille (à valider sur l'ensemble des élémen
  13 : *     identification de l'ouverture normale et du glissement
  14 : *
  15 : *
  16 : * Si vous utilisez cette procédure, vous êtes priés de citer :
  17 : * M. Matallah, C La Borderie and O. Maurel 
  18 : *  'A practical method to estimate crack openings in concrete structures'
  19 : *  International Journal for Numerical and Analytical Methods in Geomechanics, 2
  20 : *  doi:10.1002/nag.876
  21 : 
  22 : *
  23 : *
  24 : *
  25 :   SI ('EGA' OPT1  'TR');
  26 :     LTRA=VRAI;
  27 :     MESSAGE ' Extraction de la trace de l ouverture de fissure';
  28 :   SINON;
  29 :     LTRA=FAUX;
  30 :     LPRIN=FAUX;
  31 :     MESSAGE ' Extraction du tenseur d ouverture de fissure';
  32 :     SI ('EGA' OPT1 'PRIN');
  33 :       LPRIN=VRAI;
  34 :       MESSAGE 'Calcul des valeurs principales';
  35 :     FINSI;
  36 :   FINSI;
  37 :    IDIM=VALE DIME;
  38 :    SI ('EGA' IDIM 2);
  39 :         MOD1='EXTR' TAB1.MODELE 'ELEM' 'TRI3' 'QUA4' 'TRI6' 'QUA8' ;
  40 :    SINON; SI ('EGA' IDIM 3);
  41 :         MOD1='EXTR' TAB1.MODELE 'ELEM' 
  42 :              'CUB8' 'CU20' 'PRI6' 'PR15' 'PYR5' 'PY13' 'TET4' 'TE10';
  43 :         SINON;
  44 :             ERREUR 'La dimension doit être égale à 2 ou 3';
  45 :             QUITTER OUVFISS;
  46 :         FINSI;
  47 :    FINSI;      
  48 :    CHAM1='MANU' 'CHML' MOD1 'SCAL' 1. 'TYPE' 'DEFORMATIONS' 'STRESSES';
  49 :    CHAM2='INTG' CHAM1 MOD1 'ELEM' 'SCAL';
  50 :    CHAM3='CHAN' 'STRESSES' MOD1 CHAM2 'CHAN' 'TYPE' 'DEFORMATIONS';
  51 :    CHH=CHAM3**(1./(VALE DIME)) ;
  52 :    MAT1='REDU' TAB1 . 'CARACTERISTIQUES' MOD1;
  53 :    MAILL1='EXTR' MOD1 'MAILL';
  54 :    SI (EXISTE IPAS);
  55 :      N1=1;
  56 :      MESSAGE 'Pour le pas numéro ' IPAS;
  57 :    SINON;
  58 :       LECT1='INDEX' (TAB1.TEMPS);
  59 :       N1='DIME' LECT1;
  60 :       MESSAGE 'Pour tous les pas de temps de la table';
  61 :    FINSI;
  62 :    TAB1.OUV='TABLE';
  63 :    REPETER BOU1 N1; 
  64 :      SI (EXISTE IPAS);
  65 :        I=IPAS;
  66 :      SINON;
  67 :         I=LECT1 . &BOU1;
  68 :      FINSI;  
  69 :      DEP1='REDU' TAB1.DEPLACEMENTS.I MAILL1; 
  70 :      EPS1='EPSI' TAB1.DEPLACEMENTS.I MOD1;
  71 :      SIG1='REDU' TAB1.CONTRAINTES.I MOD1;
  72 :      SIG0I='ELAS' EPS1 MOD1 MAT1;
  73 :      SIGAN=SIG0I - SIG1;
  74 :      OUF0='ELAS' SIGAN MOD1 MAT1;
  75 :      LM1=EXTR OUF0 COMP;
  76 :      NCOMP=DIME LM1;
  77 :      LM2=MOTS;
  78 :      REPETER BOUCOMP NCOMP;
  79 :        LM2=INSE LM2  &BOUCOMP 'SCAL';
  80 :      FIN BOUCOMP;
  81 :      OUF1=OUF0 * CHH LM1 LM2 LM1;
  82 :      SI LTRA;
  83 :        SI (IDIM EGA 2);
  84 :           TROUF1=(('EXCO' OUF1 'EPXX' 'SCAL')
  85 :              +('EXCO' OUF1 'EPYY' 'SCAL')) ;
  86 :        FINSI;
  87 :        SI (IDIM EGA 3);
  88 :           TROUF1=(('EXCO' OUF1 'EPXX' 'SCAL')
  89 :             +('EXCO' OUF1 'EPYY' 'SCAL') +
  90 :              ('EXCO' OUF1 'EPZZ' 'SCAL'));
  91 :        FINSI;
  92 :        TAB1.OUV . I=TROUF1;
  93 :      SINON;
  94 :       SI LPRIN;
  95 :         OUF2=PRIN OUF1 MOD1;
  96 :         TAB1.OUV . I=OUF2;
  97 :       SINON;
  98 :         TAB1.OUV . I=OUF1;
  99 :       FINSI;    
 100 :      FINSI;
 101 :      I=I+1;
 102 :   FIN BOU1;
 103 : FINP;
 104 :  

© Cast3M 2003 - All rights reserved.
Disclaimer