* fichier : vibr4.dgibi
* CAS TEST DU 91/06/13 PROVENANCE : TEST
SAUT PAGE;
*
****************************************************************
* *
* TEST VIBR4 *
* *
* PLAQUE EPAISSE EN FORME DE LOSANGE *
* *
* Test NAFEMS numero fv22 *
* *
* On cherche les frequences et modes propres d'une plaque *
* en forme de losange d'un metre d'epaisseur. *
* *
* Les conditions aux limites imposees (voir dessin)sont *
* les suivantes : *
* - ux = uy = rz = 0 pour tout les noeuds, *
* - uz' = rx' = ry' = 0 pour les 4 cotes. *
* *
* dessin *
* ------ *
* *
* axe y' *
* | *
* | *
* | axe x' *
* P4 -----> *
* ----------------- P3 *
* axe y / / *
* | / / *
* | / / *
* | / / *
* | / / *
* | / / *
* ----------------- ---> axe x *
* P1 P2 *
* *
* |_____10.m______| *
* *
* *
* *
****************************************************************
OPTI ECHO 1;
*
OPTI DIME 3;
OPTI ELEM QUA8;
*
GRAPH = 'N';
*--------------------------------------------------------------*
* geometrie - maillage *
*--------------------------------------------------------------*
*
ALPHA = 45.; COS = COS ALPHA; SIN = SIN ALPHA;
*
P1 = 0. 0. 0.;
P2 = 10. 0. 0.;
P3 = (10. * (1 + COS)) (10. * SIN) 0.;
P4 = (10. * COS) (10. * SIN) 0.;
*
OEIL = 7. -100. 70.;
*
D12 = P1 DROI 6 P2;
D23 = P2 DROI 6 P3;
D34 = P3 DROI 6 P4;
D41 = P4 DROI 6 P1;
*
SUR1 = DALL D12 D23 D34 D41 PLAN;
*
SI (NEG GRAPH 'N');
TRAC OEIL QUAL SUR1;
FINSI;
*
*--------------------------------------------------------------*
* modl - materiau - caracteristique *
* rigidite - masse *
*--------------------------------------------------------------*
*
MOD1 = MODL SUR1 MECANIQUE COQ8;
MAT1 = MATR MOD1 YOUN 2.E11 NU 0.3 RHO 8.E3;
CAR1 = CARB MOD1 EPAI 1.;
MAT1=MAT1 ET CAR1;
RIG1 = RIGI MOD1 MAT1 ;
MAS1 = MASS MOD1 MAT1;
*
*--------------------------------------------------------------*
* conditions aux limites *
*--------------------------------------------------------------*
*
* - ux = uy = rz = 0 pour tout les noeuds,
* - uz' = rx' = ry' = 0 pour les 4 cotes.
*
CL1 = BLOQ UX SUR1;
CL2 = BLOQ UY SUR1;
CL3 = BLOQ RZ SUR1;
*
CL4 = BLOQ UZ (D12 ET D34);
CL5 = BLOQ RX (D12 ET D34);
CL6 = BLOQ RY (D12 ET D34);
*
DIR1 = COS SIN 0.; DIR2 = (-1 * SIN) COS 0.;
CL7 = BLOQ UZ (D23 ET D41);
CL8 = BLOQ ROTA DIRECTION DIR1 (D23 ET D41);
CL9 = BLOQ ROTA DIRECTION DIR2 (D23 ET D41);
*
RIG1 = RIG1 ET CL1 ET CL2 ET CL3 ET CL4 ET CL5
ET CL6 ET CL7 ET CL8 ET CL9;
*
*--------------------------------------------------------------*
* calcul des frequences propres *
*--------------------------------------------------------------*
*
* Utilisation de l'operateur VIBR avec l'option PROC
*
FRE1 = TABLE;
FRE1.1 = 133.95;
FRE1.2 = 201.41;
FRE1.3 = 265.81;
FRE1.4 = 282.74;
FRE1.5 = 334.45;
FRE1.6 = 386.62;
*
LIST1 = PROG FRE1.1 FRE1.2 FRE1.3 FRE1.4 FRE1.5 FRE1.6;
*
RESUL1 = VIBR PROC LIST1 RIG1 MAS1;
*
*--------------------------------------------------------------*
* extraction des resultats *
*--------------------------------------------------------------*
*
FRE2 = TABLE; ERG = TABLE;
DEP = TABLE; DEF = TABLE;
*
MESS ' RESULTATS ';
MESS ' --------- ';
SAUT 1 LIGN;
*
I = 0;
REPETER BLOC1 6;
I = I + 1;
FRE2.I = TIRE RESUL1 FREQ RANG I;
ERG.I = 100 * (ABS ((FRE2.I - FRE1.I) / FRE1.I));
MESS ' MODE ' I;
MESS ' ----------';
MESS ' Frequence propre theorique :' FRE1.I 'Hz';
MESS ' Frequence propre calculee :' FRE2.I 'Hz';
MESS ' Soit un ecart de :' ERG.I '%';
SAUT 1 LIGN;
* SI (I EGA 5);
SI (NEG GRAPH 'N');
DEP.I = TIRE RESUL1 DEPL RANG I;
DEF0 = DEFO SUR1 DEP.I 0. ROUGE;
DEF.I = DEFO SUR1 DEP.I VERT;
TRAC OEIL (DEF0 ET DEF.I);
FINSI;
FINSI;
*
FIN BLOC1;
*
*--------------------------------------------------------------*
* code fonctionnement *
*--------------------------------------------------------------*
*
ERGMAX = MAXI (PROG ERG.1 ERG.2 ERG.3 ERG.4 ERG.5 ERG.6);
*
SI (ERGMAX <EG 5.);
ERRE 0;
SINON;
ERRE 5;
FINSI.
*
SAUT 1 LIGN;
TEMPS;
SAUT 1 LIGN;
*
FIN;
*
© Cast3M 2003 - All rights reserved.
Disclaimer