Procedures | Cast3M

   1 : * @LAMAT    PROCEDUR  KK2000    99/11/30    21:15:16     3720           
   2 : *
   3 : ************************************************************************
   4 : *                        PROCEDURA @LAMAT
   5 : ************************************************************************
   6 : *
   7 : * Descrizione : permette di ottenere, secondo il tipo di omogeneizzazion
   8 : *               richiesta:
   9 : *               - la matrice di Hooke omogeneizzata e le caratteristiche
  10 : *                 equivalenti (se TAB_LAM.'TIPO'='OMOG')
  11 : *               - gli oggetti di tipo MATERIAU e CARACTER relativi ad
  12 : *                 ogni lamina eccentrica (se TAB_LAM.'TIPO'='MLAY')
  13 : *
  14 : * Sintassi    : TAB_MAT = @LAMAT  TAB_LAM  NZONE ;
  15 : *
  16 : *
  17 : * Autore/Data : Miliozzi A.  10/04/1997
  18 : *
  19 : * Revisioni   : Miliozzi A.  3/06/1999 - estensione omog a coq4
  20 : *
  21 : ************************************************************************
  22 : *
  23 : *--- INPUT
  24 : *=========
  25 : *
  26 : * TAB_LAM  Tavola delle caratteristiche del laminato
  27 : *
  28 : * NZONE    Entier che specifica il numero della zona sulla
  29 : *          quale effettuare il calcolo
  30 : *
  31 : *--- OUTPUT
  32 : *==========
  33 : *
  34 : * TAB_MAT   Tavola degli oggetti MATERIAU o MAHOOK e CARACTER per la
  35 : *           i-esima zona (indici MAT e CAR).
  36 : *
  37 : ************************************************************************
  38 : *
  39 : DEBPROC @LAMAT  TL*TABLE NZONE*ENTIER ;
  40 : *
  41 : TT      = TL.NZONE;
  42 : TIP1    = TL.TIPO ;
  43 : OBJ     = TT.MOD1 ;
  44 : MET     = TT.METRIF;
  45 : TTM     = TL.MCOL ;
  46 : *
  47 : TM      = TABLE   ;
  48 : TM.TIPO = TIP1    ;
  49 : TM.MOD1 = OBJ     ;
  50 : TM.MAT  = TABLE   ;
  51 : *
  52 : *----------------------------------------------------------
  53 : * Controllo che non sia OMOG per elementi COQ6 COQ8
  54 : *
  55 : SI ( (EGA TIP1 'OMOG') ET ((EXIST OBJ ELEM COQ6) OU
  56 :                            (EXIST OBJ ELEM COQ8)) );
  57 :  MESS ' Error with OMOG parameter: ' ;
  58 :  MESS ' With the thick shell elements it is not possible';
  59 :  MESS ' to perform the calculation using a global HOOKE matrix';
  60 :  quitter @lamat ;
  61 : FINSI;
  62 : * ---------------------------------------------------------
  63 : *
  64 : NLAM = (DIME TT) - 6 ;
  65 : *
  66 : NN = 1 ;
  67 : REPETER LOOP1 NLAM ;
  68 : *
  69 : EP1 = TT.NN.EPA ; EX1 = TT.NN.EXC ;
  70 : AN1 = TT.NN.ANG ; ID1 = TT.NN.IDM ;
  71 : *
  72 : SI (EXIST (TT.NN) G13 ) ; G1 = TT.NN.G13  ; G2 = TT.NN.G23  ;
  73 : SINON ;                   G1 = TTM.ID1.G13; G2 = TTM.ID1.G23;
  74 : FINSI ;
  75 : *
  76 : *-----------------------------------------------------------
  77 : * Definizione del matriale per gusci spessi
  78 : *
  79 : SI ( (EXIST OBJ ELEM COQ4) OU (EXIST OBJ ELEM COQ6)
  80 :          OU (EXIST OBJ ELEM COQ8) OU (EXIST OBJ ELEM DST)) ;
  81 :   SI (EGA MET 'DIRE') ;
  82 :      MAT1 = MATE OBJ
  83 :             DIRECTION TT.DIRRIF  INCL AN1    TT.DIRNOR
  84 :             YG1  TTM.ID1.YG1  YG2 TTM.ID1.YG2
  85 :             NU12 TTM.ID1.NU12 G12 TTM.ID1.G12
  86 :             G23  G2           G13 G1
  87 :             RHO  TTM.ID1.RHO
  88 :             EPAI EP1        EXCE EX1  ;
  89 :   SINON ;
  90 :      MAT1 = MATE OBJ
  91 :             RADIAL TT.DIRRIF  INCL AN1    TT.DIRNOR
  92 :             YG1  TTM.ID1.YG1  YG2 TTM.ID1.YG2
  93 :             NU12 TTM.ID1.NU12 G12 TTM.ID1.G12
  94 :             G23  G2           G13 G1
  95 :             RHO  TTM.ID1.RHO
  96 :             EPAI EP1        EXCE EX1  ;
  97 :   FINSI ;
  98 : * ----------------------------------------------------------
  99 : 
 100 : SINON ;
 101 :   SI (EGA MET 'DIRE') ;
 102 :      MAT1 = MATE OBJ
 103 :             DIRECTION TT.DIRRIF  INCL AN1    TT.DIRNOR
 104 :             YG1  TTM.ID1.YG1  YG2 TTM.ID1.YG2
 105 :             NU12 TTM.ID1.NU12 G12 TTM.ID1.G12
 106 :             RHO  TTM.ID1.RHO
 107 :             EPAI EP1        EXCE EX1  ;
 108 :   SINON ;
 109 :      MAT1 = MATE OBJ
 110 :             RADIAL TT.DIRRIF  INCL AN1    TT.DIRNOR
 111 :             YG1  TTM.ID1.YG1  YG2 TTM.ID1.YG2
 112 :             NU12 TTM.ID1.NU12 G12 TTM.ID1.G12
 113 :             RHO  TTM.ID1.RHO
 114 :             EPAI EP1        EXCE EX1  ;
 115 :   FINSI ;
 116 : *
 117 : FINSI;
 118 : *
 119 : SI ( EGA TIP1 'OMOG')             ;
 120 :     SI (NN EGA 1)                 ;
 121 :       HOOT   = HOOKE OBJ MAT1 REFE;
 122 :       EPATOT = EP1                ;
 123 :     SINON                         ;
 124 :       HOO1   = HOOKE OBJ MAT1 REFE;
 125 :       HOOT = HOOT + HOO1          ;
 126 :       DETR HOO1                   ;
 127 :       EPATOT = EPATOT + EP1       ;
 128 :     FINSI                         ;
 129 :   SINON                           ;
 130 :     TM.MAT.NN = MAT1              ;
 131 :   FINSI                           ;
 132 : *
 133 :   NN = NN + 1 ;
 134 : *
 135 : FIN LOOP1 ;
 136 : *
 137 : SI ( EGA TIP1 'OMOG')             ;
 138 :  CAREQ     = CARA OBJ EPAI EPATOT ;
 139 :  TM.MAT.1  = HOOT                 ;
 140 :  TM.CAR    = TABLE                ;
 141 :  TM.CAR.1  = CAREQ                ;
 142 : FINSI                             ;
 143 : *
 144 : FINPROC TM                   ;
 145 : *
 146 : ************************************************************************
 147 : *                       FINE PROCEDURA @LAMAT
 148 : ************************************************************************
 149 : *
 150 : 
 151 :