Datasets examples

* fichier : test_trac.dgibi

* Teste TRAC avec les nouvelles couleurs
*---------------------------------------

* Mettre GRAPH a VRAI si trace en interactif, sinon trace en Postscript
GRAPH = FAUX ;
'SI' ('NON' GRAPH) ;  'OPTION' 'TRAC' 'PSC' ;  'FINSI' ;

'OPTION' 'DIME' 2 'ELEM' 'QUA4' ;

p1 = 0 0 ;
p2 = 1 0 ;
p3 = 1 1 ;
p4 = 0 1 ;

*-- teste l'option 'COUL' 
'OPTION' 'COULEUR' 'BLEU' ;
m = 'MANU' 'QUA4' p1 p2 p3 p4 ;
'TRACER' m 'COULEUR' 'BLEU' 'NCLK' 
'TITRE' 'on doit voir un carre bleu';

*-- teste l'une des nouvelles couleurs
'TRACER' ('COULEUR' m 'ORAN') 'NCLK' 
'TITRE' 'on doit voir un carre orange';

*-- teste les isovaleurs
b = 'COOR' 1 m ;
'TRACER' b m 'NCLK' 
'TITRE' 'on doit voir un dégradé surfacique';
* le long d'une ligne
'TRACER' b ('CHANGER' m 'LIGNE') 'NCLK' 
'TITRE' 'on doit voir un dégradé le long des lignes';
* avec un nombre inférieur à 16
'TRACER' b m ('PROG' 0 'PAS' .1 1.) 'NCLK' ;
* avec un nombre inférieur à 8
'TRACER' b m ('PROG' 0 'PAS' .2 1.) 'NCLK' ;
* avec des lignes
'OPTION' 'ISOV' 'LIGNE' ;
'TRACER' b m 'NCLK' 
'TITRE' 'avec courbes isovaleurs';

*-- teste les vecteurs (en 3D car ET foire en 2D)
'OPTION' 'DIME' 3 ;
'OPTION' oeil (0. 0. 1.d30) ;
licoul = 'MOTS' 'DEFAUT' 'BLEU' 'ROUGE' 'ROSE' 'JAUNE' 'VERT' 'TURQ'
              'AZUR' 'ORANGE' 'VIOLET' 'OCEAN' 'CYAN' 'OLIVE' 'GRIS';
ncoul  = 'DIME' licoul ;
'REPETER' bcl ncoul ;
  i     = &bcl ;
  icoul = 'EXTR' licoul i ;
  ang   = (i-1.) * 360. / ncoul ;
  c     = 'MANU' 'CHPO' m 3 'UX' (('COS' ang))
                            'UY' (('SIN' ang)) 'UZ' 0.;
  v     = 'VECTEUR' 0.1 c 'UX' 'UY' 'UZ' icoul ;
  'SI' (i 'EGA' 1) ;
     vtot = v ;
  'SINON' ;
     vtot = vtot 'ET' v ; 
  'FINSI' ;
'FIN' bcl;                              

'TITRE' 'on doit voir plein de vecteurs colorés en cercle';
'TRACER' m vtot ;

*-- teste les déformées
d = ANIME 20 m ('NOMC' b 'UX') 1. ;
'TRACER' d 'NCLK'
'TITRE' 'on doit voir toutes les amplitudes jusqu a 1';
'OPTION' 'ISOV' 'SURFACE' ;
d = ANIME 3 m ('NOMC' b 'UX') 1. b ;
'TRACER' d 'NCLK'
'TITRE' 'ok ?';

'FIN' ;