Procedures | Cast3M

   1 : * ROSENT    PROCEDUR  DEGAY     95/05/11    21:16:52     1663           
   2 : DEBPROC ROSENT TAB1*TABLE; 
   3 : ********************************************************************
   4 : *  PROCEDURE ROSENT : Calcul du champ de température créé par le   *
   5 : *              déplacement d'un arc de soudure                     *
   6 : *        (D'après Rosenthal : Mathematical Theory of Heat          *
   7 : *            Distribution During Welding and Cutting)              *
   8 : ********************************************************************
   9 : *  Entrées : TABLE :                                               *
  10 : *            'PUISSANCE' : REEL : Puissance de l'arc (en W)        *
  11 : *            'RENDEMENT' : REEL : Rendement de l'arc : Rapport de  *
  12 : *               la puissance recue par la pièce et de la puissance *
  13 : *               de l'arc                                           *
  14 : *            'DIFFUSVITE' : REEL : Diffusivité thermique du        *
  15 : *               matériau (en m2/s)                                 *
  16 : *            'CONDUCTIVITE' : REEL : Conductivité thermique du     *
  17 : *               matériau (en W/Km2)                                *
  18 : *            'VITESSE' : REEL : Vitesse de déplacement de l'arc    *
  19 : *               (en m/s)                                           *
  20 : *            'T0' : REEL : Température ambiante (en °C ou en K)    *
  21 : *            'NTERMES' : ENTIER : Nombre de termes de la somme     *
  22 : *            'MAILLAGE' : MAILLAGE : Maillage support du champ de  *
  23 : *               température                                        *
  24 : *            'EPAISSEUR' : REEL : Epaisseur de la pièce (en m)     *
  25 : *            'LOCAL' : BOOLEEN : VRAI si la pièce est décrite dans *
  26 : *               le repère local à l'arc                            *
  27 : *            'INSTANT' : REEL : Si 'LOCAL' est FAUX, instant       *
  28 : *               auquel il faut calculer le champ de température    *
  29 : *               (l'abscisse de l'arc est alors V*t) (en s)         *
  30 : *            'GAUSS' : BOOLEEN : VRAI si la source est gaussienne  *
  31 : *            'XPOS' : REEL : Si 'GAUSS' est VRAI, abscisse de la   *
  32 : *               source                                             *
  33 : *            'YPOS' : REEL : Si 'GAUSS' est VRAI, ordonnee de la   *
  34 : *               source                                             *
  35 : *  Sortie  : CHPOINT : Champ de température (en °C ou en K)        *
  36 : ********************************************************************
  37 : &IMP = 'VALEUR' IMPI;
  38 : *&IMP = 1;
  39 : EPS1 = 1.0E-4;
  40 : Q    = TAB1.'PUISSANCE';
  41 : RHO  = TAB1.'RENDEMENT';
  42 : A    = TAB1.'DIFFUSVITE';
  43 : LBDA = TAB1.'CONDUCTIVITE';
  44 : V    = TAB1.'VITESSE';
  45 : T0   = TAB1.'T0';
  46 : NTER = TAB1.'NTERMES';
  47 : OBJ  = TAB1.'MAILLAGE';
  48 : THK  = TAB1.'EPAISSEUR';
  49 : SI (EXISTE TAB1 'LOCAL');
  50 :   LRL  = TAB1.'LOCAL';
  51 : SINON;
  52 :   LRL  = FAUX;
  53 : FINSI;
  54 : SI (NON LRL);
  55 :   TPS  = TAB1.'INSTANT';
  56 :   CHVT = OBJ MANU 'CHPO' 1 SCAL (V*TPS);
  57 : FINSI;
  58 : *
  59 : SI (EGA &IMP 1);
  60 :    MESS 'Creation des CHPOINT';
  61 : FINSI;
  62 : CHT0 = OBJ MANU 'CHPO' 1 SCAL T0;
  63 : CHEP = OBJ MANU 'CHPO' 1 SCAL EPS1;
  64 : *
  65 : CHX = COOR 1 OBJ;
  66 : CHY = COOR 2 OBJ;
  67 : CHZ = COOR 3 OBJ;
  68 : *
  69 : SI (EXISTE TAB1 'GAUSS');
  70 :    BGAUSS = TAB1.'GAUSS';
  71 : SINON;
  72 :    BGAUSS = FAUX;
  73 : FINSI;
  74 : SI (BGAUSS);
  75 :    CHX0 = OBJ MANU 'CHPO' 1 SCAL (TAB1.'XPOS');
  76 :    CHY0 = OBJ MANU 'CHPO' 1 SCAL (TAB1.'YPOS');
  77 :    CHX = CHX - CHX0;
  78 :    CHY = CHY - CHY0;
  79 : FINSI;
  80 : *
  81 : SI (LRL);
  82 :    CHKS = CHX;
  83 : SINON;
  84 :    CHKS = CHX - CHVT;
  85 : FINSI;
  86 : *
  87 : SI (EGA &IMP 1);
  88 :    MESS 'Calcul du champ de temperatures';
  89 : FINSI;
  90 : CHR = ((CHKS**2) + (CHY**2) + (CHZ**2))**0.5;
  91 : CHR = CHR + CHEP;
  92 : CHTT = ((-0.5)*V/A)*CHR;
  93 : CHTT = (EXP(CHTT))/CHR;
  94 : *
  95 : SI (EGA &IMP 1);
  96 :    MESS 'Nombre de noeuds ' (NBNO OBJ);
  97 : FINSI;
  98 : I = 0;
  99 : REPETER BOUC1 NTER;
 100 :    I = I + 1;
 101 :    SI (EGA &IMP 1);
 102 :       MESS 'Boucle N =' I;
 103 :    FINSI;
 104 :    CHTN = OBJ MANU 'CHPO' 1 SCAL (2.*I*THK);
 105 :    CHRN = ((CHKS**2) + (CHY**2) + ((CHTN - CHZ)**2))**0.5;
 106 :    CHRPN = ((CHKS**2) + (CHY**2) + ((CHTN + CHZ)**2))**0.5;
 107 :    CHTN = ((-0.5)*V/A)*CHRN;
 108 :    CHTN = (EXP(CHTN))/CHRN;
 109 :    CHTPN = ((-0.5)*V/A)*CHRPN;
 110 :    CHTPN = (EXP(CHTPN))/CHRPN;
 111 :    CHTT = CHTT + CHTN + CHTPN;
 112 : FIN BOUC1;
 113 : *
 114 : CHTT = (EXP(((-0.5)*V/A)*CHKS))*CHTT;
 115 : CHTT = (Q*RHO/(2.*PI*LBDA))*CHTT;
 116 : CHT  = CHT0 + CHTT;
 117 : RESP CHT;
 118 : *
 119 : FINPROC;