Procedures | Cast3M

   1 : * @LAVIS    PROCEDUR  KK2000    99/11/30    21:15:26     3720           
   2 : *
   3 : ************************************************************************
   4 : *                        PROCEDURA @LAVIS
   5 : ************************************************************************
   6 : *
   7 : * Descrizione : visualizza l'impilamento delle lamine per una
   8 : *               zona richiesta
   9 : *
  10 : * Sintassi    : @LAVIS TAB_LAM NUM_ZONA ;
  11 : *
  12 : *
  13 : * Autore/Data : Miliozzi A.  10/04/1997
  14 : *
  15 : *
  16 : * Revisioni   :
  17 : *
  18 : ************************************************************************
  19 : *
  20 : *--- INPUT
  21 : *=========
  22 : *
  23 : * TAB_LAM   Tavola caratteristica dei laminati compositi
  24 : *
  25 : * NUM_ZONA  Numero della zona da visualizzare
  26 : *
  27 : *--- OUTPUT
  28 : *==========
  29 : *
  30 : *
  31 : ************************************************************************
  32 : *
  33 : DEBPROC @LAVIS TCOMP*TABLE NZONE*ENTIER ;
  34 : *
  35 :   OPTI DIME 3 ELEM CUB8 ;
  36 :   LISCOU = MOTS 'ROUG' 'VERT' ;
  37 : *
  38 :   SI (EXIST (TCOMP.NZONE) ) ;
  39 : *
  40 : * --- RICERCA DEL MASSIMO SPESSORE
  41 : *
  42 :     N   = 1 ;
  43 :     BB  = 0.;
  44 :     TC  = TCOMP.NZONE ;
  45 :     LEX = PROG ;
  46 :     LEP = PROG ;
  47 :     LAN = PROG ;
  48 :     NPLY = (DIME TC) - 6 ;
  49 :     REPETER LOOP0 NPLY ;
  50 :       AN = TC.N.ANG ;
  51 :       SP = TC.N.EPA ;
  52 :       EX = TC.N.EXC ;
  53 :       LEX = INSERER LEX N EX ;
  54 :       LEP = INSERER LEP N SP ;
  55 :       LAN = INSERER LAN N AN ;
  56 :       SI (SP > BB ) ; BB = SP ; FINSI ;
  57 :       N = N + 1 ;
  58 :     FIN LOOP0 ;
  59 : *
  60 : * --- TRACCIAMENTO STRATIFICAZIONE
  61 : *
  62 :     OEIL   = 100. -100. 50. ;
  63 :     NN   = 1 ;
  64 :     II   = 1 ;
  65 :     REPETER LOOP1 NPLY ;
  66 :       EX = EXTRAIRE LEX NN ;
  67 :       EP = EXTRAIRE LEP NN ;
  68 :       AN = EXTRAIRE LAN NN ;
  69 :       CC = EXTRAIRE LISCOU II ;
  70 :       SI (II < 2); II = II + 1 ; SINON ; II = 1 ; FINSI ;
  71 :       KK = (FLOTTANT NN) / (FLOTTANT NPLY) ;
  72 :       C1 = 2. * BB          ; C2 = 10. * BB * KK    ;
  73 :       C3 = EX - ( EP / 2. ) ; C4 = EX + ( EP / 2. ) ;
  74 :       D1 = BB * ( COS AN )  ; D2 = BB * ( SIN AN  ) ;
  75 :       AM = 0. 0. C3 ;
  76 :       AP = 0. 0. C4 ;
  77 :       L1 = DROI 1 AP AM ;
  78 :       S1 = L1 TRANS 1 ( 0. C1 0. ) ;
  79 :       V1 = S1 VOLU TRANS 1 ( C2 0. 0. ) ;
  80 :       PP = V1 POIN PROC ( C2 C1 C3 ) ;
  81 :       FOX= FORCE (BB  0. 0. ) PP ;
  82 :       FOY= FORCE ( 0. BB 0. ) PP ;
  83 :       FOO= FORCE ( D1 D2 0. ) PP ;
  84 :       SI (NN EGA 1) ;
  85 :         VTOT = COUL V1 CC ;
  86 :         VETO = (VECT FOX 1. FX FY FZ BLEU ) ET
  87 :                (VECT FOY 1. FX FY FZ BLEU ) ET
  88 :                (VECT FOO 2. FX FY FZ ROSE ) ;
  89 :       SINON ;
  90 :         VTOT = VTOT ET ( COUL V1 CC ) ;
  91 :         VE1  = (VECT FOX 1. FX FY FZ BLEU ) ET
  92 :                (VECT FOY 1. FX FY FZ BLEU ) ET
  93 :                (VECT FOO 2. FX FY FZ ROSE ) ;
  94 :         VETO = VETO ET VE1 ;
  95 :       FINSI ;
  96 :       NN = NN + 1 ;
  97 :     FIN LOOP1 ;
  98 : *
  99 :     TITR ' ZONE NUMBER ' NZONE ;
 100 :     TRAC OEIL VTOT FACE VETO ;
 101 : *
 102 :   SINON ;
 103 :     MESS ' NON-EXISTENT ZONE NUMBER !' ;
 104 :   FINSI ;
 105 : *
 106 : FINPROC ;
 107 : *
 108 : ************************************************************************
 109 : *                       FINE PROCEDURA @LAVIS
 110 : ************************************************************************
 111 : *
 112 :