Datasets examples

*******************************************************

*  Cas test de la procedure FTRAN

*******************************************************

*  Developpe par : 

*     Alberto FRAU             (alberto.frau[at]cea.fr)     

*     Benjamin RICHARD     (benjamin.richard[at]cea.fr)

* 

*******************************************************

* Institution : 

*     CEA/DEN/DANS/DM2S/SEMT/EMSI

*******************************************************

* Commentaires

*

*  On calcule la solution d'un oscillateur 1DDL et on deduit

*  la fonction de transfert entre le deplacement au sommet et la

*  force appliquÃ©e au meme point

*

*******************************************************

*

* Options

OPTI DIME 3 MODE TRID ELEM SEG2;

*

* Sortie graphique

GRAP1 = CHAINE 'N';

*

* Caracteristique oscillatuer

FR_OSC1 = 20.;

OM_OSC1 = ((2)*(PI))*(FR_OSC1);

EP_OSC1 = 0.5;

M_OSC1 = 1000.;

K_OSC1 = ((OM_OSC1)**(2))*(M_OSC1);

*

* Caracteristique force

AMP_FOR1 = 100.;

FR_FOR1 = 2.;

OM_FOR1 = ((2)*(PI))*(FR_FOR1);

FMAX1 = 80.;

TMAX1 = (20.)/(FR_FOR1);

*

* Determination des coef pour la solution analytique

BETA1 = (OM_FOR1)/(OM_OSC1);

A1 = ((-1)*(((AMP_FOR1)/(K_OSC1))*((((2)*(EP_OSC1))*(BETA1))/(((1 - 

    ((BETA1)**(2)))**(2)) + 

   (((2)*(EP_OSC1))*(BETA1)**(2))))));

B1 = (((-1)*(OM_FOR1/OM_OSC1))*(((AMP_FOR1)/(K_OSC1))*

    (((1 - ((BETA1)**(2)))/

    (((1 - ((BETA1)**(2)))**(2)) + 

   (((2)*(EP_OSC1))*(BETA1)**(2)))))));

*

* Definition des plages temporelle et frequentielle

DT1 = (1)/((2)*(FMAX1));

LT1 = PROG 0. PAS DT1 TMAX1;

*

* Determination du deplacement et de la vitesse

OM_OSC2 = ((OM_OSC1)/(PI))*(180);

OM_FOR2 = ((OM_FOR1)/(PI))*(180);

LU1 = ((EXP(((-1)*(EP_OSC1))*(LT1)))*(((A1)*(COS((OM_OSC2)*(LT1))))

      + (((B1)*(SIN((OM_OSC2)*(LT1))))))) + (((AMP_FOR1)/(K_OSC1))*

      ((((1 - ((BETA1)**(2)))*(SIN((OM_FOR2)*(LT1)))) - (((EP_OSC1)*

     ((BETA1)**(2)))*(COS((OM_FOR2)*(LT1)))))/((((1 - 

      ((BETA1)**(2)))**(2)) + (((2)*(EP_OSC1))*(BETA1)**(2))))));

LV1 = (((EXP(((-1)*(EP_OSC1))*(LT1)))*(OM_OSC1))*(((A1)*((-1)*

   (SIN((OM_OSC2)*(LT1))))) + (((B1)*(COS((OM_OSC2)*(LT1))))))) + 

   ((((AMP_FOR1)*(OM_FOR1))/(K_OSC1))*((((1 - ((BETA1)**(2)))*

   (COS((OM_FOR2)*(LT1)))) + (((EP_OSC1)*((BETA1)**(2)))*

   (SIN((OM_FOR2)*(LT1)))))/((((1 - ((BETA1)**(2)))**(2)) + 

   (((2)*(EP_OSC1))*(BETA1)**(2))))));

*

* Evolution de la force

LF1 = (AMP_FOR1)*(SIN((OM_FOR2)*(LT1)));

EV_FOR1 = EVOL (ROUG) MANU 'Temps [s]' LT1

                            'Forc [N]' LF1;

*

EV_DEP1 =  EVOL (BLEU) MANU 'Temps [s]' LT1

                            'Depl [m]' LU1;

EV_VIT1 =  EVOL (VERT) MANU 'Temps [s]' LT1

                            'Depl [m]' LV1;

SI ('NEG' GRAP1 'N');

  DESS EV_FOR1 TITR 'Evolution de la force';

  DESS EV_DEP1 TITR 'Evolution du deplacement';

  DESS EV_VIT1 TITR 'Evolution de la vitesse';

FINSI;

*

F_TTR1 = FTRAN EV_DEP1 EV_FOR1 FMAX1 1;

*

SI ('NEG' GRAP1 'N');

  DESS F_TTR1 TITR 'Fonction de Transfert';

FINSI;

*

II1 VAL_X DENS1 = MAXI F_TTR1;

*

* Test sur la frequence de l'oscillateur

SI ((ABS(VAL_X - FR_OSC1)) > 0.00001);

 ERREUR 5;

FINSI;

*

FIN;