Procedures | Cast3M

   1 : * IDENTI    PROCEDUR  BR232186  12/07/31    21:15:01     7451           
   2 : *
   3 : *
   4 : * PROCEDURE D'IDENTIFICATION DE MODELES DE COMPORTEMENT
   5 : *
   6 : *
   7 : DEBPROC IDENTI NOMMOD*MOT;
   8 : * modele MAZARS
   9 : 'SI' ('EGA' NOMMOD 'MAZARS');
  10 :    MESSAGE 'POUR LE MODELE MAZARS IL FAUT DONNER DANS L"ORDRE :';
  11 :    MESSAGE '    LE MODULE D"ELASTICITE INITIAL';
  12 :    MESSAGE '    LE COEFFICIENT DE POISSON';
  13 :    MESSAGE '    LA LIMITE EN TRACTION';
  14 :    MESSAGE '    LA CONTRAINTE RESIDUELLE EN TRACTION';
  15 :    MESSAGE '    UN INDICE DE FRAGILITE COMPRIS ENTRE 0 ET 1';
  16 :    MESSAGE '    LA LIMITE EN COMPRESSION';
  17 :    MESSAGE '    LA DEFORMATION CORRESPONDANT A CETTE LIMITE';
  18 :    'ARGU' E0*FLOTTANT;
  19 :    'ARGU' NU0*FLOTTANT;
  20 :    'ARGU' FT*FLOTTANT;
  21 :    'ARGU' SINF*FLOTTANT;
  22 :    'ARGU' FRAGI*FLOTTANT;
  23 :    'ARGU' FC*FLOTTANT;
  24 :    'ARGU' EPSC*FLOTTANT;
  25 :    EPSD0=FT/E0;
  26 :    AT=1. - ( SINF / (E0 * EPSD0));
  27 :    BT= ( 1. + FRAGI) / EPSD0 ;
  28 :    EPSC=ABS EPSC;
  29 :    FC= ABS FC;
  30 :    SQ2=2.**0.5;
  31 :    BC= 1. / ( SQ2 * NU0 * EPSC);
  32 :    AC= ( EPSD0 - ( SQ2 * FC * NU0 / E0 ) ) *
  33 :        BC / ( BC * EPSD0 - (EXP ( ( BC * EPSD0 ) - 1.)) );
  34 :    'SAUTER' 2 'LIGNE';
  35 :    'MESSAGE' '   KTR0=' EPSD0 'ATRA=' AT 'BTRA=' BT  ;
  36 :    'MESSAGE' '                        ACOM=' AC  'BCOM=' BC;
  37 :    RESPRO EPSD0 AT BT AC BC;
  38 :    'QUITTER' IDENTI;
  39 : 'FINSI';
  40 : 
  41 : * modele GLRC_DM
  42 : SI (EGA NOMMOD 'GLRC_DM');
  43 :    MESSAGE 'POUR LE MODELE GLRC_DM IL FAUT DONNER DANS L"ORDRE :';
  44 :    MESSAGE '    LE MODULE D"ELASTICITE DU BETON';
  45 :    MESSAGE '    LE COEFFICIENT DE POISSON DU BETON';
  46 :    MESSAGE '    LE MODULE D"ELASTICITE DE L"ACIER';
  47 :    MESSAGE '    LE COEFFICIENT DE POISSON DE L"ACIER';
  48 :    MESSAGE '    L"EPAISSEUR DE LA COQUE';
  49 :    MESSAGE '    LA SECTION TOTALE D"ACIER PAR METRE LINEAIRE';
  50 :    MESSAGE '    LA POSITION RELATIVE D"UNE NAPPE DANS L"EPAISSEUR';
  51 :    MESSAGE '    LA RESISTANCE EN TRACTION DU BETON';
  52 :    MESSAGE '    L"EFFORT LIMITE EN COMPRESSION PAR METRE LINEAIRE';
  53 :    MESSAGE '    LE PARAMETRE GAMMA_MT TEL QUE 0 < GAMMA_MT < 1';
  54 :    MESSAGE '    LE PARAMETRE GAMMA_F TEL QUE 0 < GAMMA_F < 1';
  55 :    MESSAGE '    ON FAVORISE LE CISAILLEMENT : 1 SINON 0';
  56 :    
  57 :    'ARGU' EB*FLOTTANT;
  58 :    'ARGU' NUB*FLOTTANT;
  59 :    'ARGU' EA*FLOTTANT;
  60 :    'ARGU' NUA*FLOTTANT;
  61 :    'ARGU' HN*FLOTTANT;
  62 :    'ARGU' SA*FLOTTANT;
  63 :    'ARGU' XA*FLOTTANT;
  64 :    'ARGU' FB*FLOTTANT;
  65 :    'ARGU' NC*FLOTTANT;
  66 :    'ARGU' GAMT*FLOTTANT;
  67 :    'ARGU' GAMF*FLOTTANT;
  68 :    'ARGU' CISA*FLOTTANT;
  69 : 
  70 : * Module effectif en membrane
  71 :     EEQM1 = (EA * (SA / HN));
  72 :     EEQM2 = (EB * (((EB * HN) + (EA * SA))));
  73 :     EEQM3 = ((EB * HN) + (EA * SA * (1.0 - (NUB**2.0))));
  74 :     EEQM  = EEQM1 + ((EEQM2) / (EEQM3));
  75 :     
  76 : * Coefficient de Poisson effectif en membrane
  77 :     NUM1 = ((NUB * HN) * EB);
  78 :     NUM2 = ((EB * HN) + (EA * SA * (1.0 - (NUB**2.0))));
  79 :     NUM  = NUM1 / NUM2;
  80 : 
  81 : * Module effectif en flexion
  82 :     EEQF1 = (3.0 / HN) * EA * SA * (XA ** 2.0);
  83 :     EEQF2 = EB * ((EB * HN) + (3.0 * EA * SA * (XA ** 2.0)));
  84 :     EEQF3 = ((EB * HN) + 
  85 :             (3.0 * EA * SA * (XA ** 2.0) * 
  86 :             (1.0 - (NUB ** 2.0))));
  87 :     EEQF  = EEQF1 + (EEQF2 / EEQF3);
  88 :     
  89 : * Coefficient de Poisson effectif en flexion
  90 :     NUF1 = NUB * EB * HN;
  91 :     NUF2 = (EB * HN) + (3.0 * EA * SA * (XA ** 2.0) * 
  92 :            (1.0 - (NUB**2.0)));
  93 :     NUF  = NUF1 / NUF2;
  94 : 
  95 : * Parametre XGAMMC
  96 :     ND1 = FB * EEQM * HN * (1.0 - (NUB ** 2.0));
  97 :     ND2 = EB * (1.0 - (NUB * NUM));
  98 :     ND  = ND1 / ND2;
  99 : 
 100 :     GAMC1 = 1.0;
 101 :     GAMC2 = ((1.0 - GAMT) * (((ND ** 2.0) * (1.0 - NUM) * 
 102 :             (1.0 + 2.0 * NUM)) - ((NC ** 2.0) * (NUM ** 2.0))));
 103 :     GAMC3 = (((NC ** 2.0) * (1.0 - NUM) * 
 104 :             (1.0 + 2.0 * NUM)) - ((ND ** 2.0) * (NUM ** 2.0)));
 105 :     GAMC  = GAMC1 - (GAMC2 / GAMC3);
 106 :     
 107 : * Parametre de seuil k0
 108 :     XK01 = (ND ** 2.0);
 109 :     XK02 = ((1.0 - NUM) * (1.0 + (2.0 * NUM)) * 
 110 :            (1.0 - GAMT)) + ((NUM ** 2.0) * (1.0 - GAMC));
 111 :     XK03 = 4.0 * EEQM * HN * (1.0 + NUM);
 112 :     XK0  = ((XK01 * XK02) / XK03);
 113 : 
 114 : * Parametre de seuil alfa
 115 :     MD1 = FB * EEQF * (HN ** 2.0) * (1.0 - (NUB ** 2.0));
 116 :     MD2 = 6.0 * EB * (1.0 - (NUB * NUF));
 117 :     MD  = MD1 / MD2;
 118 :     
 119 :     LAMF = ((EEQF * (HN ** 3.0) * NUF) / 
 120 :            (12.0 * (1.0 - (NUF ** 2.0))));
 121 :     MUF  = ((EEQF * (HN ** 3.0)) / (24.0 * (1.0 + NUF)));
 122 :     
 123 :     
 124 :     XALFA1 = (1.0 - GAMF) * (MD ** 2.0) * (LAMF * ((1.0 - NUF) ** 2.0) + 
 125 :              (2.0 * MUF));
 126 :     XALFA2 = 2.0 * (((LAMF * (1.0 - NUF)) + (2.0 * MUF)) ** 2.0) * XK0;
 127 :     XALFA  = XALFA1 / XALFA2;
 128 :       
 129 :     RESPRO EEQM NUM EEQF NUF XK0 GAMC XALFA;
 130 :     'QUITTER' IDENTI;
 131 : 
 132 : FINSI;
 133 : 
 134 : 
 135 : 
 136 : 
 137 : 'FINPROC';
 138 : 
 139 : 
 140 : 
 141 : 
 142 :  
 143 :  
 144 :  
 145 :  
 146 :  
 147 :