Datasets examples

* fichier :  gdep2.dgibi
debproc charmeca tapas*'TABLE'  ttt*'FLOTTANT';
mata= tapas.'MA_TABLE' ;
pres1 = mata . 'CHAMPPRES';evpres= mata.'EVOLPRES';
xx = evpres extr 'ABSC' ; yy = evpres extr 'ORDO';
mo1= mata.'MODPRES'; ma1= mata.'MAPRES';
coefp= ipol ttt  xx yy;
pres2= pres1 * coefp;
ff= pressi coque mo1  pres2 'NORM' ;
fpres= pressi coque mo1  pres2 'NORM' ma1;
taa = table;
taa.'ADDI_SECOND'= fpres;
*taa.'ADDI_MATRICE'= ??
finproc  taa;


******************************************************************
*           anneau sous pression non uniforme
******************************************************************
*
* position du probleme
* --------------------
* il s agit de determiner la deformee d un anneau
* sous pression non uniforme suiveuse en grands
* deplacements
* reference:
* ----------
* Argyris J., Mlejnek H. P., Dynamics of structure, North Holland
* 1991, p545
******************************************************************

option echo 1;
option dime 2 elem seg2 ;
opti mode 'PLAN' 'CONT' ;

graph = faux ;

*-------------------------------
* definition de la geometrie
*-------------------------------

r = 100 ;
a = 0 0  ;
b = 100 0  ;
c = 0 100 ;
lig1 = b cerc 18 a c ;

*--------------------------------------
*definition des conditions aux limites
*--------------------------------------
cl1 = bloq rota (b et c) ;
cl2 = bloq uy b ;
cl3 = bloq ux c ;
cl = cl1 et cl2 et cl3 ;

*---------------------------------------------------------
*definition du modele, du materiau et des caracteristiques
*---------------------------------------------------------

valyoun = 2.1e7 ;
mo1 = modele lig1 mecanique elastique isotrope  coq2 ;
ma = mate mo1 youn valyoun nu 0. rho 7.8e3 ;
ep1 = 1. ;
ca = cara mo1 epai ep1 ;
ma = ma et ca;

*-----------------------------
* calcul de l objet chargement
*-----------------------------

lf = prog 0  1000. ;
lt = prog 0   1000. ;
ls = prog 0 pas 0.025 1. pas 0.0125 3. ;
ev1 = evol manu temps lt force lf ;

pres1 = prog ;
teta = 0. ;
n1 = 19 ;
xc = 90./18 ;
p0bar = r * r * r * 12 / valyoun ;
repeter bloc1 n1 ;
   pr1 = (1 + (cos (2*teta))) / p0bar ;
   pres1 = pres1 et (prog pr1) ;
   teta = teta + xc  ;
fin bloc1 ;
chpo1 = manu chpo lig1 1 p pres1 ;
list chpo1;

mata= table ;mata.'MODPRES' = mo1; mata.'MAPRES' = ma;
mata.'CHAMPPRES'= chpo1; mata.'EVOLPRES' = ev1;
*charg2 = char 'PSUI' chpo1 ev1 ;
*pp= pressi mo1  coque chpo1 norm ma;
*list pp;

*------------------------------
*  calcul non lineaire
*------------------------------

tab2 = table ;
tab2.grands_deplacements = vrai ;

tab2.blocages_mecaniques = cl;
tab2.modele = mo1;
tab2.caracteristiques = ma;
*tab2.chargement = charg2;
tab2.'PROCEDURE_CHAR_MECA' = vrai;
tab2.temps_calcules = ls;
tab2.'MA_TABLE' = mata;
tab2.'PROCESSEURS' = 'MONO_PROCESSEUR';
tab2.'PRECISION' = 1e-8;
tab2.'K_SIGMA'= vrai;
tab2.'MAN' = faux;
pasapas tab2 ;

*------------------------------
* comparaison avec la reference
*------------------------------

xxx = peche tab2 deplacements;
uxb = (extr xxx ux b)  ;
uxbth = -86. ;
err = (abs ((uxbth - uxb)/uxbth))*100 ;
mess 'deplacement du point b, p0 = 3 ' ;
mess 'reference 'uxbth 'castem' uxb '%erreur' err ;

si (err < 2) ;
   erre 0 ;
sinon ;
   erre 5 ;
finsi ;

si(graph) ;
   defo0 = defo lig1 xxx 0. VERT ;
   defo1 = defo lig1 xxx 1. ROUG ;
   trac (defo0 et defo1) ;
finsi ;

fin ;