* fichier : ther1.dgibi
GRAPH='N';
SAUT PAGE ;
*-------------------------------------------------------------------*
* TEST THER1
* *
* TEST DES CL DE TEMPERATURE POUR QUA4 ET TRI3 BIDIMENSIONNELS *
* ------------------------------------------------------------ *
* *
* TEMPERATURE IMPOSEE + CONVECTION *
* + FLUX *
* + SOURCE *
* *
* Ce test permet de v{rifier le bon fonctionnement des divers *
* op{rateurs thermiques de CASTEM2000. *
* *
* Une plaque rectangulaire constitu{e d'{l{ments QUA4 et TRI3 est *
* soumise @ une temp{rature impos{e @ une de ses extr{mit{s et suc- *
* essivement @ une condition de convection forc{e, @ une condition *
* de flux impos{ et @ une condition de source volumique impos{e. *
* *
* Les r{sultats sont pr{sent{s sous forme d'isotemp{ratures (elles *
* doivent etre parall}les aux deux faces sup{rieure et inf{rieure *
* de la plaque) et par la valeur de la temp{rature obtenue @ la *
* face inf{rieure de la plaque (la temp{rature est impos{e @ la *
* surface sup{rieure). *
* *
* *
*-------------------------------------------------------------------*
*
SAUT PAGE ;
*-------------- OPTIONS GENERALES DE CALCUL -----------------------------
*
TITRE 'C.L. DE TEMPERATURE - ELEMENTS TRI3 ET QUA4' ;
OPTION DIME 2 ELEM QUA4 TRI3 ;
*OPTION ECHO 0 ;
TEMPS ;
*
*------------- CREATION DE LA GEOMETRIE: POINTS SUPPORTS DES ELEMENTS --
*
A1 = 0. 0. ;A2 = 1.5 0. ;A3 = 3. 0. ;
B1 = 0. 2. ;B2 = 1.5 2. ;B3 = 3. 2. ;
C1 = 0. 4. ;C2 = 1.5 4. ;C3 = 3. 4. ;
D1 = 0. 6. ;D2 = 1.5 6. ;D3 = 3. 6. ;
*
*------------- CREATION DES QUADRANGLES ET TRIANGLES -------------------
*
QQ01 = MANU QUA4 A1 A2 B2 B1 ;
QQ02 = MANU QUA4 A2 A3 B3 B2 ;
QQ03 = MANU TRI3 B1 B2 C2 ;
QQ04 = MANU TRI3 B2 B3 C2 ;
QQ05 = MANU TRI3 B1 C2 C1 ;
QQ06 = MANU TRI3 B3 C3 C2 ;
QQ07 = MANU QUA4 C1 C2 D2 D1 ;
QQ08 = MANU QUA4 C2 C3 D3 D2 ;
*
QTOT = QQ01 ET QQ02 ET QQ03 ET QQ04 ET QQ05 ET QQ06 ET QQ07 ET QQ08 ;
SI(NEG GRAPH 'N');
TRACE QTOT ;
FINSI;
QSOUR = QQ07 ET QQ08 ;
*
DD1 = D 1 D3 D2 ;
DD2 = D 1 D2 D1 ;
L_SUP = DD1 ET DD2 ;
*
DD3 = D 1 A3 A2 ;
DD4 = D 1 A2 A1 ;
L_INF = DD3 ET DD4 ;
*
*--------------- DONNEES DU PROBLEME DE THERMIQUE -----------------------
*
*-------------- MODELISATION -------------------------------------------
*
MOD1 = MODL QTOT THERMIQUE ISOTROPE ;
MOD2 = MODL L_SUP thermique CONVECTION ;
*
*--------------- DONNEES DES CARACTERISTIQUES DU MATERIAU ---------------
*
MAT1 = MATR MOD1 'K' 100. ;
MAT2 = MATR MOD2 'H' 15. ;
*
*--------------- CREATION DES MATRICES DE CONDUCTIVITE ------------------
*
CND1 = CONDUCTIVITE MOD1 MAT1 ;
CND2 = CONDUCTIVITE MOD2 MAT2 ;
*
*--------------- TEMPERATURES IMPOSEES: BLOQUE + DEPI -------------------
*
BB1 = BLOQUE L_INF 'T' ;
EE1 = DEPI BB1 10. ;
*
*--------------- FLUX EQUIVALENTS A LA CONDITION DE CONVECTION ----------
*
CNV1 = CONVECTION MOD2 MAT2 'T' 200. ;
*
*--------------- FLUX IMPOSE --------------------------------------------
*
FLU1 = FLUX MOD1 20. L_SUP ;
*
*--------------- SOURCE DE CHALEUR --------------------------------------
*
S1 = SOURCE MOD1 100. QSOUR ;
*
*---------------- ASSEMBLAGE DES TERMES DE CONDUCTIVITE -----------------
*
CCC1 = CND1 ET CND2 ET BB1 ;CCC2 = CND1 ET BB1 ;
*
*---------------- ASSEMBLAGE DES TERMES DE FLUX EQUIVALENTS -------------
*
FFF1 = EE1 ET CNV1 ;FFF2 = EE1 ET FLU1 ;FFF3 = EE1 ET S1 ;
*
*---------------- 1ERE RESOLUTION : CONVECTION --------------------------
*
*'LISTE' CCC1 ;
CCC1bis = 'KOPS' 'RIMA' CCC1 ;
CCC1bis = 'KOPS' 'CHANINCO' CCC1bis
('MOTS' 'T' 'LX') ('MOTS' 'T' 'LX')
('MOTS' 'Q' 'FLX') ('MOTS' 'T' 'LX') ;
CCC1bis = kops TRANSPOS CCC1bis;
FFF1bis = 'NOMC' FFF1 ('MOTS' 'Q' 'FLX') ('MOTS' 'T' 'LX')
'NATURE' 'DISCRET' ;
rv='EQEX' ;
rv . 'METHINV' . 'TYPINV' = 5 ;
rv . 'METHINV' . 'IMPINV' = 2 ;
rv . 'METHINV' . 'MATASS' = CCC1bis ;
rv . 'METHINV' . 'MAPREC' = CCC1bis ;
chter1b = 'KRES' CCC1bis 'TYPI' (rv . 'METHINV') 'SMBR' FFF1bis ;
CHTER1 = RESOUDRE CCC1 FFF1 ;
'MESSAGE' 'Ecart entre les deux solveurs :'
'MESSAGE' ('MAXIMUM' ('-' chter1b chter1) 'ABS') ;
*
*---------------- 2EME RESOLUTION : FLUX --------------------------------
*
CHTER2 = RESOUDRE CCC2 FFF2 ;
*
*---------------- 3EME RESOLUTION: SOURCE -------------------------------
*
CHTER3 = RESOUDRE CCC2 FFF3 ;
*
*---------------- POST-TRAITEMENT: TRACE DES CHAMPS RESULTATS -----------
*---------------- ET CALCUL DES VALEURS CARACTERISTIQUES ----------------
*
TITRE 'ELEMENTS TRI3 ET QUA4 : CONVECTION' ;
SI(NEG GRAPH 'N');
TRACER QTOT CHTER1 ;
FINSI;
TITRE 'ELEMENTS TRI3 ET QUA4 : FLUX IMPOSE' ;
SI(NEG GRAPH 'N');
TRACER QTOT CHTER2 ;
FINSI;
TITRE 'ELEMENTS TRI3 ET QUA4 : SOURCE' ;
SI(NEG GRAPH 'N');
TRACER QTOT CHTER3 ;
FINSI;
*
T1 = EXTR CHTER1 T D2 ;
T2 = EXTR CHTER2 T D2 ;
T3 = EXTR CHTER3 T D2 ;
*
SAUT PAGE ; SAUT 2 LIGNE ;
MESS ' CONVECTION FLUX SOURCE ' ;
SAUT 1 LIGN ;
MESS ' T› DE REFERENCE 100 11.2 20 ' ;
SAUT 1 LIGN ;
MESS ' T› CALCULEE ' T1 ' ' T2 ' ' T3 ;
TEMPS ;
* CODE DE FONCTIONNEMENT SUR LE FLUX
FREF=11.2;
RESI=ABS((T2-FREF)/FREF);
SI(RESI <EG 5E-2);
ERRE 0;
SINO;
ERRE 5;
FINSI;
FIN;
© Cast3M 2003 - All rights reserved.
Disclaimer