Datasets examples

* fichier : plus1.dgibi
'OPTI' 'ECHO' 0 ;
************************************************************************
* NOM         : PLUS1
* DESCRIPTION : Test de non-régression de '+' sur les CHPOINTs
*               Avant la fiche 5834, ce test donnait une erreur.
*
*
*
* LANGAGE     : GIBIANE-CAST3M
* AUTEUR      : Stéphane GOUNAND (CEA/DEN/DM2S/SFME/LTMF)
*               mél : gounand@semt2.smts.cea.fr
**********************************************************************
* VERSION    : v1, 07/08/2007, version initiale
* HISTORIQUE : v1, 07/08/2007, création
* HISTORIQUE :
* HISTORIQUE :
************************************************************************
*
interact = FAUX ;
*
'SAUTER' 2 'LIGNE' ;
'MESSAGE' ' Execution de plus1.dgibi' ;
'SAUTER' 2 'LIGNE' ;
*
'OPTION' 'DIME' 1  ;
pd1 = 'POIN' -1. ; pA = 'POIN' 0. ; pD = 'POIN' 3. ; pB = 'POIN' 1. ;
mt = pA ; _mt = pA 'ET' pB ;
ch1 = ('MANUEL' 'CHPO' _mt 1 'UX' 1.)
  '+' ('MANUEL' 'CHPO' mt 1 'P' 2.) ;
ch2 = ('MANUEL' 'CHPO' mt 1 'T' 2.)
  '+' ('MANUEL' 'CHPO' _mt 2 'UX' 1. 'VX' 4.) ;
*
chsref = ('MANUEL' 'CHPO' pA 'UX' 2. 'VX' 4. 'P' 2. 'T' 2.)
     '+' ('MANUEL' 'CHPO' pB 'UX' 2. 'VX' 4.) ;
*
lok = VRAI ; errref = 1.D-10 ;
ch3 = ch2 '+' ch1 ;
ch4 = ch1 '+' ch2 ;
*
md1 = 'MAXIMUM' ('-' chsref ch3) 'ABS' ;
t1 = ('EGA' md1 0. errref) ;
'SI' ('NON' t1) ;
   cherr = 'CHAINE' '!!! Erreur, on aurait voulu md1=' md1 ' < '
                     errref ;
   'MESSAGE' cherr ;                          
'FINSI' ;                          
lok = lok 'ET' t1 ;
*
md2 = 'MAXIMUM' ('-' chsref ch4) 'ABS' ;
t2 = ('EGA' md2 0. errref) ;
'SI' ('NON' t2) ;
   cherr = 'CHAINE' '!!! Erreur, on aurait voulu md2=' md2 ' < '
                     errref ;
   'MESSAGE' cherr ;                          
'FINSI' ;                          
lok = lok 'ET' t2 ;
* Fin du jeu de donnees 
*
'SAUTER' 2 'LIGNE' ;
'SI' lok ;
   'MESSAGE' 'Tout sest bien passe' ;
'SINON' ;
   'MESSAGE' 'Il y a eu des erreurs' ;
'FINSI' ;   
'SAUTER' 2 'LIGNE' ;
'SI' interact ;
   'OPTION' 'DONN' 5 'ECHO' 1 ;
'FINSI' ;   
'SI' ('NON' lok) ;
   'ERREUR' 5 ;
'FINSI' ;   
*
* End of dgibi file PLUS1
*
'FIN' ;