* fichier : fsi5.dgibi
* CAS TEST DU 91/10/04 PROVENANCE : PETI
OPTI ECHO 0;
SAUT PAGE;
*
******************************************************************
* *
* TEST FSI5 *
* *
* ANNULAR FLUID LAYER WITH FREE SURFACE *
* *
* Calculation of the frequencies of an annular water layer *
* with free surface, for m= 1 *
* The mean radius is 0.5m and the thickness of annulus is 5mm *
* *
* *
* P5_________ *
* | | *
* | | *
* | | *
* | fluid | *
* | | *
* | | *
* | | *
* P6 ----------- *
* *
* *
* *
* The boundary conditions are *
* *
* dp | *
* ---- | = 0. *
* dz | h = 0. *
* *
* dp | *
* ---- | = 0. *
* dr | r = Ri , Ro *
******************************************************************
*
TEMPS;
*
OPTI DIME 2;
OPTI MODE FOUR 1 ;
OPTI ELEM QUA4;
*
GRAPH = 'N';
*
*================================================================*
* geometry *
*================================================================*
*
* Dimensions en metres
*
* Points
*
THICK = 5.0 ;
N1 = 20 ;
R = 500. ;
P5 = (R - (THICK * 0.5 )) 1000.0 ;
P6 = (R - (THICK * 0.5 )) 0.0 ;
*
*
S5 =P5 D N1 P6 ;
*
WATER = S5 TRAN 1 (THICK 0. ) ;
FRSUR = COTE WATER 4 ;
*
* OPTIO FOR TRACE
*
SI (NEG GRAPH 'N');
TITR ' FSI5 : MAILLAGE';
TRAC QUAL (WATER ET (0 0));
FINSI;
*
*================================================================*
* modl - materiau - rigidite - masse *
*================================================================*
*
MODLIQ =MODL WATER LIQUIDE LQU4 ;
MODSUR =MODL FRSUR LIQUIDE LSU2;
*
MATLIQ = MATR (MODLIQ ET MODSUR)
RHO 1.E-9 RORF 1.E-9 CSON 1435.E3 CREF 1435.E3 LCAR 1000. G 9810.;
*
RIG1 = RIGI (MODLIQ ET MODSUR) MATLIQ ;
MAS1 = MASS (MODLIQ ET MODSUR) MATLIQ ;
*
*
*==============================================================*
* boundary conditions *
*==============================================================*
*
* No explicit boundary condition ; the boundary conditions are
* natural .
*
*==============================================================*
* theritical value of frequency
*
* 5
FRE1 = 0.6922;
LIST1 = PROG FRE1 ;
*
*==============================================================*
* calculation of the frequencies *
* and *
* extraction of some results *
*==============================================================*
*
*
* Use of the operator VIBR. (option PROC)
*
*
RESUL = VIBR PROC LIST1 RIG1 MAS1 ;
*
*==============================================================*
* results *
*==============================================================*
*
MESS ' RESULTATS ';
MESS ' --------- ';
SAUT 1 LIGN;
*
*
FRE2 = TIRE RESUL FREQ RANG 1;
ERG = 100 * (ABS ((FRE1 - FRE2 ) / FRE1 ));
MESS ' MODE ' 1 ;
MESS ' ----------';
MESS ' Frequence theorique :' FRE1 'Hz';
MESS ' Frequence calculee :' FRE2 'Hz';
MESS ' Soit un ecart de : ' ERG '%';
SAUT 1 LIGN;
*
* mode shape extraction and optional trace
*
SI (NEG GRAPH 'N');
MOD = TIRE RESUL DEPL RANG 1;
DEF0 = DEFO FRSUR MOD 0. ;
DEF = DEFO FRSUR MOD VERT;
TRAC (DEF ET DEF0);
FINSI;
*
*==============================================================*
* code validation *
*==============================================================*
*
ERGMAX = ERG ;
*
SI (ERGMAX <EG 5.);
ERRE 0;
SINON;
ERRE 5;
FINSI;
*
SAUT 1 LIGN;
TEMPS;
SAUT 1 LIGN;
*
FIN;
*
© Cast3M 2003 - All rights reserved.
Disclaimer