* fichier : dy_dev10.dgibi
******************************************************************
*
* Cas-Test de la liaison palier de l'operateur DYNE
*
* Arbre rigide L=1m sur 2 paliers cylindriques
* Chargement statique des paliers Fz = 1000 N
*
******************************************************************
*
OPTI 'DIME' 3 'ELEM' SEG2 echo 0;
*
d_pasa = vrai ;
NPas1 = 1000 ;
PTps1 = 6.25e-5/30. ;
NSor1 = 30 ;
NbMod1 = 6 ;
*
Ra1= 0.02 ;
E1 = 2.e+15 ;
Rho1 = 7800. ;
Nu1 = 0.3 ;
*
P0 = 0. 0. 0. ;
P1 = 0.5 0. 0. ;
P2 = 1. 0. 0. ;
*
El1 = DROI P0 P1 1 ;
El2 = DROI P1 P2 1 ;
Mail1 = El1 ET El2 ;
*
Modl1 = MODL Mail1 'MECANIQUE' 'TUYA' ;
*
Cara1 = CARA Modl1 'RAYO' Ra1 'EPAI' Ra1 ;
*
Mate1 = MATE Modl1 'YOUNG' E1 'NU' Nu1 'RHO' Rho1 ;
*
Blo1 = BLOQ 'UX' 'RX' 'RY' 'RZ' Mail1 ;
*
MMass1 = MASS Modl1 (Cara1 ET Mate1) ;
MRigi1 = RIGI Modl1 (Cara1 ET Mate1) ;
*
TBasR1 = VIBR 'SIMU' 10. NbMod1 (MRigi1 ET Blo1) MMass1 'TBAS' ;
NNOR TBasR1.MODES 'AVEC' (MOTS 'UY' 'UZ') ;
*
* Creation de la table des CONDITIONS INITIALES
************************************************
TInit1 = TABLE 'INITIAL' ;
*
UY0 = 0. ;
UZ0 = -0.0001e-3 ;
Dep0 = MANU 'CHPO' Mail1 2 'UY' UY0 'UZ' UZ0 NATURE DIFFUS ;
*
REPE bb1 NbMod1 ;
i1 = &bb1 ;
Def1 = TBasR1 . 'MODES' . i1 . 'DEFORMEE_MODALE' ;
M_G1 = TBasR1 . 'MODES' . i1 . 'MASSE_GENERALISEE' ;
P_R1 = TBasR1 . 'MODES' . i1 . 'POINT_REPERE' ;
qi1 = (YTMX Def1 MMass1 Dep0) / M_G1 ;
f_r1 = TBasR1 . 'MODES' . i1 . 'FREQUENCE';
mai4 = manu poi1 p_r1 ;
mo_mod4 = modele mai4 mecanique elastique modal ;
ca_mod4 = mate mo_mod4 freq f_r1 mass m_g1 defo Def1;
SI (EGA i1 1) ;
TInit1.'DEPLACEMENT' = MANU 'CHPO' P_R1 1 'ALFA' qi1 NATURE DIFFUS ;
TInit1.'VITESSE' = MANU 'CHPO' P_R1 1 'ALFA' 0. NATURE DIFFUS ;
mo_1 = mo_mod4 ; ca_1 = ca_mod4 ;
SINON ;
TInit1.'DEPLACEMENT' = TInit1.'DEPLACEMENT' ET
(MANU 'CHPO' P_R1 1 'ALFA' qi1 NATURE DIFFUS) ;
TInit1.'VITESSE' = TInit1.'VITESSE' ET
(MANU 'CHPO' P_R1 1 'ALFA' 0. NATURE DIFFUS) ;
mo_1 = mo_1 et mo_mod4 ; ca_1 = ca_1 et ca_mod4 ;
FINSI ;
FIN bb1 ;
*
* Creation de la table des LIAISONS (paliers)
**********************************************
*
TLiai1 = TABLE 'LIAISON' ;
TLiai1 . LIAISON_B = TABLE 'LIAISON_B' ;
PAL1 = TABLE 'LIAISON_ELEMENTAIRE' ;
PAL1 . TYPE_LIAISON = 'PALIER_FLUIDE' ;
PAL1 . MODELE_PALIER = RODELI ;
PAL1 . POINT_SUPPORT = P0 ;
PAL1 . LONGUEUR_PALIER = 0.01 ;
PAL1 . RAYON_ARBRE = 0.02 ;
PAL1 . VISCOSITE_FLUIDE = 0.02 ;
PAL1 . RHO_FLUIDE = 960. ;
PAL1 . PRESSION_ADMISSION = 0. ;
PAL1 . VITESSE_ROTATION = 2 * pi * 100. ;
PAL1 . EPSI = 0.;
PAL1 . PHII = 0. ;
PAL1 . AFFICHAGE = 0 ;
PAL1 . GEOMETRIE_PALIER = TABLE ;
PAL1 . GEOMETRIE_PALIER . NOMBRE_LOBES = 1 ;
PAL1 . GEOMETRIE_PALIER . CRITERE_ARRET = 1e-4 ;
PAL1 . GEOMETRIE_PALIER . 1 = TABLE ;
PAL1 . GEOMETRIE_PALIER . 1 . ASYMETRIE = 0. ;
PAL1 . GEOMETRIE_PALIER . 1 . JEU_USINAGE = 1e-4 ;
PAL1 . GEOMETRIE_PALIER . 1 . PRECHARGE = 0. ;
PAL1 . GEOMETRIE_PALIER . 1 . ANGLE_DEBUT = 0. ;
PAL1 . GEOMETRIE_PALIER . 1 . AMPL_ANGLE = 2 * pi ;
PAL1 . GEOMETRIE_PALIER . 1 . COEF_SUR = 1.715 ;
PAL1 . GEOMETRIE_PALIER . 1 . NB_MAILLES = 100 ;
*
maifl1 = manu poi1 p0 ;
mpafl1 = modele maifl1 liaison 'PALIER_FLUIDE' 'RHODE_LI';
tfl1 = table ; tfl1 . mpafl1 = vrai ;
cpafl1 = mate mpafl1 'LONG' 0.01 'RAYO' 0.02 'VISC' 0.02 'RHOF' 960.
'PADM' 0. 'VROT' (2*pi*100) 'EPSI' 0. 'PHII' 0. 'AFFI' 0
'TLOB' PAL1 . GEOMETRIE_PALIER 'SORT' tfl1 ;
*
PAL2 = TABLE 'LIAISON_ELEMENTAIRE' ;
PAL2 . TYPE_LIAISON = 'PALIER_FLUIDE' ;
PAL2 . MODELE_PALIER = RODELI ;
PAL2 . POINT_SUPPORT = P2 ;
PAL2 . LONGUEUR_PALIER = 0.01 ;
PAL2 . RAYON_ARBRE = 0.02 ;
PAL2 . VISCOSITE_FLUIDE = 0.02 ;
PAL2 . RHO_FLUIDE = 960. ;
PAL2 . PRESSION_ADMISSION = 0. ;
PAL2 . VITESSE_ROTATION = 2 * pi * 100. ;
PAL2 . EPSI = 0.;
PAL2 . PHII = 0. ;
PAL2 . AFFICHAGE = 0 ;
PAL2 . GEOMETRIE_PALIER = TABLE ;
PAL2 . GEOMETRIE_PALIER . NOMBRE_LOBES = 1 ;
PAL2 . GEOMETRIE_PALIER . CRITERE_ARRET = 1e-4 ;
PAL2 . GEOMETRIE_PALIER . 1 = TABLE ;
PAL2 . GEOMETRIE_PALIER . 1 . ASYMETRIE = 0. ;
PAL2 . GEOMETRIE_PALIER . 1 . JEU_USINAGE = 1e-4 ;
PAL2 . GEOMETRIE_PALIER . 1 . PRECHARGE = 0. ;
PAL2 . GEOMETRIE_PALIER . 1 . ANGLE_DEBUT = 0. ;
PAL2 . GEOMETRIE_PALIER . 1 . AMPL_ANGLE = 2 * pi ;
PAL2 . GEOMETRIE_PALIER . 1 . COEF_SUR = 1.715 ;
PAL2 . GEOMETRIE_PALIER . 1 . NB_MAILLES = 100 ;
*opti donn 3 ;
maifl2 = manu poi1 p2 ;
mpafl2 = modele maifl2 liaison 'PALIER_FLUIDE' 'RHODE_LI';
tfl2 = table ; tfl2 . mpafl2 = vrai ;
cpafl2 = mate mpafl2 'LONG' 0.01 'RAYO' 0.02 'VISC' 0.02 'RHOF' 960.
'PADM' 0. 'VROT' (2*pi*100) 'EPSI' 0. 'PHII' 0. 'AFFI' 0
'TLOB' PAL2 . GEOMETRIE_PALIER 'SORT' tfl2 ;
*
TLiai1 . LIAISON_B . 1 = PAL1 ;
TLiai1 . LIAISON_B . 2 = PAL2 ;
*
* Creation de la table des VARIABLES DE SORTIE
***********************************************
TSort1 = TABLE 'SORTIE' ;
TSort1 . 'VARIABLE' = TABLE 'VARIABLE' ;
TSort1 . 'LIAISON_B' = TABLE 'LIAISON_B' ;
TSort1 . 'LIAISON_B' . PAL1 = VRAI ;
TSort1 . 'LIAISON_B' . PAL2 = VRAI ;
tsort1 . 'VARIABLE' . vitesse = vrai ;
tsort1 . 'VARIABLE' . deplacement = vrai ;
*
* Creation de la table du CHARGEMENT (chargement statique)
*************************************
TChar1 = TABLE 'CHARGEMENT' ;
LTps1 = PROG 0.0 'PAS' PTps1 'NPAS' (NPas1+1) ;
FsY1 = 0. ;
FsZ1 = -1000. ;
Chp_Fs1 = MANU CHPO 3 (P0 ET P2)
'FX' 0. 'FY' FsY1 'FZ' FsZ1 ;
Ev_Fs1 = EVOL MANU LTps1 (PROG (NPas1+2) * 1.) ;
Char_Fs1 = CHAR Chp_Fs1 Ev_Fs1 ;
TChar1 . 'BASE_A' = PJBA TBasR1 Char_Fs1 ;
char_fs2 = pjba char_fs1 mo_1 ca_1 ;
*
tabdyn = table 'PASAPAS' ;
tabdyn . modele = mo_1 et mpafl1 et mpafl2 ;
tabdyn . caracteristiques = ca_1 et cpafl1 et cpafl2 ;
tabdyn . chargement = char_fs2 ;
tabdyn . deplacements = table ;
tabdyn . vitesses = table ;
tabdyn . deplacements . 0 = tinit1 . deplacement ;
tabdyn . vitesses . 0 = tinit1 . vitesse ;
si d_pasa ;
tabdyn . dynamique = vrai ;
tabdyn . temps_calcules = prog 0. pas (ptps1*10) (ptps1*npas1) ;
tabdyn . temps_sauves = prog 0. pas (ptps1*nsor1) (ptps1*nsor1*33);
pasapas tabdyn ;
sinon ;
tabdyn . sortie = table ;
tabdyn . sortie . mpafl1 = vrai ;
tabdyn . sortie . mpafl2 = vrai ;
tabdyn . pas_de_temps = ptps1 ;
tabdyn . nombre_pas = npas1 ;
tabdyn . pas_de_sortie = nsor1 ;
dyne de_vogelaere tabdyn ;
finsi ;
* Cacul temporel : Appel a DYNE
********************************
TResu1 = DYNE 'DE_VOGELAERE' TBasR1 TChar1 TInit1 TSort1
TLiai1 PTps1 NPas1 NSor1 ;
*
Abs1 = TResu1 . PAL1 . 'UY_ARBRE' /
PAL1 . 'GEOMETRIE_PALIER'. 1 . 'JEU_USINAGE' ;
Ord1 = TResu1 . PAL1 .'UZ_ARBRE' /
PAL1 . 'GEOMETRIE_PALIER' . 1 . 'JEU_USINAGE' ;
Abs2 = TResu1 . PAL1 . 'FY_PALIER';
Ord2 = TResu1 . PAL1 . 'FZ_PALIER';
si d_pasa ;
abs11 = prog 0.; abs21 = prog 0.; ord11 = prog 0.; ord21 = prog 0.;
repeter b_p ((dime tabdyn . temps) - 1) ;
tuu1 = 'EXTR' ('REDU' tabdyn . variables_internes . &b_p mpafl1)
'SLIA' 1 1 1 ;
abs11 = abs11 et tuu1 . 'UY_ARBRE' ;
ord11 = abs21 et tuu1 . 'UZ_ARBRE' ;
abs21 = abs21 et tuu1 . 'FY_PALIER';
ord21 = ord21 et tuu1 . 'FZ_PALIER';
fin b_p ;
abs11 = abs11/PAL1 . 'GEOMETRIE_PALIER'. 1 . 'JEU_USINAGE' ;
ord11 = ord11/PAL1 . 'GEOMETRIE_PALIER' . 1 . 'JEU_USINAGE' ;
sinon ;
Abs11 = tabdyn . liaisons . mpafl1 . 'UY_ARBRE' /
PAL1 . 'GEOMETRIE_PALIER'. 1 . 'JEU_USINAGE' ;
Ord11 = tabdyn . liaisons . mpafl1 .'UZ_ARBRE' /
PAL1 . 'GEOMETRIE_PALIER' . 1 . 'JEU_USINAGE' ;
Abs21 = tabdyn . liaisons . mpafl1 . 'FY_PALIER';
Ord21 = tabdyn . liaisons . mpafl1 . 'FZ_PALIER';
finsi ;
*
OPTI ECHO 0 ;
MESS 'Resultats attendus : .17 / -.92 / -28.9 / 1026.1' ;
MESS 'Resultats calcules :' ;
MESS (EXTR Abs1 34) (EXTR Ord1 34) (EXTR Abs2 34) (EXTR Ord2 34) ;
MESS (EXTR Abs11 34) (EXTR Ord11 34) (EXTR Abs21 34) (EXTR Ord21 34) ;
err1 = (.17 - (EXTR Abs1 34))/ .17 ;
err2 = (-.92 - (EXTR Ord1 34))/ -.92 ;
err3 = (-28.9 - (EXTR Abs2 34))/ -28.9 ;
err4 = (1026.1 - (EXTR Ord2 34)) / 1026.1 ;
err11 = (.17 - (EXTR Abs11 34))/ .17 ;
err21 = (-.92 - (EXTR Ord11 34))/ -.92 ;
err31 = (-28.9 - (EXTR Abs21 34))/ -28.9 ;
err41 = (1026.1 - (EXTR Ord21 34)) / 1026.1 ;
mess 'err1' err1 'err2' err2 'err3' err3 'err4' err4 ;
si ( ((abs (err2+err21)) > 0.05) ou ((abs (err4 + err41)) > 0.05)) ;
erre 5 ;
sinon ;
erre 0 ;
finsi ;
*
FIN ;
© Cast3M 2003 - All rights reserved.
Disclaimer