Procedures | Cast3M

   1 : * MULTIDEC  PROCEDUR  PICA      92/07/03    21:27:22     619            
   2 : *----------------------------------------------------------------------*
   3 : *                                                                      *
   4 : * PROCEDURE MULTIDEC                                                   *
   5 : *                                                                      *
   6 : * CALCUL DE LA DECOMPOSITION D'UN SIGNAL SUR UNE SEQUENCE DE FILTRE    *
   7 : *        ONDELETTE ORTHOGONALE                                         *
   8 : *                                                                      *
   9 : *----------------------------------------------------------------------*
  10 : *                                                                      *
  11 : * ENTREE                                                               *
  12 : *                                                                      *
  13 : * SIGNAL X/Y CONTENANT LE SIGNAL. DX DOIT ETRE CONSTANT                *
  14 : *        DANS LE PROCESSUS DE DECOMPOSITION DIADIC, ON STOPPE          *
  15 : *        DES QUE LE NB DE POINT N'EST PLUS PAIR                        *
  16 : *                                                                      *
  17 : * HTILDE Y CONTENANT LE FILTRE (NON FORCEMENT SYMETRIQUE), DANS LA     *
  18 : *        DECOMPOSITION DIADIQUE ON STOPPE DES QUE CETTE  CORRELATION   *
  19 : *        DEVIENT IMPOSSIBLE. LE STOCKAGE PEUT COMPRENDRE               *
  20 : * MMHTI  POINTS NEGATIFS (MMHTI<0--->SYMETRIQUE)                       *
  21 : *                                                                      *
  22 : * GTILDE Y CONTENANT LE FILTRE ( NON SYMETRIQUE). LE STOCKAGE COMPREND *
  23 : * MMGTI  POINTS NEGATIFS (MMGTI<0--->SYMETRIQUE)                       *
  24 : *                                                                      *
  25 : * OPTIO  MOT CONTENANT LE MODE DE CORRELATION (DEFAUT='SYME')          *
  26 : *                                                                      *
  27 : * N      NOMBRE DE NIVEAU ESPERE (DEFAUT=NB MAX)                       *
  28 : *                                                                      *
  29 : *----------------------------------------------------------------------*
  30 : *                                                                      *
  31 : * SORTIE                                                               *
  32 : *                                                                      *
  33 : * M      NOMBRE DE NIVEAU EFFECTIVEMENT ATTEINT                        *
  34 : *                                                                      *
  35 : * ONDELL M COURBES DE DECOMPOSITION PAR ORDRE DE FREQUENCE CROISSANT   *
  36 : *                                                                      *
  37 : * COARSE RESIDU DU SIGNAL APRES M NIVEAU                               *
  38 : *----------------------------------------------------------------------*
  39 : 'DEBPROC' MULTIDEC SIGNAL*'EVOLUTION' HTILDE*'LISTREEL'
  40 :           MMHTI *'ENTIER' GTILDE*'LISTREEL' MMGTI *'ENTIER' 
  41 :                     OPTIO/'MOT' N/'ENTIER';
  42 : *----------------------------------------------------------------------*
  43 : 'SI' ('NON' ('EXISTE' OPTIO));OPTIO='TEXT' SYME;'FINSI';
  44 : 'SI' ('NON' ('EXISTE' N))    ;N=1000;        'FINSI';
  45 : *
  46 : 'SI' (MMHTI '<' 0); MMHO='TEXT' ' ';
  47 :                     MMHTI=('DIMENSION' HTILDE) - 1;
  48 :                     MPHTI= MMHTI;
  49 : 'SINON';            MMHO='TEXT' 'NPNE' MMHTI;
  50 :                     MPHTI=('DIMENSION' HTILDE) - (MMHTI+1);
  51 : 'FINSI';
  52 : *
  53 : 'SI' (MMGTI '<' 0); MMGO='TEXT' ' ';
  54 :                     MMGTI=('DIMENSION' GTILDE) - 1;
  55 :                     MPGTI=MMGTI;
  56 : 'SINON';            MMGO='TEXT' 'NPNE' MMGTI;
  57 :                     MPGTI=('DIMENSION' GTILDE) - (MMGTI+1);
  58 : 'FINSI';
  59 : *
  60 : XXXX='EXTRAIRE' SIGNAL 'ABSC' 1;
  61 : YPHI='COPIER' ('EXTRAIRE' SIGNAL 'ORDO' 1);
  62 : NPT ='DIMENSION' XXXX;
  63 : *
  64 : Q=NPT/2;REF=NPT-(2*Q);
  65 : *
  66 : I=0;
  67 : 'REPETER' LAB1 N;
  68 : *
  69 :   NNPT=NPT;NPT=(NPT+1)/2;
  70 :   Q=NPT/2;R=NPT-(2*Q);
  71 :   'SI' (R 'NEG' REF);
  72 :     'MESSAGE' '*** changement de parite du nb de point au niveau' (I+1);
  73 :     'MESSAGE' '*** reconstruction correcte impossible'
  74 :     'MESSAGE' '--> fin calcul';
  75 :     'QUITTER' LAB1;
  76 :   'FINSI';
  77 :   'SI' ((MMGTI '>' NNPT) 'OU' (MPGTI '>' NNPT));
  78 :     'MESSAGE' '*** nb de point insuffisant pour Phi au niveau' (I+1);
  79 :     'MESSAGE' '--> fin calcul';
  80 :     'QUITTER' LAB1;
  81 :   'FINSI';
  82 :   'SI' ((MMHTI '>' NNPT) 'OU' (MPHTI '>' NNPT));
  83 :     'MESSAGE' '*** nb de point insuffisant pour Psi au niveau' (I+1);
  84 :     'MESSAGE' '--> fin calcul';
  85 :     'QUITTER' LAB1;
  86 :   'FINSI';
  87 : *
  88 :   I=I+1;
  89 :   YYPHI='CVOLUTION' YPHI HTILDE MMHO OPTIO;
  90 :   YYPSI='CVOLUTION' YPHI GTILDE MMGO OPTIO;
  91 :   XX   ='DIADIQUE'  XXXX 'DIRE'; XXXX=XX;
  92 :   YPHI ='DIADIQUE'  YYPHI 'DIRE';
  93 :   YPSI ='DIADIQUE'  YYPSI 'DIRE';
  94 :   'TITRE' 'Decomposition en ondelette : Niveau i=' I;
  95 :   PSI='EVOLUTION' 'MANUEL' 'temps' XXXX 'Y(niveau i)' YPSI;
  96 : *
  97 :   'SI' (I 'EGA' 1);
  98 :     ONDELL=PSI;
  99 :   'SINON';
 100 :     ONDELL=PSI 'ET' ONDELL;
 101 :   'FINSI';
 102 : *
 103 : 'FIN' LAB1;
 104 : *
 105 : M=I;
 106 : 'TITRE' 'Signal de faible resolution : niveau m=' M;
 107 : COARSE='EVOLUTION' 'MANUEL' 'temps' XXXX 'Y(niveau i)' YPHI;
 108 : 'FINPROC' M ONDELL COARSE;