Procedures | Cast3M

   1 : * HRAYO     PROCEDUR  FANDEUR   10/12/06    21:15:25     6804           
   2 : ************************************************************************
   3 :  'DEBPROC' HRAYO mcv*'MMODEL'
   4 :            mor1*'MMODEL' mar1*'MCHAML' tt1*'CHPOINT'
   5 :            mor2*'MMODEL' mar2*'MCHAML' tt2*'CHPOINT'
   6 :            rel12/'MAILLAGE' stefan/'FLOTTANT' ;
   7 :  
   8 : ************************************************************************
   9 : * Calcul d'un coefficient d'échange linéarisé pour le traitement
  10 : * du rayonnement infini et face à face :
  11 : *
  12 : * Données:
  13 : *   mcv     : modele de convection (sur maillage standard ou raccord)
  14 : *   mor1    : modele de rayonnement defini sur le maillage l1
  15 : *   mat1    : champ d'émissivités associé au modèle mor1
  16 : *   tt1     : champoint défini sur l1
  17 : *   indice 2: idem maillage l2
  18 : *   rel12   : géométrie définissant les relations entre le support
  19 : *             de l1 et le support de l2
  20 : *            (nécessaire pour le rayonnement face à face)
  21 : * Resultat
  22 : *   h       : coefficient d'échange linéarisé défini sur le modèle mcv
  23 : *
  24 : ************************************************************************
  25 : * constante de Stefan-Boltzmann
  26 : 'SI' ('NON' ('EXIS' stefan)) ;
  27 :  stefan = 5.673e-8 ;
  28 : 'FINSI' ;
  29 : 
  30 : * extraction des emissivites et transformation en champoint
  31 : * (de type SCAL pour les operations arithmétiques)
  32 : ee1 = 'EXCO' mar1 'EMIS' 'SCAL';
  33 : e1  = 'CHAN' 'CHPO' mor1 ee1 ;
  34 : 
  35 : ee2 = 'EXCO' mar2 'EMIS' 'SCAL';
  36 : ex2 = 'CHAN' 'CHPO' mor2 ee2 ;
  37 : 
  38 : t1 = 'NOMC' tt1 'SCAL' ;
  39 : tx2= 'NOMC' tt2 'SCAL' ;
  40 : 
  41 : * projection des champs sur le maillage l1
  42 : 'SI' ( 'EXIS' rel12 ) ;
  43 : * cas du rayonnement face a face ( rel12 existe)
  44 :  rel21 = 'INVE' rel12 ;
  45 :         t2 = 'KPRO' tx2 rel21 ;
  46 :         e2 = 'KPRO' ex2 rel21 ;
  47 : 'SINON' ;
  48 : * cas du rayonnement infini      ( rel12 n'existe pas)
  49 :         t2 = tx2 ;
  50 :  e2 = ex2 ;
  51 : 'FINSI' ;
  52 : 
  53 : * calcul sur le maillage l1
  54 : r1 = 1. '-' e1 ;
  55 : r2 = 1. '-' e2 ;
  56 : dd = r1 '*' r2 ;
  57 : d = 1. '-' dd ;
  58 : ee=(e1 '*' e2) '/' d ;
  59 : sie = stefan '*'ee ;
  60 : 2t1 = t1 '*' t1; 2t2 = t2 '*' t2;
  61 : hh1 = (2t1 '+' 2t2) '*' (t1 '+' t2) ;
  62 : hh  = sie '*' hh1 ;
  63 : h1 = 'NOMC' hh 'H' 'NATU' DIFFUS  ;
  64 : 
  65 : * projection sur le mailllage l2
  66 : 'SI' ( 'EXIS' rel12 ) ;
  67 : * cas du rayonnement face a face
  68 : h2 = 'KPRO' h1 rel12 ;
  69 : h12 = h1 'ET' h2 ;
  70 : 'SINON' ;
  71 : * cas du rayonnement infini
  72 : h12 = h1 ;
  73 : 'FINSI' ;
  74 : 
  75 : * definition du champ h sur le modele de convection
  76 : *he  = 'CHAN' 'CHAM' h12 mcv 'NOEU' ;
  77 : he  = 'CHAN' 'CHAM' h12 mcv 'RIGIDITE' ;
  78 : h   = 'CHAN' 'TYPE' he  'CARACTERISTIQUE' ;
  79 : 'FINPROC' h ;
  80 :  
  81 :