* fichier : uferdx.dgibi
SAUT PAGE ;
*********************************************************************
* Utilisation des modules CHI1 et CHI2
* avec presence de redox
*********************************************************************
OPTION DIME 2 ;
*
*
* DEFINITION DU MAILLAGE
*
n1 = 1 ;
n2 = 1 ;
a = 0.0 0.0 ;
b = 0.0 0.1 ;
c = 2. 0.1 ;
d = 2. 0. ;
*
*
option elem qua4 ;
*
ab = a droit n1 b ;
bc = b droit n2 c ;
cd = c droit n1 d ;
da = d droit n2 a ;
*
*
GP = AB BC CD DA DALL 'PLAN' ;
ELIM 0.001 GP ;
AB= CHANG POI1 AB ;
G1= CHANG POI1 GP ;
G0= DIFF G1 AB ;
*
* TABLE ENTREE DE CHI1
TABDON=TABLE ;
TABDON.IDEN= LECT 5 4 103 99 6 7 32 39 40 41 50 ;
TABDON.CLIM= TABLE ;
TABDON.CLIM . TYP6 = LECT 99 ;
TABDON.CHXMX = LECT 40007 20310 40501 32530 32520 21460
32009 32011 ;
* on rajoute 3 espèces ne figurant pas dans
* la base de données
TABDON.NVESP= TABLE ;
TABDON.NVESP.1 =TABLE ;
TABDON.NVESP.1 .IDEN= 40501 ;
TABDON.NVESP.1 .LOGK= -92.81 ;
TABDON.NVESP.1 .ITYP= 5 ;
TABDON.NVESP.1 .COMP= LECT 40 99 ;
TABDON.NVESP.1 .STOECH= PROG 1. 4. ;
TABDON.NVESP.2 =TABLE ;
TABDON.NVESP.2 .IDEN= 32530 ;
TABDON.NVESP.2 .LOGK= 13.03 ;
TABDON.NVESP.2 .ITYP= 5 ;
TABDON.NVESP.2 .COMP= LECT 32 40 50 ;
TABDON.NVESP.2 .STOECH= PROG 1. 3. -14. ;
TABDON.NVESP.3 =TABLE ;
TABDON.NVESP.3 .IDEN= 32520 ;
TABDON.NVESP.3 .LOGK= -2.46 ;
TABDON.NVESP.3 .ITYP= 5 ;
TABDON.NVESP.3 .COMP= LECT 32 40 50 ;
TABDON.NVESP.3 .STOECH= PROG 2. 1. -8. ;
*OPTION DONN 5 ;
*
TB1=CHI1 TABDON
COMP '/u/castem/divers/COMPOM' ;
*
* TABLE DES PARAMETRES DE CHI2
*OPTION DONN 5 ;
TBPAR2= TABLE ;
TBPAR2.'SOUSTYPE'='DONNEES_CHIMIQUES' ;
TBPAR2.FIONI= MANU CHPO G1 1 SCAL 0.001 ;
TBPAR2.LOGC= MANU CHPO G1 11 X005 -3. X004 -11. X103 -3. X099 -5.
X006 -10. X007 -10. X032 -10. X039 -10. X040 -10. X041 -10.
X050 -7. ;
*
* on forme le CHPOIN des concentrations totales
*
TOTNA1= MANU CHPO G1 1 X005 1.0008D-3 ;
TOTNA2= MANU CHPO AB 1 X005 (1.D-2 - 1.0008D-3) ;
TOTNA= TOTNA1 + TOTNA2 ;
TOTK1=MANU CHPO G1 1 X004 1.D-11 ;
TOTK2=MANU CHPO AB 1 X004 (1.D-5 - 1.D-11) ;
TOTK= TOTK1 + TOTK2 ;
TOTCL1=MANU CHPO G1 1 X103 1.0915D-3 ;
TOTCL2=MANU CHPO AB 1 X103 (1.0022057D-2 - 1.0915D-3) ;
TOTCL=TOTCL1 + TOTCL2 ;
TOTE1= MANU CHPO G1 1 X099 4.5619624684D-5 ;
TOTE2= MANU CHPO AB 1 X099 (1.49708535D-12 - 4.5619624684D-5) ;
TOTE= TOTE1 + TOTE2 ;
TOTFE3= MANU CHPO G1 1 X006 4.559E-5 ;
TOTFE5= MANU CHPO AB 1 X006 (1.D-8 - 4.559E-5) ;
TOTFE3= TOTFE3 + TOTFE5 ;
TOTFE2= MANU CHPO G1 1 X007 0.D0 ;
TOTU6 = MANU CHPO G1 1 X032 2.D-8 ;
TOTU = MANU CHPO AB 1 X032 ( 1.D-6 - 2.D-8) ;
TOTU6 = TOTU6 + TOTU ;
TOTU3 = MANU CHPO G1 1 X039 0.D0 ;
TOTU4 = MANU CHPO G1 1 X040 0.D0 ;
TOTU5 = MANU CHPO G1 1 X041 0.D0 ;
TOTH1= MANU CHPO G1 1 X050 -4.8578064D-7 ;
TOTH2= MANU CHPO AB 1 X050 (1.0028126D-5 + 4.8578064D-7) ;
TOTH = TOTH1 + TOTH2 ;
TBPAR2.TOT= TOTNA + TOTK + TOTCL + TOTE + TOTFE3 + TOTFE2 + TOTU6 +
TOTU5 + TOTU4 + TOTU3 + TOTH ;
TBPARM= TABLE ;
TBPARM.ITMAX = 80;
TBPARM.EPS= 1.D-6 ;
TBPARM.NFI= 4 ;
*TBPARM.ITERSOLI=15 ;
*
* on précise les elements de la table CHIMI2
* que l'on souhaite conserver
*
TBPARM.SORTIE= MOTS 'TYP5' 'PREC' 'FION' ;
*
TB3= CHI2 TB1 TBPARM TBPAR2 ;
* CONTROLE DES RESULTATS
FIONTE1=MANU CHPO G1 1 SCAL 1.13636E-03 'NATURE' DISCRET ;
FIONTE2=MANU CHPO AB 1 SCAL (1.00229E-02 - 1.13636E-03 )
'NATURE' DISCRET ;
FIONTES= FIONTE1 + FIONTE2 ;
VERR1= ( ABS ( FIONTES - TB3.FION )) MASQUE SUPERIEUR 5.D-8 SOMME ;
PRECTE1= MANU CHPO G1 8 W050 0. W051 0. W052 5.18766E-09 W053 0.
W054 0. W055 1.99605E-08 W056 0. W057 0. 'NATURE' DISCRET ;
PRECTE2= MANU CHPO AB 8 W050 0. W051 0. W052 -5.18766E-09 W053 0.
W054 0. W055 -1.99605E-08 W056 0. W057 0. 'NATURE' DISCRET ;
PRECTES= PRECTE1+PRECTE2 ;
PRECD=PRECTES / 50. ;
VERR2= ( ABS ( PRECTES - TB3.PREC )) MASQUE SUPERIEUR PRECD SOMME ;
TY5TE1= MANU CHPO AB 8 W050 8.28223E-16 W051 4.85086E-02
W052 2.07294E-03 W053 1.31814E-04 W054 1.65945E-02 W055 2.17882E-16
W056 2.31600E-180 W057 1.16045E-44 'NATURE' DISCRET ;
TY5TE2= MANU CHPO G0 8 W050 1.15633E-36 W051 8.45130E-07 W052 0.
W053 7.27012E-23 W054 9.15253E-21 W055 0. W056 7.36067E-97
W057 6.18787E-16 'NATURE' DISCRET ;
TY5TES= TY5TE1+TY5TE2 ;
TY5D= TY5TES/ 50. ;
* DANS LE CAS DES CONCENTRATIONS TRES FAIBLES
* ON ADMETTRA UNE ERREUR PLUS IMPORTANTE SUR LE RESULTAT
TT1= TY5TES MASQUE DIFFERENT 0. ;
TTT= TT1 MASQUE INFERIEUR 1.E-40 ;
TY5D= TY5D + ( TTT / 2. ) ;
VERR3= ( ABS ( TY5TES - TB3.TYP5 )) MASQUE SUPERIEUR TY5D SOMME ;
*OPTION DONN 5 ;
* TABLE ENTREE DE CHI1
TABLIM2= TABLE ;
TABLIM2. TYP3 = LECT 50 99 ;
TABDON.CLIM = TABLIM2 ;
*OPTION DONN 5 ;
TB4=CHI1 TABDON
COMP '/u/castem/divers/COMPOM'
LOGK '/u/castem/divers/COMPOM' ;
*
* TABLE ENTREE DE CHI2
*
TBPAR3= TABLE ;
TBPAR3.'SOUSTYPE'='DONNEES_CHIMIQUES' ;
TBPAR2.FIONI= MANU CHPO G1 1 SCAL 0.001 ;
TBPAR3.LOGC= MANU CHPO G1 11 X005 -3. X004 -11. X103 -3. X099 -5.
X006 -10. X007 -10. X032 -10. X039 -10. X040 -10. X041 -10.
X050 -7. ;
TBPAR3.FIONI= TB3.FION ;
PH1=MANU CHPO G1 1 W046 7.D0 ;
PH2=MANU CHPO AB 1 W046 (5.D0 - 7.D0) ;
PH=PH1+PH2 ;
PE1=MANU CHPO G1 1 W045 -7.5D0 ;
PE2=MANU CHPO AB 1 W045 (12.D0 + 7.5D0) ;
PE=PE1+PE2 ;
TBPAR3.CLIM= PH + PE ;
TOTE=MANU CHPO G1 1 X099 0.D0 ;
TOTH=MANU CHPO G1 1 X050 0.D0 ;
TBPAR3.TOT= TOTNA + TOTK + TOTCL + TOTE + TOTFE3 + TOTFE2 + TOTU6 +
TOTU5 + TOTU4 + TOTU3 + TOTH ;
TB5= CHI2 TB4 TBPARM TBPAR3 ;
* CONTROLE DES RESULTATS
FIONTE1=MANU CHPO G1 1 SCAL 1.13652E-03 'NATURE' DISCRET ;
FIONTE2=MANU CHPO AB 1 SCAL (1.00178E-02 - 1.13652E-03 )
'NATURE' DISCRET ;
FIONTES= FIONTE1 + FIONTE2 ;
FIOND= FIONTES/ 2.D5 ;
VERR4= ( ABS ( FIONTES - TB5.FION )) MASQUE SUPERIEUR FIOND SOMME ;
PRECTE1= MANU CHPO G1 8 W051 0. W052 0. W053 0. W054 0.
W055 1.99815E-08 W056 0. W057 0. W058 0. 'NATURE' DISCRET ;
PRECTE2= MANU CHPO AB 8 W051 0. W052 0. W053 0. W054 0.
W055 -1.99815E-08 W056 0. W057 0. W058 0. 'NATURE' DISCRET ;
PRECTES= PRECTE1+PRECTE2 ;
PRECD=PRECTES / 50. ;
VERR5= ( ABS ( PRECTES - TB5.PREC )) MASQUE SUPERIEUR PRECD SOMME ;
TY5TE1= MANU CHPO AB 8 W051 4.45529E-02 W052 7.02472E-04
W053 1.13068E-04 W054 1.42344E-02 W055 3.57552E-17
W056 1.39104E-182 W057 4.39903E-47 W058 1.00004E-16
'NATURE' DISCRET ;
TY5TE2= MANU CHPO G0 8 W051 1.22641E-07 W052 4.63350E-03
W053 3.16228E-23 W054 3.98107E-21 W055 0. W056 3.89045E-96
W057 2.69153E-16 W058 2.18776E-37 'NATURE' DISCRET ;
TY5TES= TY5TE1+TY5TE2 ;
TY5D= TY5TES/ 50. ;
* DANS LE CAS DES CONCENTRATIONS TRES FAIBLES
* ON ADMETTRA UNE ERREUR PLUS IMPORTANTE SUR LE RESULTAT
TT1= TY5TES MASQUE DIFFERENT 0. ;
TTT= TT1 MASQUE INFERIEUR 1.E-40 ;
TY5D= TY5D + ( TTT / 2. ) ;
VERR6= ( ABS ( TY5TES - TB5.TYP5 )) MASQUE SUPERIEUR TY5D SOMME ;
*
VERR= VERR1+VERR2+VERR3+VERR4+VERR5+VERR6 ;
SI (VERR EGA 0 ) ;
ERRE 0 ;
SINO ;
ERRE 5 ;
FINSI ;
FIN ;
© Cast3M 2003 - All rights reserved.
Disclaimer