Datasets examples

* fichier :  bo2.dgibi
 SAUT PAGE ;
**********************************************************************
*                Utilisation des opérateurs CHI1 et CHI2
*               test avec échange
**********************************************************************
OPTION DIME 2 ;                                                         
*
*                DEFINITION DU MAILLAGE
*
*
n1 = 1 ;
*n2 = 160 ;
*n2 = 80  ;
n2 = 1   ;
*
*                 POINT SERVANT A DEFINIR LE CONTOUR
*
a = 0.0 0.0 ;
b = 1. 0.0 ;
c = 1. 8. ;
d = 0. 8. ;
*
option elem qua4 ;
*
ab = a droit n1 b ; 
bc = b droit n2 c ; 
cd = c droit n1 d ; 
da = d droit n2 a ; 
*
*                         DEFINITION DU MAILLAGE
*
*
GP = AB BC CD DA DALL 'PLAN' ;
ELIM 0.001 GP ;
AB= CHANG POI1 AB ;
G1= CHANG POI1 GP ;
G0= DIFF G1 AB ;
*
TABDON=TABLE ;                                                          
TABDON.IDEN= LECT 1 22 5 103 50 ;
TABDON.NVCOMP= TABLE ;
 COMP1=TABLE ;
 COMP1.IDEN= 162 ;
 COMP1.NOM= X162 ;
 COMP1.CHARGE= -1 ;
TABDON.NVCOMP.1= COMP1 ;
   TABESP1= TABLE   ;
    TABESP1.IDEN= 163 ;
    TABESP1.LOGK= 7. ;
    TABESP1.ITYP= 2 ;
    TABESP1.COMP=  LECT 162 50 ;
    TABESP1.STOECH=  PROG  1.  1.  ;
   TABESP2= TABLE   ;
    TABESP2.IDEN= 164 ;
    TABESP2.LOGK= 1.5 ;
    TABESP2.ITYP= 2 ;
    TABESP2.COMP=  LECT 162 5 ;
    TABESP2.STOECH=  PROG  1. 1.   ;
 TABDON.NVESP= TABLE ;
 TABDON.NVESP.1= TABESP1 ;
 TABDON.NVESP.2= TABESP2 ;
 TABDON.ECHANGE= LECT 162 ;
*
*  LOGK  '/u2/anne/mch/LOGK2' ;
 TB1=CHI1 TABDON  COMP  '/u/castem/divers/COMPOM'
   LOGK  '/u/castem/divers/COMPOM' ;
*
*                        Table de données de CHI2
*
*
 TBPAR2= TABLE ;
 TBPAR2.'SOUSTYPE'='DONNEES_CHIMIQUES' ;
 TBPAR2.LOGC= MANU CHPO G1 6 X001 -6. X022 -6. X005 -6.
               X050 -6. X162 -2. X103 -6. ;
  TOTCA= MANU CHPO G1 1 X001 1.D-15 ;
  TOTLI1= MANU CHPO G1 1 X022 1.248D-9 ;
  TOTLI2= MANU CHPO AB 1 X022 (1.D-3 - 1.248D-9) ;
  TOTLI = TOTLI1 + TOTLI2 ;
  TOTNA1= MANU CHPO G1 1 X005 1.100131015D-1 ;
  TOTNA2= MANU CHPO AB 1 X005 (1.D-1 - 1.100131015D-1) ;
  TOTNA= TOTNA1 + TOTNA2 ;
  TOTCL1= MANU CHPO G1 1 X103 1.D-1 ;
  TOTCL2= MANU CHPO AB 1 X103 (1.02D-1 - 1.D-1)  ;
   TOTCL= TOTCL1+ TOTCL2 ;
  TOTSF1= MANU CHPO G1 1 X162  1.D-2 ;
  TOTSF2= MANU CHPO AB 1 X162  (1.D-15 - 1.D-2);
  TOTSF= TOTSF1 + TOTSF2 ;
  TOTH1= MANU CHPO G1 1 X050 -1.3012D-5 ;
  TOTH2= MANU CHPO AB 1 X050 (1.0001D-3 + 1.3012D-5) ;
   TOTH = TOTH1 + TOTH2 ;
 TBPAR2.TOT= TOTCA + TOTLI + TOTNA + TOTCL + TOTSF +TOTH ;
 TBPAR2.FIONI= MANU CHPO G1 1 SCAL 0.001 ;
 TBPARM= TABLE ;
 TBPARM.ITMAX = 80;
 TBPARM.EPS= 1.D-8 ;
 TBPARM.NFI= 4 ;
 TBPARM.ITERSOLI=15 ;
 TBPARM.SORTIE= MOTS 'FION' 'TYP5' 'SURF' ;
*
 TB3= CHI2 TB1 TBPARM TBPAR2 ;
*
*                                   controle des résultats
*
 FIONTE1=MANU CHPO G1 1 SCAL 1.00030E-01 'NATURE' DISCRET ;
 FIONTE2=MANU CHPO AB 1 SCAL (1.02000E-01 - 1.00030E-01)
 'NATURE' DISCRET ;
 FIONTES= FIONTE1 + FIONTE2 ;
 VERR1= ( ABS ( FIONTES - TB3.FION )) MASQUE SUPERIEUR 5.D-6 SOMME ;
 SURFTE1= MANU CHPO G0 2  W006  9.98262E-03  W010  1.73813E-05
   'NATURE' DISCRET ;
 SURFTE2= MANU CHPO AB 2 W006  3.15844E-19  W010  9.98885E-16
 'NATURE' DISCRET ;
 SURFTES= SURFTE1+SURFTE2 ;
 SURFD=SURFTES /  50. ;
 VERR2= ( ABS ( SURFTES - TB3.SURF )) MASQUE SUPERIEUR SURFD SOMME ;
 TY5TE1=  MANU CHPO G0 1 W011  3.12037E-20 'NATURE' DISCRET ;
 TY5TE2=  MANU CHPO AB 1 W011   9.43503E-33  'NATURE' DISCRET ;
 TY5TES= TY5TE1+TY5TE2 ;
 TY5D= TY5TES/ 50. ;
 VERR3= ( ABS ( TY5TES - TB3.TYP5 )) MASQUE SUPERIEUR TY5D SOMME ;
*
 VERR= VERR1+VERR2+VERR3 ;
 SI (VERR EGA 0 ) ;
  ERRE 0 ;
 SINO  ;
  ERRE 5 ;
 FINSI ;
FIN ;