* fichier : dyne02.dgibi
******************************
*
* Impact d'une barre sur un plan rigide
* Calcul sur base modale
* Opérateur Dyne
* D. Combescure
* Aout 2006
*
********************************
*
*GRAPH = VRAI;
GRAPH = FAUX;
*
opti dime 3 elem seg2;
*
L1 = 1.;
n1 = 10;
L = 2.;
n2 = 10;
*
p1 = 0. 0. 0.;
p2 = L1 0. 0.;
p2b = L1 0. 0.;
p3 = L 0. 0.;
lig1 = d n1 p1 p2;
lig2 = d n2 p2b p3;
mesh = lig1;
*
S1 = 0.1;
*
E1 = 2000.;
nu1 =0.2;
ro1 = 7.8D-3;
*
mod1 = modl mesh mecanique elastique BARR;
mat1 = mate mod1 YOUN E1 NU nu1 RHO ro1
SECT S1;
*
rig1 = RIGI mod1 mat1;
mas1 = mass mod1 mat1;
bl1 = (BLOQ lig1 UY) et (bloq lig1 UZ);
bl2 = (BLOQ lig2 UY) et (bloq lig2 UZ);
bl2b = (BLOQ p2b DEPL);
*
For1 = MAS1 * (MANU CHPO mesh 1 UX (-9.81));
*
nmode = 2;
FR = VIBR PROCHE (PROG nmode) (LECT nmode) (RIG1 et bl1 et bl2b)
MAS1 MULT TBAS;
*
SI GRAPH;
oeil = 0. 0. 100.;
Repeter bou1 nmode;
FIFI = FR . MODES . &Bou1 . FREQUENCE ;
TT = FR . MODES . &Bou1 . DEFORMEE_MODALE ;
DEf1 = DEFO mesh TT;
titre (CHAIN 'Frequence=' Fifi);
trac oeil def1;
fin bou1;
FINSI;
*
*
* Appel à DYNE
*
************************************************
* TEMPS
*************************
*
DT = 1.E-4 ;
NTT = 5000 ;
*
*************************
* TABLE AMORTISSEMENT
*************************
*
TAMOR = TABLE 'AMORTISSEMENT' ;
AMO = PROG NMODE*0.0 ;
TAMOR . AMORTISSEMENT = AMOR FR AMO ;
*
*************************
* TABLE CHARGEMENT (CHARG1 CHARG2 CHARG3)
*************************
TCHAR = TABLE 'CHARGEMENT' ;
*
Ampl = 1.0;
Evotime = evol manu (prog 0. 0.01 100.)
(Ampl*(prog 0. 1. 1.));
CHA1 = CHAR For1 Evotime;
CHAP1 = PJBA FR CHA1;
TCHAR.'BASE_A' = CHAP1;
***********************************************************
*
* LIAISONS
*
***********************************************************
*
TILIA = TABLE 'LIAISON' ;
TTLB = TABLE 'LIAISON_B' ;
TILIA.'LIAISON_B' = TTLB ;
***********************************************************
* POINT POINT
***********************************************************
*
Kliai = 30.0*E1*S1/L1;
Jeuliai = .01;
TLA12 = TABLE 'LIAISON_ELEMENTAIRE' ;
TTLB . 1 = TLA12 ;
TLA12 . 'TYPE_LIAISON' = MOT 'POINT_POINT';
TLA12 . 'POINT_A' = P2 ;
TLA12 . 'POINT_B' = P2b ;
TLA12. 'NORMALE' = ( -1. 0. 0.);
TLA12 . 'RAIDEUR' = Kliai ;
TLA12 . 'JEU' = JeuLiai ;
TLA12 . 'AMORTISSEMENT' = 0. ;
*************************
* TABLE SORTIE
*************************
*
TABSOR = TABLE 'SORTIE';
*
TABSOR2 = TABLE 'LIAISON_B' ;
TABSOR.'LIAISON_B' = TABSOR2 ;
*
TVARPP = TABLE 'VARIABLE' ;
TVARPP.'FORCE_DE_CHOC_POINT_A' = VRAI ;
TVARPP.'FORCE_DE_CHOC_POINT_B' = VRAI ;
TVARPP.'UY_POINT_A' = VRAI ;
TVARPP.'UY_POINT_B' = VRAI ;
TVARPP.'VITESSE' = VRAI ;
*
TVARGD = TABLE 'VARIABLE' ;
TVARGD.'FORCE_DE_CHOC' = VRAI ;
TVARGD.'VITESSE' = VRAI ;
TVARGD.'UY' = VRAI ;
*
TABSOR2. TLA12 = TVARPP;
*
************************************************
* CALCUL TEMPOREL PROPREMENT DIT
***********************************************
*
*TRESU = DYNE DE_VOGELAERE FR TAMOR TCHAR TILIA
* NTT DT 1 TABSOR ;
TRESU = DYNE DIFFERENCES_CENTREES FR TAMOR TCHAR TILIA
NTT DT 1 TABSOR ;
*
************************************************
* TRACE DES DEPLACEMENTS EN FONCTION DU TEMPS
**********************************************
*
UXP2 = EVOL VERT RECO TRESU FR 'DEPL' P2 UX ;
UXP3 = EVOL BLEU RECO TRESU FR 'DEPL' P3 UX ;
UXP3 = evol bleu manu (extr UXP3 absc)
((extr UXP3 ordo) + (PROG (dime (extr UXP3 ordo) )*(-0.01)));
VXP2 = EVOL VERT RECO TRESU FR 'VITE' P2 UX ;
VXP3 = EVOL BLEU RECO TRESU FR 'VITE' P3 UX ;
*
*
*
TDS = TRESU . 'TEMPS_DE_SORTIE' ;
RESCHOC = TRESU . TLA12;
FchocB = RESCHOC. FORCE_DE_CHOC_POINT_B;
FchocA = RESCHOC. FORCE_DE_CHOC_POINT_A;
*
EVFchoA = 'EVOL' 'MANU' TDS FChocA;
EVFchoB = 'EVOL' 'MANU' TDS FChocB;
*
SI GRAPH;
ta = table;
ta.2= 'TIRR';
DESS (UXP2 ET UXP3) ta XBORD 0. 0.20 TITRE 'DEPL BASE MODALE' ;
DESS (VXP2 ET VXP3) ta XBORD 0. 0.20 TITRE 'VITE BASE MODALE' ;
DESS EVFchoA XBORD 0. 0.20 ;
DESS EVFchoB XBORD 0. 0.20 ;
FINSI;
*
FIN;
*******************
© Cast3M 2003 - All rights reserved.
Disclaimer