Datasets examples

* fichier :  flam3.dgibi
* COMPARAISON DES CALCULS DE FLAMBAGE D'UN TUBE 
* SOUS PRESSION INTERNE (TUBE DE SACLAY)
OPTI DIME 3 ELEM QUA4 ECHO 0;
MESS '  COMPARAISON DES CALCULS DE FLAMBAGE';
MESS 'D UN TUBE SOUS PRESSION INTERNE MODéLISé';
MESS '    AVEC COQ3 ET COQ4 (TUBE DE SACLAY)';
L = 10. ;
T = .01 ;
R = .5 ;
E = 2E11 ;
NV = 30 ;
NH = 8 ;
************************
P1 = R 0 0 ; 
P2 = R 0 L ;
L1 = P1 D NV P2 ;
AX1 = 0 0 0 ; 
AX2 = 0 0 L;
SURF4 = ROTA L1 AX1 AX2 NH 90. ;
SURF3 = CHAN 'TRI3' SURF4;
* MODéLES, MATéRIAUX ET RIGIDITé
MODL3 = MODE SURF3 MECANIQUE COQ3;
MODL4 = MODE SURF4 MECANIQUE COQ4;
MAT3 = MATE MODL3 YOUN E NU .30 RHO 8000 EPAI T ;
MAT4 = MATE MODL4 YOUN E NU .30 RHO 8000 EPAI T ;
RIG3 = RIGI MODL3 MAT3 ;
RIG4 = RIGI MODL4 MAT4 ;
I1 = PI*(R**3)*T ;
S1 = 2*PI*R*T ;
* CONDITION AUX LIMITES
LL41 = COTE 2 SURF4 ;
BL41 = SYMT DEPL ROTA (0 0 0) (1 0 0) (0 1 0) SURF4 .01 ;
BL42 = SYMT DEPL ROTA AX1 AX2 P1 SURF4 .01 ;
BL43 = SYMT DEPL ROTA AX1 AX2 (0 1 0) SURF4 .01;
F4 = PRESS COQU MODL4 (MANU CHPO SURF4 1 P -100.) NORM;
LL31 = COTE 2 SURF4 ;
BL31 = SYMT DEPL ROTA (0 0 0) (1 0 0) (0 1 0) SURF3 .01 ;
BL32 = SYMT DEPL ROTA AX1 AX2 P1 SURF3 .01 ;
BL33 = SYMT DEPL ROTA AX1 AX2 (0 1 0) SURF3 .01;
F3 = PRESS COQU MODL3 (MANU CHPO SURF3 1 P -100.) NORM;
* CALCULS éLASTIQUES
DEP3 = RESO (RIG3 ET BL31 ET BL32 ET BL33) F3 ;
SIG3 = SIGM MODL3 MAT3 DEP3 ;
KSIG3 = KSIG MODL3 MAT3 SIG3 FLAM ;
DEP4 = RESO (RIG4 ET BL41 ET BL42 ET BL43) F4 ;
SIG4 = SIGM MODL4 MAT4 DEP4 ;
KSIG4 = KSIG MODL4 MAT4 SIG4 FLAM ;
* CONDITIONS AUX LIMITES POUR LE CALCUL DE FLAMBAGE
BL33 = ANTI DEPL ROTA AX1 AX2 (0 1 0) SURF3 .01;
PP0 = POIN SURF3 PROCHE (0 R L) ;
BL34 = BLOQ UX PP0 ;
RIGT3 = RIG3 ET BL31 ET BL32 ET BL33 ET BL34 ;
BL43 = ANTI DEPL ROTA AX1 AX2 (0 1 0) SURF4 .01;
PP0 = POIN SURF4 PROCHE (0 R L) ;
BL44 = BLOQ UX PP0 ;
RIGT4 = RIG4 ET BL41 ET BL42 ET BL43 ET BL44 ;
* CALCUL DE FLAMBAGE
KP3 = KP MODL3 (MANU CHPO SURF3 1 P -100.) FLAM ;
TAB3 = VIBR PROCHE (PROG 79.) RIGT3
                     ((1*KP3) ET (-1*KSIG3) ) TBAS ;
KP4 = KP MODL4 (MANU CHPO SURF4 1 P -100.) FLAM ;
TAB4 = VIBR PROCHE (PROG 79.) RIGT4
                     ((1*KP4) ET (-1*KSIG4) ) TBAS ;
DEP3 = TAB3.MODES. 1 .DEFORMEE_MODALE ;
DEP4 = TAB4.MODES. 1 .DEFORMEE_MODALE ;
DEF3 = DEFO DEP3 SURF3 1. ROUGE ;
DEF4 = DEFO DEP4 SURF4 1. VERT ;
DEF0 = DEFO DEP3 SURF3 0. ;
*TRAC (DEF3 ET DEF4 ET DEF0) ;
F3 = TAB3.MODES. 1 .FREQUENCE ;
LL3 = (2*PI*F3)**2 ;
F4 = TAB4.MODES. 1 .FREQUENCE ;
LL4 = (2*PI*F4)**2 ;
PCOQ3 = LL3*100 ;
PCOQ4 = LL4*100 ;
PTH = PI**2*E*R*T/4/L/L ;
ERR3 = ABS (100.*(PTH - PCOQ3)/PCOQ3);
ERR4 = ABS (100.*(PTH - PCOQ4)/PCOQ4);
MESS 'CALCUL THéORIQUE        : ' PTH;
MESS 'CALCUL NUMéRIQUE (COQ3) : ' PCOQ3;
MESS 'ERREUR                  : ' ERR3 '%';
MESS 'CALCUL NUMéRIQUE (COQ4) : ' PCOQ4;
MESS 'ERREUR                  : ' ERR4 '%';
*------------------ CODE DE BON FONCTIONNEMENT -------------------------
SI ((ERR3 < 5) ET (ERR4 < 5));
   ERRE 0;
SINON;
   ERRE 5;
FINSI;
FIN;