Procedures | Cast3M

   1 : * CHTGAU    PROCEDUR  DEGAY     95/05/11    21:15:14     1663           
   2 : DEBPROC CHTGAU TAB1*TABLE;
   3 : ********************************************************************
   4 : *  PROCEDURE CHTGAU : Calcul du champ de température créé par le   *
   5 : *              déplacement d'un arc de soudure gaussien            *
   6 : ********************************************************************
   7 : *  Entrées : TABLE :                                               *
   8 : *            'PUISSANCE' : REEL : Puissance de l'arc (en W)        *
   9 : *            'RENDEMENT' : REEL : Rendement de l'arc : Rapport de  *
  10 : *               la puissance recue par la pièce et de la puissance *
  11 : *               de l'arc                                           *
  12 : *            'DIFFUSVITE' : REEL : Diffusivité thermique du        *
  13 : *               matériau (en m2/s)                                 *
  14 : *            'CONDUCTIVITE' : REEL : Conductivité thermique du     *
  15 : *               matériau (en W/Km2)                                *
  16 : *            'VITESSE' : REEL : Vitesse de déplacement de l'arc    *
  17 : *               (en m/s)                                           *
  18 : *            'T0' : REEL : Température ambiante (en °C ou en K)    *
  19 : *            'NTERMES' : ENTIER : Nombre de termes de la somme     *
  20 : *            'MAILLAGE' : MAILLAGE : Maillage support du champ de  *
  21 : *               température                                        *
  22 : *            'EPAISSEUR' : REEL : Epaisseur de la pièce (en m)     *
  23 : *            'LOCAL' : BOOLEEN : VRAI si la pièce est décrite dans *
  24 : *               le repère local à l'arc                            *
  25 : *            'INSTANT' : REEL : Si 'LOCAL' est FAUX, instant       *
  26 : *               auquel il faut calculer le champ de température    *
  27 : *               (l'abscisse de l'arc est alors V*t) (en s)         *
  28 : *            'GAUSS' : BOOLEEN : VRAI si la source est gaussienne  *
  29 : *            'ECART-TYPE' : REEL : Ecart-type de la gaussienne     *
  30 : *               (en m)                                             *
  31 : *  Sortie  : CHPOINT : Champ de température (en °C ou en K)        *
  32 : ********************************************************************
  33 : OBJ  = TAB1.'MAILLAGE';
  34 : Q    = TAB1.'PUISSANCE';
  35 : ECT  = TAB1.'ECART-TYPE';
  36 : T0   = TAB1.'T0';
  37 : TAB1.'XPOS'      = 0.;
  38 : TAB1.'YPOS'      = 0.;
  39 : TAB1.'PUISSANCE' = 0.5*Q/3.497;
  40 : TAB1.'T0'        = 0.;
  41 : CHT              = ROSENT TAB1;
  42 : I = 0;
  43 : REPETER BOUCLE 6;
  44 :    I = I + 1;
  45 :    ANG1             = 30. + (I*60.);
  46 :    TAB1.'XPOS'      = 0.5*ECT*(COS ANG1);
  47 :    TAB1.'YPOS'      = 0.5*ECT*(SIN ANG1);
  48 :    TAB1.'PUISSANCE' = 0.3107*Q/3.497;
  49 :    CHT1             = ROSENT TAB1;
  50 :    CHT = CHT + CHT1;
  51 : FIN BOUCLE;
  52 : I = 0;
  53 : REPETER BOUCLE 6;
  54 :    I = I + 1;
  55 :    ANG1             = (I - 1)*60.;
  56 :    TAB1.'XPOS'      = ECT*(COS ANG1);
  57 :    TAB1.'YPOS'      = ECT*(SIN ANG1);
  58 :    TAB1.'PUISSANCE' = 0.1468*Q/3.497;
  59 :    CHT1             = ROSENT TAB1;
  60 :    CHT = CHT + CHT1;
  61 : FIN BOUCLE;
  62 : I = 0;
  63 : REPETER BOUCLE 6;
  64 :    I = I + 1;
  65 :    ANG1             = 30. + (I*60.);
  66 :    TAB1.'XPOS'      = 1.5*ECT*(COS ANG1);
  67 :    TAB1.'YPOS'      = 1.5*ECT*(SIN ANG1);
  68 :    TAB1.'PUISSANCE' = 0.0420*Q/3.497;
  69 :    CHT1             = ROSENT TAB1;
  70 :    CHT = CHT + CHT1;
  71 : FIN BOUCLE;
  72 : TAB1.'PUISSANCE' = Q;
  73 : TAB1.'T0' = T0;
  74 : CHT0 = OBJ MANU 'CHPO' 1 SCAL T0;
  75 : CHT = CHT + CHT0;
  76 : RESP CHT;
  77 : FINPROC;