Datasets examples

* fichier :  flam2.dgibi
* COMPARAISON DES CALCULS DE FLAMBAGE D'UN TUBE 
* SOUS PRESSION EXTERNE (D'APRèS R.J. GIBERT)
OPTI DIME 3 ELEM QUA4 ECHO 0;
MESS '  COMPARAISON DES CALCULS DE FLAMBAGE';
MESS 'D UN TUBE SOUS PRESSION EXTERNE MODéLISé';
MESS '           AVEC COQ3 ET COQ4';
P0 = 0. 0. 0.;
P1 = 0. 1. 0.;
P2 = 0. 0. 1.;
P3 = 0.08 0. 0.;
P4 = 0.08 1. 0.;
P5 = 0.08 0. 1.;
C1 = CERC 20 P1 P0 P2;
C2 = CERC 20 P4 P3 P5;
L1 = D 1 P1 P4;
L2 = D 1 P2 P5;
OBJ4 = C1 TRAN 1 P3;
ELIM (OBJ4 ET L1 ET L2 ET C1 ET C2) 1.E-3;
OBJ3 = CHAN 'TRI3' OBJ4;
*  CONDITIONS AUX LIMITES
BC1 = BLOQ C1 'UX' 'RY' 'RZ';
BC2 = BLOQ C2 'UX' 'RY' 'RZ';
BL1 = BLOQ L1 'UZ' 'RX' 'RY';
BL2 = BLOQ L2 'UY' 'RX' 'RZ';
CL = BC1 ET BC2 ET BL1 ET BL2;
*  MODELE
MOD3 = MODE OBJ3 MECANIQUE ELASTIQUE ISOTROPE COQ3;
MOD4 = MODE OBJ4 MECANIQUE ELASTIQUE ISOTROPE COQ4;
*  MATERIAU
MAT3 = MATE MOD3 YOUN 2.E11 NU 0.3 EPAI 0.05;
MAT4 = MATE MOD4 YOUN 2.E11 NU 0.3 EPAI 0.05;
*  RIGIDITé
RIG3 = RIGI MOD3 MAT3;
RIG4 = RIGI MOD4 MAT4;
*  CHARGEMENT
PR3 = PRES 'COQU' MOD3 -1000000. 'NORM';
PR4 = PRES 'COQU' MOD4 -1000000. 'NORM';
*  CALCUL ELASTIQUE
DEP3 = RESO (RIG3 ET CL) PR3;
DEP4 = RESO (RIG4 ET CL) PR4;
*  CALCUL DES CONTRAINTES
SIG3 = SIGM MAT3 MOD3 DEP3;
SIG4 = SIGM MAT4 MOD4 DEP4;
*  MATRICE KS ET KP
CHP3 = MANU 'CHPO' OBJ3 1 'SCAL' -1000000.;
CHP4 = MANU 'CHPO' OBJ4 1 'SCAL' -1000000.;
KS3 = KSIG SIG3 MOD3 mat3 FLAM;
KS4 = KSIG SIG4 MOD4 mat4 FLAM;
KP3 = KP MOD3 CHP3 FLAM;
KP4 = KP MOD4 CHP4 FLAM;
RAI3 = KP3 ET ((-1.)*KS3);
RAI4 = KP4 ET ((-1.)*KS4);
RAS3 = (-1.)*KS3;
RAS4 = (-1.)*KS4;
*  RECHERCHE DE LA CHARGE CRITIQUE
*OPTI IMPI 2;
XMOD3 = VIBR PROCHE (PROG 0.417) (RIG3 ET CL) RAI3 'TBAS';
XMOD4 = VIBR PROCHE (PROG 0.417) (RIG4 ET CL) RAI4 'TBAS';
XMOD3S = VIBR PROCHE (PROG 0.482) (RIG3 ET CL) RAS3 'TBAS';
XMOD4S = VIBR PROCHE (PROG 0.482) (RIG3 ET CL) RAS4 'TBAS';
FF3 = XMOD3.'MODES'. 1 .'FREQUENCE';
FF4 = XMOD4.'MODES'. 1 .'FREQUENCE';
FF3S = XMOD3S.'MODES'. 1 .'FREQUENCE';
FF4S = XMOD4S.'MODES'. 1 .'FREQUENCE';
COM3 = (6.283184*FF3)**2;
COM4 = (6.283184*FF4)**2;
COM3S = (6.283184*FF3S)**2;
COM4S = (6.283184*FF4S)**2;
COMT = ((2.E11/(4*(1 - 0.09)))*((0.05/1.)**3))/1000000.;
MESS 'VALEUR THEORIQUE               : ' COMT;
MESS 'COQ3 :';
MESS '  VALEUR CALCULéE AVEC KP      : ' COM3;
ERR3 = ABS (100*(COMT - COM3)/COMT);
MESS '                        ERREUR : ' ERR3 '%';
MESS '  VALEUR CALCULéE SANS KP      : ' COM3S;
MESS '  VARIATION (THéORIQUE : 4/3)  : ' (COM3S/COM3);
MESS ;
MESS 'COQ4 :';
MESS '  VALEUR CALCULéE AVEC KP      : ' COM4;
ERR4 = ABS (100*(COMT - COM4)/COMT);
MESS '                        ERREUR : ' ERR4 '%';
MESS '  VALEUR CALCULéE SANS KP      : ' COM4S;
MESS '  VARIATION (THéORIQUE : 4/3)  : ' (COM4S/COM4);
*------------------ CODE DE BON FONCTIONNEMENT -------------------------
SI ((ERR3 < 5) ET (ERR4 < 5));
   ERRE 0;
SINON;
   ERRE 5;
FINSI;

FIN;