* fichier : tran8.dgibi
* CAS TEST DU 91/06/13 PROVENANCE : TEST
SAUT PAGE;
*
***************************************************************
* *
* TEST TRAN8 *
* *
* THERMIQUE TRANSITOIRE LINEAIRE EN 2D *
* *
* Test NAFEMS numero T3 *
* *
* *
* description *
* ----------- *
* *
* A C B *
* <_0.02_> *
* | | | *
* |=================================| ---> axe X *
* | | *
* <______________0.1 m______________> *
* *
* *
* conditions aux limites *
* ---------------------- *
* *
* - temperature imposee au point A : *
* TA = 0 *
* *
* - temperature imposee au point B : *
* TB = 100 * sin (PI * temps / 40) *
* *
***************************************************************
*
OPTI ECHO 0;
*
OPTI DIME 2;
OPTI ELEM QUA4;
*
GRAPH = 'N';
*
*-------------------- geometrie : maillage -------------------*
*
PA1 = 0. 0.; PB1 = 0.1 0. ;
PA2 = 0. 0.01; PB2 = 0.1 0.01;
*
N = 10;
D1 = PA1 DROI N PB1;
D2 = PB1 DROI 1 PB2;
D3 = PB2 DROI N PA2;
D4 = PA2 DROI 1 PA1;
*
SUR1 = DALL D1 D2 D3 D4 PLAN;
*
*SI (NEG GRAPH 'N');
* TITR 'TRAN8 : MAILLAGE';
* TRAC QUAL SUR1;
*FINSI;
*
*------------------ modeles - materiaux ----------------------*
*
MODL1 = MODL SUR1 THERMIQUE ISOTROPE QUA4;
MATR1 = MATR MODL1 'RHO' 7200 'K' 35.0 'C' 440.5;
*
*--------- temperatures imposees : fonction du temps --------*
*
* - Cote PA : temperature constante de 0 degres celcius
* - Cote PB : temperature variable en fonction du temps
*
BLOCD4 = BLOQ D4 'T';
BLOCD2 = BLOQ D2 'T';
*
TEMPD4 = DEPI BLOCD4 1.;
TEMPD2 = DEPI BLOCD2 1.;
*
* Un pas toutes les secondes, temps maximum 40. s.
*
LTEMPS = PROG 0. PAS 1. 40.;
*
LD4 = PROG 41 * 0.;
LD2 = PROG SINU (1. / 80.) AMPL 100 LTEMPS;
*
EVOLD4 = EVOL MANU TEMPS LTEMPS THETA LD4;
EVOLD2 = EVOL MANU TEMPS LTEMPS THETA LD2;
*
CHAD4 = CHAR 'TIMP' TEMPD4 EVOLD4;
CHAD2 = CHAR 'TIMP' TEMPD2 EVOLD2;
*
*----------- creation d'un flux nul (type chargement) --------*
*
FLU0 = MANU CHPO (D1 ET D3) 1 Q 0.;
*
EVOL3 = EVOL MANU TEMP LTEMPS FLUX (PROG 41 * 1.);
FLU1 = CHAR 'Q' FLU0 EVOL3;
*
*------------ objets pour la procedure PASAPAS ---------------*
*
TAB1 = TABLE ;
BLOCT = (BLOCD2 ET BLOCD4);
CHART = (FLU1 ET CHAD4 ET CHAD2);
*
TAB1.'TEMPERATURES' = TABLE;
TAB1.'TEMPERATURES' . 0 = MANU CHPO SUR1 1 T 0.;
TAB1.'BLOCAGES_THERMIQUES' = BLOCT ;
TAB1.'CHARGEMENT' = CHART;
TAB1.'MODELE' = MODL1;
TAB1.'CARACTERISTIQUES'= MATR1;
TAB1.'TEMPS_SAUVES' = PROG 0. PAS 1. 32.;
TAB1.'TEMPS_CALCULES' = PROG 0. PAS 1. 32.;
TAB1.'PROCEDURE_THERMIQUE' = LINEAIRE;
PASAPAS TAB1;
*
*---------------- extraction des resultats -------------------*
*
* On cherche la temperature du point C a t = 32 s.
*
CHPO3 = PECHE TAB1 'TEMPERATURES';
*
THET1 = EXTR CHPO3 T (SUR1 POIN PROC (0.08 0.));
THET2 = 36.6;
*
ERG = 100 * (ABS ((THET2 - THET1) / THET2));
*
* Trace facultatif de la repartition de temperature a t = 32 s
*
SI (NEG GRAPH 'N');
TITR 'TRAN8 : Temperature a t = 32 s';
TRAC SUR1 CHPO3;
FINSI;
*
*---------------- affichage des resultats ---------------------*
*
MESS ' RESULTATS ';
MESS ' --------- ';
SAUT 1 LIGN;
*
MESS ' Temperature theorique au point C, a t = 32 s :' THET2;
MESS ' Temperature calculee au point C, a t = 32 s :' THET1;
MESS ' Soit un ecart de :' ERG '%';
SAUT 1 LIGN;
*
*---------------- code fonctionnement --------------------------*
*
SI (ERG <EG 5);
ERRE 0;
SINON;
ERRE 5;
FINSI;
SAUT 1 LIGN;
*
TEMPS;
SAUT 1 LIGN;
*
FIN;
*
© Cast3M 2003 - All rights reserved.
Disclaimer