* fichier : ther3.dgibi
GRAPH='N';
SAUT PAGE ;
*-------------------------------------------------------------------*
* TEST THER3 *
* *
* TEST DES CL DE TEMPERATURE POUR PYR5 CUB8 TET4 PRI6 TRIDIM: *
* ----------------------------------------------------------- *
* *
* TEMPERATURE IMPOSEE + CONVECTION *
* + FLUX *
* + SOURCE *
* *
* Comme dans le test THER1, cet exemple permet de tester les condi- *
* tions aux limites de temp{rature pour des {l{ments massifs lin{- *
* aires (PYR5, CUB8, TET4, PRI6). *
* *
* Un parall{l{pip}de rectangle constitu{ des {l{ments cit{s plus *
* haut est soumis @ une temp{rature impos{e @ sa face sup{rieure et *
* @ une condition de flux impos{e, une condition de source volumique*
* ou une condition de convection forc{e. *
* *
* Les r{sultats sont pr{sent{s sous forme d'isotemp{rature dans une *
* tranche verticale du parall{l{pip}de. Les courbes doivent etre *
* parall}les aux faces sup{rieure et inf{rieure. *
* *
* 21 DECEMBRE 1988. *
*-------------------------------------------------------------------*
*
*--- Disposition des noeuds des {l{ments :
*
* A4________F4_________D4
* / / /|
* / / / |
* B4_________E4_________C4 D3
* | | | / IN: noeud milieu de
* | 6PYR5 | 12TE4 |/ (AN BN EN FN AN+1 BN+1 EN+1 FN+1)
* B3_________E3_________C3
*
* A3________F3_________D3
* / / /| JN: noeud milieu de
* / / / | (DN CN EN FN DN+1 CN+1 EN+1 FN+1)
* B3_________E3_________C3 D2
* | | | /
* | 1CUB8 | 6PYR5 |/
* B2_________E2_________C2
*
* A2________F2_________D2
* / / /|
* / / / |
* B2_________E2_________C2 D1
* | | | /
* | 6PYR5 | 2PRI6 |/
* B1_________E1_________C1
*
*
*------------------------------------------------------------------------
*
*--- OPTIONS GENERALES DE CALCUL:
*
TITRE 'THER3 - C.L. TEMPERATURE - ELEMENTS LINEAIRES 3D' ;
OPTION ECHO 0 ;
OPTION DIME 3 ELEM SEG2 ;
TEMPS ;
*
*--- CREATION DE LA GEOMETRIE: POINTS SUPPORTS DES ELEMENTS
*
A1=0. 0. 0.; B1=1. 0. 0.; C1=1. 3. 0.; D1=0. 3. 0.;
A2=0. 0. 2.; B2=1. 0. 2.; C2=1. 3. 2.; D2=0. 3. 2.;
A3=0. 0. 4.; B3=1. 0. 4.; C3=1. 3. 4.; D3=0. 3. 4.;
A4=0. 0. 6.; B4=1. 0. 6.; C4=1. 3. 6.; D4=0. 3. 6.;
E1=1. 1.5 0.; F1=0. 1.5 0.; E2=1. 1.5 2.; F2=0. 1.5 2.;
E3=1. 1.5 4.; F3=0. 1.5 4.; E4=1. 1.5 6.; F4=0. 1.5 6.;
I1= .5 .75 1.; I3= .5 .75 5.; J1= .5 2.25 1.; J2=.5 2.25 3.;
J3= .5 2.25 5.;
*
*--- CREATION DES PYRAMIDES A 5 NOEUDS:
*
PP01 = MANU PYR5 A1 B1 E1 F1 I1 ;
PP02 = MANU PYR5 E1 F1 F2 E2 I1 ;
PP03 = MANU PYR5 E2 F2 A2 B2 I1 ;
PP04 = MANU PYR5 A2 B2 B1 A1 I1 ;
PP05 = MANU PYR5 B1 E1 E2 B2 I1 ;
PP06 = MANU PYR5 A1 F1 F2 A2 I1 ;
*
PP07 = MANU PYR5 D2 C2 E2 F2 J2 ;
PP08 = MANU PYR5 E2 F2 F3 E3 J2 ;
PP09 = MANU PYR5 E3 F3 D3 C3 J2 ;
PP10 = MANU PYR5 D3 C3 C2 D2 J2 ;
PP11 = MANU PYR5 C2 E2 E3 C3 J2 ;
PP12 = MANU PYR5 D2 F2 F3 D3 J2 ;
*
PP13 = MANU PYR5 A3 B3 E3 F3 I3 ;
PP14 = MANU PYR5 E3 F3 F4 E4 I3 ;
PP15 = MANU PYR5 E4 F4 A4 B4 I3 ;
PP16 = MANU PYR5 A4 B4 B3 A3 I3 ;
PP17 = MANU PYR5 B3 E3 E4 B4 I3 ;
PP18 = MANU PYR5 A3 F3 F4 A4 I3 ;
*
*--- VOLUME COMPOSE DES 18 PYRAMIDES A 5 NOEUDS:
*
VOL1 = PP01 ET PP02 ET PP03 ET PP04 ET PP05 ET PP06 ET PP07 ET PP08
ET PP09 ET PP10 ET PP11 ET PP12 ET PP13 ET PP14 ET PP15 ET PP16
ET PP17 ET PP18 ;
*
*--- CREATION DES PRISMES A 6 NOEUDS:
*
PR01 = MANU PRI6 E1 D1 F1 E2 D2 F2 ;
PR02 = MANU PRI6 E1 C1 D1 E2 C2 D2 ;
*
*--- VOLUME COMPOSE DES 2 PRISMES A 6 NOEUDS:
*
VOL2 = PR01 ET PR02 ;
*
*--- CREATION DES TETRAEDRES A 4 NOEUDS:
*
TT01 = MANU TET4 E3 D3 F3 J3 ;
TT02 = MANU TET4 E3 D3 C3 J3 ;
TT03 = MANU TET4 C3 D4 D3 J3 ;
TT04 = MANU TET4 C3 D4 C4 J3 ;
TT05 = MANU TET4 C4 F4 E4 J3 ;
TT06 = MANU TET4 C4 F4 D4 J3 ;
TT07 = MANU TET4 E3 F4 E4 J3 ;
TT08 = MANU TET4 E3 F4 F3 J3 ;
TT09 = MANU TET4 E3 C4 C3 J3 ;
TT10 = MANU TET4 E3 C4 E4 J3 ;
TT11 = MANU TET4 F3 D4 D3 J3 ;
TT12 = MANU TET4 F3 D4 F4 J3 ;
*
*--- VOLUME COMPOSE DES 12 TETRAEDRES A 4 NOEUDS
*
VOL3 = TT01 ET TT02 ET TT03 ET TT04 ET TT05 ET TT06
ET TT07 ET TT08 ET TT09 ET TT10 ET TT11 ET TT12 ;
*
*--- CREATION DU CUBE A 8 NOEUDS:
*
VOL4 = MANU CUB8 B2 E2 F2 A2 B3 E3 F3 A3 ;
*
*--- REUNION DES VOLUMES ELEMENTAIRES:
*
VOLTOT = VOL1 ET VOL2 ET VOL3 ET VOL4 ;
*
VOLSOUR = PP13 ET PP14 ET PP15 ET PP16 ET PP17 ET PP18
ET TT01 ET TT02 ET TT03 ET TT04 ET TT05 ET TT06
ET TT07 ET TT08 ET TT09 ET TT10 ET TT11 ET TT12 ;
*
*--- L_INF ETANT BASEE SUR LES POINTS: A1 B1 E1 C1 D1 F1
*
DD1 = D 1 A1 B1 ;
DD2 = D 1 B1 E1 ;
DD3 = D 1 E1 C1 ;
DD4 = D 1 C1 D1 ;
DD5 = D 1 D1 F1 ;
DD6 = D 1 F1 A1 ;
*
L_INF = DD1 ET DD2 ET DD3 ET DD4 ET DD5 ET DD6 ;
*
*--- SURFACE INFERIEURE:
*
S_INF = SURF L_INF PLANE ;
*
*--- L_SUP ETANT BASEE SUR LES POINTS: A4 B4 E4 C4 D4 F4
*
LL1 = D 1 A4 B4 ;
LL2 = D 1 B4 E4 ;
LL3 = D 1 E4 C4 ;
LL4 = D 1 C4 D4 ;
LL5 = D 1 D4 F4 ;
LL6 = D 1 F4 A4 ;
*
L_SUP = LL1 ET LL2 ET LL3 ET LL4 ET LL5 ET LL6 ;
*
*--- SURFACE SUPERIEURE:
*
S_SUP = SURF L_SUP PLANE ;
*
*--- DONNEES DU PROBLEME DE THERMIQUE:
*
*--- MODELISATION:
*
MOD1 = MODL VOLTOT THERMIQUE ISOTROPE ;
MOD2 = MODL S_SUP thermique CONVECTION ;
*
*--- DONNEE DES CARACTERISTIQUES DU MATERIAU:
*
MAT1 = MATR MOD1 'K' 100. ;
MAT2 = MATR MOD2 'H' 15. ;
*
*--- CREATION DES MATRICES DE CONDUCTIVITE:
*
CND1 = CONDUCTIVITE MOD1 MAT1 ;
CND2 = CONDUCTIVITE MOD2 MAT2 ;
*
*--- TEMPERATURES IMPOSEES: BLOQUE + DEPI
*
BB1 = BLOQUE S_INF 'T' ;
EE1 = DEPI BB1 10. ;
*
*--- FLUX EQUIVALENTS A LA CONDITION DE CONVECTION:
*
CNV1 = CONVECTION MOD2 MAT2 'T' 200. ;
*
*--- FLUX IMPOSE:
*
FLU1 = FLUX MOD1 20. S_SUP ;
*
*--- SOURCE VOLUMIQUE:
*
S1 = SOURCE MOD1 100. VOLSOUR ;
*
*--- ASSEMBLAGE DES TERMES DE CONDUCTIVITE:
*
CCC1 = CND1 ET CND2 ET BB1 ;CCC2 = CND1 ET BB1 ;
*
*--- ASSEMBLAGE DES TERMES DE FLUX EQUIVALENTS:
*
FFF1 = EE1 ET CNV1 ;FFF2 = EE1 ET FLU1 ;FFF3 = EE1 ET S1 ;
*
*--- 1ERE RESOLUTION: TEMPERATURE IMPOSEE + CONVECTION
*
CHTER1 = RESOUDRE CCC1 FFF1 ;
*
*--- 2EME RESOLUTION: TEMPERATURE IMPOSEE + FLUX
*
CHTER2 = RESOUDRE CCC2 FFF2 ;
*
*--- 3EME RESOLUTION: TEMPERATURE IMPOSEE + SOURCE
*
CHTER3 = RESOUDRE CCC2 FFF3 ;
*
*--- CHAMPS THERMIQUES ET RESULTATS:
*
*----------------------*--------------*---------------*--------------*
* CONDITION IMPOSEE * CONVECTION * FLUX * SOURCE *
*----------------------*--------------*---------------*--------------*
* TEMPERATURE MAXIMALE * 101.23 * 11.154 * 19.780 *
*----------------------*--------------*---------------*--------------*
*
* REMARQUE : LE CHAMP DE TEMPERATURE RESULTAT EST SENSIBLE A LA
* REPARTITION DES POINTS D'INTEGRATION DANS LE MAILLAGE.
*
*--- POST-TRAITEMENT: TRACE DU MAILLAGE ET DES CHAMPS RESULTATS
*
OEIL = 100. 100. 100. ;
TITRE 'ELEMENTS PYR5 CUB8 TET4 PRI6 : MAILLAGE' ;
SI(NEG GRAPH 'N');
TRACER OEIL VOLTOT ;
FINSI;
OEIL = 100. 0. 0. ;
TITRE 'ELEMENTS PYR5 CUB8 TET4 PRI6 : CONVECTION' ;
SI(NEG GRAPH 'N');
TRACER OEIL VOLTOT CHTER1 ;
FINSI;
TITRE 'ELEMENTS PYR5 CUB8 TET4 PRI6 : FLUX' ;
SI(NEG GRAPH 'N');
TRACER OEIL VOLTOT CHTER2 ;
FINSI;
TITRE 'ELEMENTS PYR5 CUB8 TET4 PRI6 : SOURCE' ;
SI(NEG GRAPH 'N');
TRACER OEIL VOLTOT CHTER3 ;
FINSI;
T1 = EXTR CHTER1 T B4;
T2 = EXTR CHTER2 T A4;
T3 = EXTR CHTER3 T D4;
SAUT PAGE ;
SAUT 2 LIGN ;
MESS ' TEMPERATURE MAXIMUM DE REFERENCE CALCULEE ' ;
SAUT 1 LIGN ;
MESS ' CONVECTION 101.23 ' T1 ;
MESS ' FLUX 11.154 ' T2 ;
MESS ' SOURCE 19.780 ' T3 ;
TEMPS ;
* CODE DE FONCTIONNEMENT SUR LA TEMP. MAX. EN CONVECTION
TREF=101.23;RESI=ABS((T1-TREF)/TREF);
SI(RESI <EG 5E-2);
ERRE 0;
SINO;
ERRE 5;
FINSI;
FIN;
© Cast3M 2003 - All rights reserved.
Disclaimer