* fichier : ccar3.dgibi
**
** --- 10 OCTOBRE 1997 ---
**
** TEST CAVITE CARRE
**
** teste LAPL KONV(SUPG) KMAB KMBT en IMPL et DFDT (centrep0 et p1)
** Formulation MACRO P0 et P1
** Formulation QUADR P0 et P1
*opti trace ps ;
OPTION ISOV 'SULI' ;
GRAPH = 'N' ;
COMPLET = FAUX ;
SI ( COMPLET ) ;
ds1=0.02 ; ds2=0.2 ;
*ds1=0.02 ; ds2=0.1 ;
ds1=0.01 ; ds2=0.05 ;
SINON ;
err1=2.e-2 ;
ds1=0.04 ; ds2=0.3 ;
FINSI ;
DEBPROC TEST KPRESS*MOT TYPK*MOT MACRO*MOT GRAPH*MOT ;
option dime 2 elem TYPK ;
p1= 0 0 ; p12=0.5 0. ; p2= 1 0 ;
ab=p1 d dini ds1 dfin ds2 p12 d dini ds2 dfin ds1 p2 ;
mt= ab trans dini ds1 dfin ds2 (0 0.5) trans dini ds2
dfin ds1 (0 0.5) ;
bc=cote 2 mt ; cd=cote 3 mt ; da=cote 4 mt ;
AA=bc moin (0.5 0.) ;
BB=ab plus (0. 0.5) ;
elim (AA et BB et mt) 1.e-3 ;
mt= chan mt QUAF ;
$mt=mode mt 'NAVIER_STOKES' MACRO ;
EPSS=1.e-8;
MU =1. ;
RO= 400. ;
DT=1. ;
* La cavité est fermée il faut imposer la pression en 1 point !
prep1=doma $mt kpress;
bcp=elem prep1 POI1 (lect 1) ;
*
CD=CHAN CD POI1;
CD=ELEM CD (LECT 2 PAS 1 ((NBEL CD) - 1)) ;
*
RV= eqex 'OMEGA' 0.7 'NITER' 5
'OPTI' 'EF' 'IMPL' 'SUPG' KPRESS
ZONE $mt OPER LAPN MU INCO 'UN'
ZONE $mt OPER KONV RO 'UN' MU DT INCO 'UN'
ZONE $mt OPER KMAB (-1.) 1.E-2 INCO 'UN' 'PRES'
ZONE $mt OPER KMBT (-1.) INCO 'PRES' 'UN'
'OPTI' 'EFMC' INCOD KPRESS
ZONE $mt OPER DFDT EPSS 'PRES' DT 'UN' MU INCO 'PRES'
;
RV= eqex RV CLIM
PRES TIMP bcp 0.
UN UIMP CD 1. UN VIMP CD 0. UN UIMP DA 0. UN VIMP DA 0.
UN UIMP AB 0. UN VIMP AB 0. UN UIMP BC 0. UN VIMP BC 0. ;
rv.inco= table inco ;
rv.inco.un = kcht $mt vect sommet (1.e-5 1.e-5) ;
rv.inco.pres = kcht $mt scal KPRESS 1.e-5 ;
exec rv ;
AA = chan AA quaf ;
BB = chan BB quaf ;
elim (mt et aa et bb ) 1.e-3 ;
$AA=mode AA 'NAVIER_STOKES' MACRO ;
$BB=mode BB 'NAVIER_STOKES' MACRO ;
srti=doma $AA 'MAILLAGE' ;
srth=doma $BB 'MAILLAGE' ;
evolV = EVOL 'CHPO' (rv.'INCO'.'UN') UX (srti ) ;
evolH = EVOL 'CHPO' (rv.'INCO'.'UN') UY (srth ) ;
evx=extr evolV 'ORDO' ;
list evx ;
evy=extr evolV 'ABSC' ;
evolV= evol 'MANU' 'Vitesse' evx 'Hauteur' evy ;
rv.'EVOLV'=evolV ;
rv.'EVOLH'=evolH ;
si ('EGA' graph 'O' );
TAB1=TABLE;
TAB1.'TITRE'=TABLE ;
TAB1 . 1 ='MARQ REGU ' ;
TAB1.'TITRE' . 1 = mot 'Composante_UX ' ;
DESS evolV 'TITX' 'R (m)' 'TITY' 'V (m/s)' LEGE TAB1 ;
TAB1.'TITRE' . 1 = mot 'Composante_UY ' ;
DESS evolH 'TITX' 'R (m)' 'TITY' 'V (m/s)' LEGE TAB1 ;
c1=vect (rv.inco.'UN') 0.3 ux uy jaune ;
trace c1 mt ;
pn= ELNO $mt (rv.inco.'PRES') KPRESS ;
trace pn mt ;
mess ' MAX P ' (maxi pn) 'MIN P ' (mini pn) ;
finsi ;
FINPROC RV ;
RV= test 'CENTRE' 'QUA8' 'MACRO' GRAPH ;
evv= (rv.'EVOLV');
evh= (rv.'EVOLH');
SI ( NON COMPLET ) ;
lrr=prog
2.43000E-08 +2.99486E-02 +5.66717E-02 +9.69482E-02 +.13621
+.19572 +.23763 +.21778 +.11062 +2.22662E-03
8.41545E-02 .14460 .21077 .29282 .49443
.71545 .99757 ;
lr=extr (rv.'EVOLV') 'ABSC' ;
lr = abs lr ;
ER=(resu( abs (lr - lrr) ))*0.0625 ;
mess ' Ecart sur CENTRE QUA8 MACRO ' er ;
si ( er > err1 ) ; erreur 5 ; finsi ;
FINSI ;
RV= test 'CENTREP1' 'QUA8' 'QUAF' GRAPH ;
evv= evv et (rv.'EVOLV');
evh= evh et (rv.'EVOLH');
SI ( NON COMPLET ) ;
lrr=prog
2.43000E-08 +2.16450E-02 +4.15949E-02 +7.32300E-02 +.10680
+.16017 +.21000 +.19926 +9.28972E-02 +2.03073E-02
6.24749E-02 .11395 .18806 .27293 .47598
.70673 .99757 ;
lr=extr (rv.'EVOLV') 'ABSC' ;
lr = abs lr ;
ER=(resu( abs (lr - lrr) ))*0.0625 ;
mess ' Ecart sur CENTREP1 QUA8 QUADR ' er ;
si ( er > err1 ) ; erreur 5 ; finsi ;
FINSI ;
RV= test 'CENTREP1' 'QUA8' 'MACRO' GRAPH ;
evv=evv et (rv.'EVOLV');
evh= evh et (rv.'EVOLH');
SI ( NON COMPLET ) ;
lrr=prog
2.43000E-08 +2.75896E-02 +5.30539E-02 +9.28867E-02 +.13248
+.19214 +.24900 +.23503 +.10435 +1.59022E-02
9.16737E-02 .15820 .22408 .30042 .50088
.72370 .99757;
lr=extr (rv.'EVOLV') 'ABSC' ;
lr = abs lr ;
ER=(resu( abs (lr - lrr) ))*0.0625 ;
mess ' Ecart sur CENTREP1 QUA8 MACRO ' er ;
si ( er > err1 ) ; erreur 5 ; finsi ;
FINSI ;
RV= test 'CENTREP0' 'QUA8' 'QUAF' GRAPH ;
evv= evv et (rv.'EVOLV');
evh= evh et (rv.'EVOLH');
SI ( NON COMPLET ) ;
lrr=prog
2.43000E-08 +3.29351E-02 +5.56572E-02 +8.29802E-02 +.10512
+.12415 +.12389 +6.57575E-02 +4.16763E-02 +2.59546E-02
+1.09653E-02 +5.26515E-03 5.43831E-02 .15114 .38804
.64474 .99757;
lr=extr (rv.'EVOLV') 'ABSC' ;
lr = abs lr ;
ER=(resu( abs (lr - lrr) ))*0.0625 ;
mess ' Ecart sur CENTREP0 QUA8 QUADR ' er ;
si ( er > err1 ) ; erreur 5 ; finsi ;
FINSI ;
RV= test 'CENTREP0' 'QUA8' 'MACRO' GRAPH ;
evv=evv et (rv.'EVOLV');
evh= evh et (rv.'EVOLH');
SI ( NON COMPLET ) ;
lrr=prog
2.43000E-08 3.88683E-02 6.63672E-02 9.75319E-02 +.12062
.13600 .13108 6.96810E-02 4.52764E-02 2.02565E-02
4.81434E-03 3.33747E-03 6.00279E-02 .15440 .39504
.65279 .99757;
lr=extr (rv.'EVOLV') 'ABSC' ;
lr = abs lr ;
ER=(resu( abs (lr - lrr) ))*0.0625 ;
mess ' Ecart sur CENTREP0 QUA8 MACRO ' er ;
si ( er > err1 ) ; erreur 5 ; finsi ;
FINSI ;
si ('EGA' graph 'O' );
titre 'Coupe oy à x=1/2 ' ;
TAB1=TABLE;
TAB1.'TITRE'= table ;
TAB1 . 1 ='TIRR MARQ CROI REGU ';
TAB1.'TITRE' . 1 ='MACRO STAB QUA4 ';
TAB1 . 2 ='TIRM MARQ PLUS REGU ';
TAB1.'TITRE' . 2 =' P1-Q2 ';
TAB1 . 3 ='TIRR MARQ ETOI REGU ';
TAB1.'TITRE' . 3 =' P1 iso Q2';
TAB1 . 4 ='TIRM MARQ CARR REGU ';
TAB1.'TITRE' . 4 =' P0-Q2 ';
TAB1 . 5 ='TIRR MARQ LOSA REGU ';
TAB1.'TITRE' . 5 =' P0 iso Q2 ';
DESS EVV 'TITX' 'Oy' LEGE TAB1 ;
titre 'Coupe ox à y=1/2 ' ;
DESS EVH 'TITX' 'Ox' LEGE TAB1 ;
FINSI ;
RV= test 'CENTRE' 'TRI6' 'MACRO' GRAPH ;
evv= (rv.'EVOLV');
evh= (rv.'EVOLH');
SI ( NON COMPLET ) ;
lrr=prog
2.43000E-08 3.78634E-02 7.36738E-02 .10991 .15048
.17902 .21175 .19267 .12321 1.24406E-02
8.49699E-02 .14204 .19784 .27675 .49157
.70911 .99757;
lr=extr (rv.'EVOLV') 'ABSC' ;
lr = abs lr ;
ER=(resu( abs (lr - lrr) ))*0.0625 ;
mess ' Ecart sur CENTRE TRI6 MACR ' er ;
si ( er > err1 ) ; erreur 5 ; finsi ;
FINSI ;
RV= test 'CENTREP1' 'TRI6' 'QUAF' GRAPH ;
evv=evv et (rv.'EVOLV');
evh= evh et (rv.'EVOLH');
SI ( NON COMPLET ) ;
lrr=prog
2.43000E-08 2.63551E-02 5.27287E-02 8.52686E-02 .12436
.17501 .22987 .20393 .11337 1.39453E-02
8.24727E-02 .13427 .21546 .29014 .49608
.71022 .99757;
lr=extr (rv.'EVOLV') 'ABSC' ;
lr = abs lr ;
ER=(resu( abs (lr - lrr) ))*0.0625 ;
mess ' Ecart sur CENTREP1 TRI6 QUADR ' er ;
si ( er > err1 ) ; erreur 5 ; finsi ;
FINSI ;
RV= test 'CENTREP1' 'TRI6' 'MACRO' GRAPH ;
evv=evv et (rv.'EVOLV');
evh= evh et (rv.'EVOLH');
SI ( NON COMPLET ) ;
lrr=prog
2.43000E-08 2.84128E-02 4.97722E-02 8.16473E-02 .10407
.12931 .14750 9.07169E-02 5.61807E-02 1.24650E-02
2.90796E-03 2.01045E-02 6.12103E-02 .15432 .40073
.67195 .99757 ;
lr=extr (rv.'EVOLV') 'ABSC' ;
lr = abs lr ;
ER=(resu( abs (lr - lrr) ))*0.0625 ;
mess ' Ecart sur CENTREP1 TRI6 MACRO ' er ;
si ( er > err1 ) ; erreur 5 ; finsi ;
FINSI ;
RV= test 'CENTREP0' 'TRI6' 'MACRO' GRAPH ;
evv=evv et (rv.'EVOLV');
evh= evh et (rv.'EVOLH');
SI ( NON COMPLET ) ;
lrr=prog
2.43000E-08 2.67197E-02 4.69013E-02 7.77459E-02 9.90798E-02
.12505 .14073 9.63472E-02 6.05324E-02 1.80841E-02
1.57786E-03 2.34364E-02 6.58036E-02 .16034 .40541
.67444 .99757;
lr=extr (rv.'EVOLV') 'ABSC' ;
lr = abs lr ;
ER=(resu( abs (lr - lrr) ))*0.0625 ;
mess ' Ecart sur CENTREP0 TRI6 MACRO ' er ;
si ( er > err1 ) ; erreur 5 ; finsi ;
FINSI ;
si ('EGA' graph 'O' );
titre 'Coupe oy à x=1/2 ' ;
TAB1=TABLE;
TAB1.'TITRE'= table ;
TAB1 . 1 ='TIRR MARQ CROI REGU ';
TAB1.'TITRE' . 1 ='P0 P1 Stab ';
TAB1 . 2 ='TIRM MARQ PLUS REGU ';
TAB1.'TITRE' . 2 =' P1 P2+Bulle ';
TAB1 . 3 ='TIRR MARQ ETOI REGU ';
TAB1.'TITRE' . 3 =' P1 iso P2';
TAB1 . 4 ='TIRM MARQ CARR REGU ';
TAB1.'TITRE' . 4 =' P0 iso P2';
DESS EVV 'TITX' 'Oy' LEGE TAB1 ;
titre 'Coupe ox à y=1/2 ' ;
DESS EVH 'TITX' 'Ox' LEGE TAB1 ;
FINSI ;
FIN ;
© Cast3M 2003 - All rights reserved.
Disclaimer