* fichier :  fsi6.dgibi
* CAS TEST DU 91/10/04     PROVENANCE : PETI                                    
OPTI ECHO 0;                                                                    
SAUT PAGE;                                                                      
*                                                                               
******************************************************************              
*                                                                *              
*                          TEST FSI6                             *              
*                                                                *              
*      PARALLELEPIPEDIQUE FLUID VOLUME WITH FREE SURFACE         *              
*                                                                *              
*  Calculation of the sloshing frequency of a parallelpipedique  *              
*  fluid volume                                                  *              
*  Height (h) 0.1m length (a) 2m & breadth (b) 1.58m             *              
*                                                                *              
*                 P2                                             *              
*                 _________________                              *              
*                /                 /|                            *              
*               /                 / |                            *              
*              /              b  /  |                            *              
*             /                 /   |                            *              
*            /       a         /    |                            *              
*        P1 /_________________/    /                             *              
*           |                 |   /                              *              
*           |                 |  /                               *              
*           |               h | /                                *              
*           |_________________|/                                 *              
*                                                                *              
*                                                                *              
*                                                                *              
*                                                                *              
*  The boundary conditions are                                   *              
*                                                                *              
*      dp  |                                                     *              
*     ---- |                 = 0.                                *              
*      dz  | h = 0.                                              *              
*                                                                *              
*      dp  |                                                     *              
*     ---- |                 = 0.                                *              
*      dx  | x = 0  , a                                          *              
*                                                                *              
*      dp  |                                                     *              
*     ---- |                 = 0.                                *              
*      dy  | y = 0  , b                                          *              
****************************************************************** 
*
TEMPS;
*
OPTI DIME 3;
OPTI ELEM CUB8;
GRAPH = 'N';
*
*================================================================*
*               geometry                                         *
*================================================================*
*
* Dimensions en metres
*
* Points
*
P1 = 0. 0. 0.     ;
P2 = 0. 1.58114 0.     ;
EYE =  5. -3. 3.  ;
*
*
S1 =P1 D 15 P2    ;
*
FRSUR  = S1 TRAN 15 (2. 0. 0.)      ;
WATER = FRSUR VOLU TRAN 2 (0. 0. -0.1)   ;
*
* OPTIO FOR TRACE
*
SI (NEG GRAPH 'N');
  TITR ' FSI6 : MAILLAGE';
  TRAC QUAL  WATER CACH EYE   ;
FINSI;
*
*================================================================*
*      modl - materiau - rigidite - masse                        *
*================================================================*
*
MODLIQ1=MODL WATER LIQUIDE LCU8;
MODLIQ2=MODL FRSUR LIQUIDE LSU4;

*
MATLIQ = MATR (MODLIQ1 ET MODLIQ2)
         RHO 1.E3 RORF 1.E3 CSON 1435. CREF 1435. LCAR 1.0  G 9.81 ;
*
RIG1 = RIGI (MODLIQ1 ET MODLIQ2)    MATLIQ  ;
MAS1 = MASS (MODLIQ1 ET MODLIQ2)    MATLIQ  ;
*
*
*==============================================================*
*                boundary conditions                           *
*==============================================================*
*
* No explicit boundary condition ; the boundary conditions are
* natural .
*
*==============================================================*
* Theoritical value  of frequency
*
*                                                               5
FRE1 =  TABLE ;
FRE1.1 = 0.2476;
FRE1.2 = 0.3132;
FRE1.3 = 0.3993;
FRE1.4 = 0.4952;
LIST1 = PROG FRE1.1 FRE1.2 FRE1.3 FRE1.4 ;
*
*==============================================================*
*              calculation of the frequencies                  *
*                            and                               *
*                extraction of some results                    *
*==============================================================*
*
*
* Use of the operator VIBR. (option PROC)
*
*
 RESUL = VIBR PROC LIST1     RIG1  MAS1         ;
*
*==============================================================*
*                   results                                    *
*==============================================================*
*
MESS ' RESULTATS ';
MESS ' --------- ';
SAUT 1 LIGN;
*
*
FRE2 = TABLE; MOD = TABLE; DEF = TABLE;ERG = TABLE;
*
I = 0;
REPETER BLOC1 (dime resul);
  I = I + 1;
  FRE2.I = TIRE RESUL FREQ RANG I;
  ERG.I = 100 * (ABS ((FRE1.I - FRE2.I) / FRE1.I));
  MESS ' MODE '  I     ;
  MESS ' ----------';
  MESS ' Frequence theorique :' FRE1.I 'Hz';
  MESS ' Frequence calculee  :' FRE2.I 'Hz';
  MESS '    Soit un ecart de : ' ERG.I '%';
  SAUT 1 LIGN;
*
* mode shape extraction and optional trace
*
  SI (NEG GRAPH 'N');
     MOD.I = TIRE RESUL DEPL RANG I;
     DEF0 = DEFO FRSUR  MOD.I 0.;
     DEF.I = DEFO FRSUR MOD.I VERT;
     TRAC CACH (DEF.I ET DEF0) EYE CACH ;
  FINSI;
FIN BLOC1;
*
*==============================================================*
*                   code validation                            *
*==============================================================*
*
ERGMAX = MAXI (PROG ERG.1 ERG.2 ERG.3 ERG.4 )  ;
*
SI (ERGMAX <EG 5.0);
   ERRE 0;
SINON;
   ERRE 5;
FINSI;
*
SAUT 1 LIGN;
TEMPS;
SAUT 1 LIGN;
*
FIN;
*