C FLURE2    SOURCE    CHAT      05/01/13    00:04:43     5004           
       SUBROUTINE FLURE2(H0,RHOS,E1AN,T0,TABLE,IDIM,REL)
*
*      inversion de la fonction de fluage de LCPC - Granger
*
*      entree 
*            H0,RHOS,E1AN,T0 : parametres de la fonction 
*                              de fluage de LCPC-Granger
*            TABLE : tableau des temps de calcul
*            IDIM : dimension de TABLE
*            
*      sortie
*            REL : tableau des valeurs de la fonction de relaxation 
*                  calculee aux temps de TABLE
*  
      IMPLICIT INTEGER(I-N)
       IMPLICIT REAL*8(A-H,O-Z) 
*
       REAL*8 TABLE(0:1000),REL(0:1000)
*
*      initialisation de REL a 0
*
       DO 5 I=0,1000
         REL(I)=0.
5      CONTINUE
*
*      calcul de REL(0)=rel(t0,t0)
*
       CALL LCPC(H0,RHOS,E1AN,T0,T0,FLU)
       REL(0)=1./FLU
       T1=TABLE(1)
*
*      calcul de REL(K)=rel(t0,table(k))
*
       DO 10 K=1,IDIM
         TK=TABLE(K)
         TKM=TABLE(K-1)
         CALL LCPC(H0,RHOS,E1AN,T0,TK,FLU0)
         CALL LCPC(H0,RHOS,E1AN,T1,TK,FLU1)
         SOM=2.+(FLU1-FLU0)*REL(0)
         IF (K.GE.2) THEN
           DO 20 I=1,K-1
             TIM=TABLE(I-1)
             TIP=TABLE(I+1)
             CALL LCPC(H0,RHOS,E1AN,TIP,TK,FLUP)
             CALL LCPC(H0,RHOS,E1AN,TIM,TK,FLUM)
             SOM=SOM+(FLUP-FLUM)*REL(I)
20         CONTINUE
         ENDIF
         CALL LCPC(H0,RHOS,E1AN,TK,TK,FLUK)
         CALL LCPC(H0,RHOS,E1AN,TKM,TK,FLUKM)
         REL(K)=SOM/(FLUK+FLUKM)
10     CONTINUE       
       END