Datasets examples

* fichier :  four2.dgibi
GRAPH='N';                                                                      
SAUT PAGE ;                                                                     
*************************************************************************       
*  TEST FOUR2                                                                   
*                                                                               
*  CYLINDRE INFINI SOUS PRESSION EXTERNE(NU=0)                                  
*                                                                               
* Soit un cylindre infini soumis @ une pression externe.                        
*                                                                               
* Par une analyse de Fourier, on se propose de d{terminer la premi}re           
* fr{quence propre des dix premiers modes de la structure. Les éléments
* utilisés sont des éléments massifs.                           
*                                                                                        
* Comparaison a une solution analytique                                                                               
*************************************************************************    
*
TITRE 'CYLINDRE INFINI SOUS PRESSION EXTERNE';
OPTI DIME 2 ELEM qua8 MODE FOUR 0;
*
*------------------ CONSTRUCTION DE LA GEOMETRIE ------------------------
*
PA1=999.5 0.;PB1=999.5 10.;PO1=0. 0.;PO2=0. 10.;
PA2=1000.5 0.;PB2=1000.5 10.;
L1 =  PA1 DROI 3 PA2;
L2 =  PA2 DROI 10 PB2;
L3 =  PB2 DROI 3 PB1;
L4 =  PB1 DROI 10 PA1;
*
CYL = DALLER L1 L2 L3 L4 PLAN;
SI (NEG GRAPH 'N');
  TRAC CYL;
FINSI;
*
MOD1=MODL CYL MECANIQUE ELASTIQUE qua8;

*
*--- DECLARATION DE FOURIER NOHARM POUR LES OBJETS QUI SERONT UTILISES --
*------------- POUR PLUSIEURS NUMEROS D'HARMONIQUE ----------------------
*
OPTI MODE FOUR NOHARM;
*
*
*-------------- CONDITIONS AUX LIMITES SYMETRIQUES ----------------------
*
SYMB=SYMT CYL DEPL PA1 PO1  0.05;
SYMH=SYMT CYL DEPL PB1 PO2  0.05;
CDL=SYMB ET SYMH;
*
*-------------- MATERIAU ET CARACTERISTIQUES ----------------------------
*
MAT =MATR MOD1 YOUN 20000. NU 0.;
*
*------ DECLARATION DE FOURIER MODE 0 POUR LE CALCUL DES CONTRAINTES ----
*
OPTI MODE FOUR 0;

FP=PRES MASS MOD1 1. L2 ;
RIG=RIGI MOD1 MAT;
*
*
AAA = RIG ET CDL et (bloq PA1 UT);
U=RESO AAA  FP ;
SIG=SIGMA U MOD1 MAT;
I = 1;
ERRMAX = 0.;
REPETER BOUC1 9;
   I = I + 1;
*
*----- DECLARATION DE FOURIER MODE I POUR L'ANALYSE DE FLAMBAGE ---------
*
   OPTI MODE FOUR I;
   MKSI=KSIGMA MOD1 MAT (SIG * -1.)  FLAM;
   RIG=RIGI MOD1 MAT ;
*
*--------- RECHERCHE DE LA 1ERE FREQUENCE PROPRE ------------------------
*
   MODF=VIBR PROC (PROG 0.01) (RIG ET CDL) MKSI;
   LAMBDA1=((TIRE MODF FREQ RANG 1) * 6.28) ** 2;
   LDUM = (20000./(1. - 0.))*((1./1000.)**3)/12.;
   LTH1 = LDUM*I*I;

*   SAUT 1 LIGN ;
*   MESS 'Mode : ' I;
*   SAUT 1 LIGN ;
*   MESS '  K(SIG) SEUL  :   ON DOIT TROUVER LAMBDA=' LTH1;
*   MESS '                   LE CALCUL DONNE LAMBDA=' LAMBDA1;
*   SAUT 1 LIGN ;

    ERR1 = (LTH1 - LAMBDA1)/LTH1*100;
    ERRMAX=MAXI (PROG ERRMAX ERR1);
FIN BOUC1;
mess ' errmax vaut ' errmax '%';
SI (ERRMAX < 1.5 );
   ERRE 0;
SINON ;
   ERRE 5;
FINSI;
FIN;