Datasets examples

* fichier : gamma.dgibi
*---------------------------------------------------------------------*
* Test de la fonction gamma : L2 = 'FONC' 'GAMMA' L1 ;                *
*---------------------------------------------------------------------*
*                                                                     *
* Test de quelques valeurs remarquables :                             *
L1       = 'PROG' -1.5 -0.5 0.5 1. 1.5 2. 2.5 3. 3.5 4. ;
RCPI1    = PI ** 0.5 ;
L2       = 'PROG' (4. * RCPI1 / 3.) (-2. * RCPI1) RCPI1 1.
                  (0.5 * RCPI1) 1. (0.75 * RCPI1) 2.
                  (0.125 * 15. * RCPI1) 6. ;
L3       = 'FONC' 'GAMMA' L1 ;
ERR1     = 'MAXI' 'ABS' ((L3 - L2) / L2) ;
*                                                                     *
* Test egalite : G(x)G(1-x)=PI/sin(PI*x) :                            *
E1       = 1. 'EXP' ;
L1       = 'PROG' (-17. * E1 * E1) PAS E1 (E1 ** 7.1) ;
L2       = ('PROG' ('DIME' L1) * PI) / ((180. * L1) 'SIN') ;
L3       = 'FONC' 'GAMMA' (('PROG' ('DIME' L1) * 1.) - L1) ;
L3       = L3 * ('FONC' 'GAMMA' L1) ;
L23      = (L3 - L2) / L2 ;
ERR2     = 'MAXI' 'ABS' L23 ;
*'LIST' ERR2 ;
*'DESS' ('EVOL' 'MANU' L1 L23) ;
*                                                                     *
ERR0     = 'MAXI' ('PROG' ERR1 ERR2) ;
'SI' (ERR0 '>' 1.E-10) ;
  'ERRE' 5 ;
'FINS' ;
*                                                                     *
'FIN' ;