Datasets examples

* fichier :  fronabs.dgibi
******************************************************************
*
*  test des frontieres absorbantes
*
*  on teste la reultante pour un champ de vitesses donne
*
*
***************************************************************

option dime 3 elem cub8;

E = 1.;
POIS = 0. ;
RO = 1.;

P0 = 0. 0. 0. ;
P1 = 1. 0. 0. ;
P2 = 0. 0. -1. ;

D1 = P0 DROI 5 P1 ;
D2 = P0 DROI 5 P2 ;
C1 = CERC 5 P1 P0 P2 ;

SUR1 = SURF (D1 ET D2 ET C1) PLANE ;

SOL1 = SUR1 VOLU 5 ROTA 90. ( 0.0 0.0 0.0 ) ( 0.0 0.0 1.0 ) ;

*TRAC QUAL SOL1 cach;

BOR1 = C1 ROTA 5 90. ( 0.0 0.0 0.0 ) ( 0.0 0.0 1.0 ) ;

ELIM 0.01 (BOR1 et SOL1) ;

MOD_S = MODE SOL1 MECANIQUE ; 
MAT_S1 = MATE MOD_S YOUN E NU POIS RHO RO    ;

AMOT1 = AMOR MOD_S BOR1 MAT_S1 ;

E = 2.;
POIS = 0. ;
RO = 1.;

MAT_S2 = MATE MOD_S YOUN E NU POIS RHO RO    ;

AMOT2 = AMOR MOD_S BOR1 MAT_S2 ;

X1 = COOR 1 BOR1 ;
Y1 = COOR 2 BOR1 ;
Z1 = COOR 3 BOR1 ;
X1 = NOMC 'UX' X1;
Y1 = NOMC 'UY' Y1;
Z1 = NOMC 'UZ' Z1;

DEP1 = X1 + Y1 ;
DEP1 = DEP1 + Z1 ;

RIG1 = RELA CORI DEPL SOL1 ;
RIG2 = BLOQ (P0 et P2) DEPL;
RIG3 = BLOQ P1 UY ;
F1 = DEPI RIG3 1. ;
DEP2 = RESO (RIG1 ET RIG2 et rig3 ) F1 ;

vec1 = vect dep2 ux uy uz 1. jaun ;
*trac vec1 sol1 cach ;

FOR1=RESUL (AMOT1 * DEP1);
FOR2=RESUL (AMOT2 * DEP2);
for1 = (xtx for1)**.5 ;
for2 = (xtx for2)**.5 ;
** resultat analytiques
fan1 = 3**.5 * pi / 4 ; fan2 =  2**.5 * pi / 4 ; 
err1 = for1 -  fan1 / fan1 * 100 ;
err2 = for2 -  fan2 / fan2 * 100 ;
errmax = maxi abs (prog err1 err2) ;

list errmax ;

MESS 'La résultante des forces visqueuses dues au déplacement 
radial est' FOR1;

MESS 'La résultante des forces visqueuses dues au déplacement 
tangentiel est' FOR2;

SI(errmax <EG 4.);
    ERRE 0;
SINO;
    ERRE 5;
FINSI;

FIN;